Çevrimdışı

;Uzun süre önce yaptığım bir SpamFilter asistanıdır.
;cod:

dialog Spam {
title "SpamFilter Ekleme Asistanı"
size -1 -1 240 147
option dbu
combo 1, 3 47 64 44, size drop
text "Sebep:", 2, 4 11 45 8, center
text "Eklenecek Kelime", 4, 4 24 45 8, center
check "Özel Mesajlar", 5, 71 53 50 10
check "Kanal Mesajları", 7, 71 43 50 10
check "Özel Notice", 8, 126 43 43 10
check "KanaL Notice", 9, 126 53 40 10
check "Kanaldan Çıkış Mesajı", 10, 173 43 64 10
check "Quit Mesajları", 11, 173 53 64 10
check "Away Mesajları", 12, 71 63 50 10
check "Topicler", 13, 126 63 43 10
check "Dcc Mesajları", 14, 173 63 50 10
check "nick!user@host", 15, 71 73 50 10
edit "-", 22, 143 73 65 9
box "", 6, 69 33 169 52, result
text "Süre", 19, 126 74 15 8, center
combo 3, 51 10 183 72, size edit hsbar drop
check "Yardım", 16, 36 62 30 10, push
button "Ekle", 18, 4 62 30 10
edit "Yasaklanacak Kelime", 20, 51 23 184 10
box "", 21, 1 33 69 52, result
check "Spamları txt Dosyasına Kaydet", 24, 5 88 91 10
check "Sebepleri Gösterme", 25, 5 101 91 10
check "Dosyayı Kaydettikten Sonra Göster", 26, 133 88 101 10
check "Satırları Numaralandır", 27, 133 101 101 10
box "", 23, 1 81 237 65, result
edit "", 17, 4 117 232 25, read multi vsbar
box "", 29, 1 4 237 33
text "Ceza Tipi:", 30, 4 38 61 8, center
}

