Auto oper hakkında - IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası

DarK^ · 31 Ocak 2006, 11:16

Merhaba , auto oper yapmaya calısıyorum ama değişkenleri olusturma ve bunları kullanma konusunda sorunum var iş oraya gelince tıkanıyor.

Ben şunu yapmıstım

Kod: Kodu kopyalamak için üzerine çift tıklayın!

 
alias opers { dialog -m opers opers }
dialog opers {
  title "Oper Girisi"
  size -1 -1 130 79
  option dbu
  edit "", 1, 22 17 90 10
  text "Oper Nickiniz", 2, 41 6 48 8
  text "Oper şifreniz", 3, 44 33 47 8
  edit "", 4, 22 47 89 10
  check "Auto oper aktif", 5, 22 63 50 10
  button "Tamam", 6, 85 62 37 12
}
 
on *:dialog:opers:sclick:1: { set %a }
on *:dialog:opers:sclick:4: { set %b }
on *:dialog:opers:sclick:5: { .dialog -x opers opers }
on *:dialog:opers:sclick:6 { .enable #autos }
#autos on
on 1:connect: { oper %a %b }
#autos end

Ama tabiki olmadı. ben bu 1 ve 4 did numarasındaki girilen değeri connect eventiyle servere bağlanınca nasıl kullanabilirim ?

Mümkünse kodu yazdıktan sonra açıklamada yazarsanız sevinirim.Çünkü sadece kodu alıp mircimi koymak istemiyorum.Mantığını anlayıp bununla baska seylerde yapabilmek istiyorum.

Vatan · 31 Ocak 2006, 13:25

Öncelikle kodunu,

Kod: Kodu kopyalamak için üzerine çift tıklayın!

 
alias opers { dialog -m opers opers }
dialog opers {
title "Oper Girisi"
size -1 -1 130 79
option dbu
edit "", 1, 22 17 90 10
text "Oper Nickiniz", 2, 41 6 48 8
text "Oper Sifreniz", 3, 44 33 47 8
edit "", 4, 22 47 89 10
check "Auto oper aktif", 5, 22 63 50 10
button "Tamam", 6, 85 62 37 12,ok
}
on *:dialog:opers:*:*:{ 
if $devent == init { if ($group(#autos) == On) { did -c opers 5 } | did -a opers 1 $iif(%Opernick != $null,%Opernick,-yok-) | did -a opers 4 $iif(%OperSifre != $null,%OperSifre,-yok-) }
if ($devent == sclick && $did == 5) { if ($did($dname,5).state == 1) { .enable #autos } | else { .disable #autos } }
if $devent == edit { set %Opernick $did(1) | set %OperSifre $did(4) }
}
#autos off
on 1:connect: { if ($me == %Opernick) { oper %Opernick %OperSifre } }
#autos end

şeklinde değiştir.

Kodda 5 numaralı ID'ye yani Check nesnesine tıklandığında #autos Grubu aktif hale gelir. yani iki "#autos" arasındaki kodlar çalışır duruma geçer.Check nesnesi tıksız oldugunda bu grup Off olur.Yani çalışmaz hale geçer.
Dialog açıldığı an bu grubun kontrolü yapılır.

Kod: Kodu kopyalamak için üzerine çift tıklayın!

if $devent == init { if ($group(#autos) == On) { did -c opers 5 } | did -a opers 1 $iif(%Opernick != $null,%Opernick,-yok-) | did -a opers 4 $iif(%OperSifre != $null,%OperSifre,-yok-) }

Eğer "#autos == On" ise Check nesnesi tıklı hale getirilir.Yani "did -c opers 5".Daha sonra önceden kaydedilmiş %Opernick ve %OperSifre değerleri varsa edit nesnelerine yazdırılır.Eğer bu değerler önceden kaydedilmemişse yani "boşsa" -yok- şeklinde bir yazı 1 ve 4 nesnelerine yazdırılır.

Kod: Kodu kopyalamak için üzerine çift tıklayın!

 
did -a opers 1 $iif(%Opernick != $null,%Opernick,-yok-) 
did -a opers 4 $iif(%OperSifre != $null,%OperSifre,-yok-)

Dialog açıkken, 5 nesnesine tıklanırsa;

Kod: Kodu kopyalamak için üzerine çift tıklayın!

 
if ($devent == sclick && $did == 5) { if ($did($dname,5).state == 1) { .enable #autos } | else { .disable #autos } }

#autos grubu aktif hale gelir.Tik işareti kaldırılırsa #autos deaktif olur.

Bir de eğer editlere bir değer girilirse o an kayıt işlemi yapılır.

Kod: Kodu kopyalamak için üzerine çift tıklayın!

 
if $devent == edit { set %Opernick $did(1) | set %OperSifre $did(4) }

başka sorun varmı?

Benzer Konular
Konu	Konuyu Başlatan	Forum	Cevaplar	Son Mesaj
Root Admin Oper Helper Karşılama ve Oper Açtı Uyarısı	Goemon	Conference Room (CR)	1	22 Kasım 2015 14:41
Oper Renklendirici (Sunucuda ki oper'lerin renklerini pembe yapin) :D	¿	mIRC Parça Kodlar	1	19 Mayıs 2015 16:44
Grand Theft Auto V hakkında 13 özellik	Ramses	Oyun Dünyasından Son Haberler	0	07 Kasım 2014 01:07
Addonları tek dosyada birleştirme ve oper korumaları hakkında [LütFen ßakınız!!!]	HipHop	mIRC Scripting Sorunları	28	21 Şubat 2006 17:24
auto msg hakkında..	MaeLStrOm	mIRC Scripting Sorunları	2	26 Nisan 2005 17:33

Konuyu Toplam 1 Üye okuyor. (0 Kayıtlı üye ve 1 Misafir)

Etiketlenen Kullanıcılar
Etiketlemek istediğiniz kullanıcılar arasına virgül koyunuz. Örnek: nokta,sukunet,NucLear

5846 sayılı Fikir ve Sanat Eserleri Kanunu gereğince sitemizde telif hakkı bulunan mp3,video v.b. eserlerin paylaşımı yasaktır. Yasal işlem olması halinde paylaşan kişi yada kişilerin bilgileri gerekli kuruma verilecektir.