on *:dialog:Spam:*:*:{
if ($devent == init) {
dialog -s Spam -1 -1 480 170
did -a $dname 1 Kill | did -a $dname 1 KLine | did -a $dname 1 GLine | did -a $dname 1 ZLine
did -a $dname 1 GZLine | did -a $dname 1 Shun | did -a $dname 1 TempShun | did -a $dname 1 Block
did -a $dname 1 DCCBlock | did -a $dname 1 virusChan
$iif($isfile(sebep.txt) == $true,loadbuf -o $dname 3 sebep.txt,write sebep.txt)
did -ca $dname 3 Sunucu_kurallarina_uymadiginiz_icin_serverdan_uzak lastirildiniz...
did -a $dname 3 Yasaklanmış_kelime_kullandınız...
did -a $dname 3 ---
if (%num == açık) { did -c $dname 27 }
if (%run == on) { did -c $dname 26 }
if (%kaydet == açık) { did -c $dname 24 }
if (%sebepler == kapalı) { did -c $dname 25 }
if (%kaydet == kapalı) { did -b $dname 26 }
}
if ($devent == sclick) {
if ($did == 16) { $iif($did(16).state == 1,dialog -s Spam -1 -1 480 300,dialog -s Spam -1 -1 480 170) }
if ($did == 5) { $iif($did(5).state == 1,set %tip $addtokcs(%tip,p,46),set %tip $remtokcs(%tip,p,1,46)) }
if ($did == 7) { $iif($did(7).state == 1,set %tip $addtokcs(%tip,c,46),set %tip $remtokcs(%tip,c,1,46)) }
if ($did == 8) { $iif($did(8).state == 1,set %tip $addtokcs(%tip,n,46),set %tip $remtokcs(%tip,n,1,46)) }
if ($did == 9) { $iif($did(9).state == 1,set %tip $addtokcs(%tip,N,46),set %tip $remtokcs(%tip,N,1,46)) }
if ($did == 10) { $iif($did(10).state == 1,set %tip $addtokcs(%tip,P,46),set %tip $remtokcs(%tip,P,1,46)) }
if ($did == 11) { $iif($did(11).state == 1,set %tip $addtokcs(%tip,q,46),set %tip $remtokcs(%tip,q,1,46)) }
if ($did == 12) { $iif($did(12).state == 1,set %tip $addtokcs(%tip,a,46),set %tip $remtokcs(%tip,a,1,46)) }
if ($did == 13) { $iif($did(13).state == 1,set %tip $addtokcs(%tip,t,46),set %tip $remtokcs(%tip,t,1,46)) }
if ($did == 14) { $iif($did(14).state == 1,set %tip $addtokcs(%tip,d,46),set %tip $remtokcs(%tip,d,1,46)) }
if ($did == 27) { $iif($did(27).state == 1,set %num açık,set %num kapalı) }
if ($did == 26) { $iif($did(26).state == 1,set %run on,set %run off) }
if ($did == 24) {
if ($did(24).state == 1) { set %kaydet açık | did -e $dname 26 }
else { set %kaydet kapalı | did -b $dname 26 }
}
if ($did == 25) { $iif($did(25).state == 0,set %sebepler açık,set %sebepler kapalı) }
if ($did == 15) { $iif($did(15).state == 1,set %tip $addtokcs(%tip,u,46),set %tip $remtokcs(%tip,u,1,46)) }
if ($did == 18) {
if ($did(1).sel == 0) { halt $input(Ceza Tipi Seçiniz.,oiud,Dikkat!!I) }
if ($did(3).sel == 0) {
if (%sebep == $null) { halt $input(Sebep Seçiniz. veya Yazınız.,oiud,Dikkat!!) }
}
if ($len(%tip) <= 0) { halt $input(Mesaj Tipi Seçiniz..,oiud,Dikkat!!) }
if ($did(20) == $null) && (%ekle == $null) { halt $input(Yasaklamak İstediğiniz Kelimeyi Yazınız...,oiud,Dikkat!!) }
if (%sebep == $null) { spamfilter add $remove(%tip,.) $did(1) $did(22) $did(3) $did(20) }
if (%sebep != $null) { spamfilter add $remove(%tip,.) $did(1) $did(22) %sebep $did(20) }
}
}
if ($devent == edit) {
if ($did == 3) {
if ($did(3) != $null) { set %sebep $replace($did(3),$chr(32),$chr(95)) | did -a $dname 3 $replace($did(3),$chr(32),$chr(95)) }
}
if ($did == 20) { $iif($did(20) != $null,set %ekle $did(20)) }
}
if ($devent == close) {
write sebep.txt %sebep
unset %ekle | unset %sebep | unset %tip
}
if ($devent == mouse) {
if ($did == 3) { did -ra $dname 17 Kendi Mesajını Yazmanızı Yada Daha Önce Yazdığınız Bir Mesajı Sebep Olarak Belirtilir. $crlf Boşluk Karakterleri Otomatik ( _ ) alt tireye çevrilir Hata Yapma Oranı 0 Olması için. $crlf ( _ ) Alt tire Girerseniz işlev Yapılmaz. Normal Tanımlanır.. Değişen Mesajlar Otomatik Eklenir. }
if ($did == 5) { did -ra $dname 17 Kulanıcıların özeline yazılan mesajları kapsar. $crlf Yasakladıgınız kelime birinin özeline yazılırsa aktif olur. }
if ($did == 12) { did -ra $dname 17 Away mesajlarını kapsar kullanıcı away mesajında yasakladığınız kelimeyi kullanırsa aktif olur. }
if ($did == 8) { did -ra $dname 17 Özele notice yoluyla gönderilen mesajları kapsar.Yasakladığınız kelime notice mesajı ile yollanırsa aktif olur.. }
if ($did == 9) { did -ra $dname 17 Kanala notice yoluyla gönderilen mesajları kapsar.Yasakladığınız kelime notice mesajı ile yollanırsa aktif olur. }
if ($did == 13) { did -ra $dname 17 Kanal topiclerini kapsar.Herhangi bir kanalın topic'ine yasakladığınız kelime yazılırsa aktif olur. }
if ($did == 14) { did -ra $dname 17 DCC Mesajlar Açılımı: Direct Client Connection Bağlantı Kurulurken Mesajlaşma Esnasında Aktif olur.. }
if ($did == 11) { did -ra $dname 17 Quit Mesajları Kişiler Sunucudan Çıkarken "/quit Mesaj" Şeklinde Komut Kullandıkların Aktif Olur.. }
if ($did == 10) { did -ra $dname 17 Kanaldan Çıkış Mesajları Kişiler Kanaldan Çıkmadan Hemen Önce Yolladığı Mesajlarda Aktif Olur. }
if ($did == 6) { did -ra $dname 17 Nick!user@Host:realname Bir Nick i veya İdenti yada bir Host u Yasaklamak İçin Kullanılır. }
if ($did == 22) { did -ra $dname 17 ( - ) Tire Karakteri Varsayılan Zamanı Temsil Eder Eğer Farklı Bir Zaman Çeşidi Girmek İsterseniz Saniye Cinsinden Belirtmelisiniz $crlf Yada Spamfilter Zaman Birimlerini Biliyorsanız O Şekilde Girersiniz Ne yazlı ise Onu Yansıtmaktadır.. }
if ($did == 24) { did -ra $dname 17 Spamfilter Den Gelen Tüm Yazıları txt Dosyasına Kaydeder ; Fakat Bu bir Karışıklığa Yol Açmasın Diye Dialog Kapandığında Silinir. Üst Üste Yığınlar Sizi Yanıltabilir.. }
if ($did == 25) { did -ra $dname 17 Bu Seçenek Seçilirse @Spam Penceresinde Sebebler Görüntülenmez... }
if ($did == 27) { did -ra $dname 17 Takibi Kolay Olması Açısından Satırları Numaralandırır. }
if ($did == 26) { did -ra $dname 17 Eğer Dosyayı Kaydetmeyi Seçtiyseniz ; Dosyaya Yazıldıktan Sonra İncelemeniz İçin Dosyayı Görüntüler... }
if ($did == 29) { did -ra $dname 17 The KaRaNTiNa was Here.. }
}
}
alias spamf { $iif(!$dialog(spam),dialog -ma Spam Spam,dialog -v Spam) }
menu @Spamlar {
$iif($1,SiL):.set %kaldır $read(spam.*,$sline(@spamlar,1).ln) | .spamfilter del $gettok($eval(%kaldır,1),1-2,32) $gettok($eval(%kaldır,1),5-6,32) $gettok($eval(%kaldır,1),8-,32) | write $+(-dl,$sline(@spamlar,1).ln) Spam.* | dline @Spamlar $sline(@spamlar,1).ln | unset %kaldır
$iif($1,Göster):{
if (!$window(@SpamDetay)) { window @SpamDetay | aline -hp @SpamDetay $read(spam.*,$sline(@spamlar,1).ln) }
else { clear @Spamdetay | aline -hp @spamdetay $read(spam.*,$sline(@spamlar,1).ln) }
}
}
raw 229:*:{
tokenize 32 $1-
inc %numara
if (%num == açık) { var %numar 4[ $+ %numara $+ ] }
$iif(%sebepler == kapalı,aline -hp @Spamlar %numar $3-6 $9 $+(12,$10-),aline -hp @Spamlar %numar $3-)
if (%kaydet == açık) { write Spamlar.txt $3- }
write spam.* $3-
halt
}
raw 219:*:{
set %numara 0
if (%run == on) { run Spamlar.txt }
}
on 1:CLOSE:@Spamlar:.remove spam.* | .remove spamlar.txt


;Kodu koplayıp alt+r yapın
;addona ulaşmak için /Spamf komutunu kullanın.