!ekLe Nick ve ekLediqim nicke istediqim komudu uygulama - IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası

deLiyimmm · 25 Ocak 2009, 01:03

ArkadasLar sizden söyle bi kod istiyorum tabi mümkünse.
!ekLe nick dediqim nicki Listeye ekLice ekLediqim nick kanaLa girdiqi zaman istediqim komudu üzerinde uyguLayacak
!ekLE nick
!List
!siL

komutlari mümkünmü

yardimlariniz icin simdiden tskler...

Editor · 25 Ocak 2009, 01:20

Kişi Kanala girdiğinde Uygulanacak komut nedir ?

Buraya Bakarsanız

[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]

!ekle nick
!sil nick
!list
görebilirsiniz.

deLiyimmm · 25 Ocak 2009, 12:59

mesa ekLediqim nick kanaLa Girdiqinde ßeLirLediqim hostu ve whoiS'i aLacak ßöyLe ßise mümkünmü yardimlariniz icin tSkler...

AzuLa · 25 Ocak 2009, 14:14

PHP Kod: Kodu kopyalamak için üzerine çift tıklayın!


on *:text:*:#: {

  if $chan == #AzuLon {

    if $nick isop $chan {

      if $1 == !hostekle {

        if $2 == $null {

          msg $chan(#AzuLon) Eklenecek Nicki Yazmadınız.

          halt

        }

        if $read(hosts.txt,w,$2) {

          msg $chan(#AzuLon) Bu Nicki Daha Önceden Eklemişsiniz.

          halt

        }

        else {

          write hosts.txt $2

          msg $chan(#AzuLon) Eklenen Nick : $2

        }

      } 

      if $1 == !hostsil {

        if $2 == $null {

          msg $chan(#AzuLon) Silinecek Nicki Yazmadınız.

          halt

        }

        if !$read(hosts.txt,w,$2) {

          msg $chan(#AzuLon) Bu Nick Listede Yer Almamaktadır.

          halt

        }

        else {

          write $+(-,dw,$2) hosts.txt

          msg $chan(#AzuLon) Silinen Nick : $2

        }

      }

      if $1 == !hostlist {

        msg $chan(#AzuLon) Oto Host Listesi Sıralanıyor:

        var %a 1

        while %a <= $lines(hosts.txt) {

          msg $chan(#AzuLon) $read(hosts.txt,%a) 

          inc %a

        }

        msg $chan(#AzuLon) Oto Host Listesinin Sonu

      }

      if $1 == !hostreset {

        remove hosts.txt

        msg $chan(#AzuLon) Tüm veriler silinmiştir. 

      }

    }

    else {

      if !host* iswm $1 {

        msg $chan(#AzuLon) Bu komutu kullanabilmek için $chan kanalında Op Olmalısınız.

      }

    }

  }

}

 
on *:join:#HostKanalı: {

  if $read(hosts.txt,w,$nick) {

    chgident $nick Identiniz

    chghost $nick Hostunuz

    chgname $nick Fullnameniz

  }

}

Komutlar :
!hostekle nick : Nicki Listeye Ekler.
!hostsil nick : Nicki Listeden Siler.
!hostlist : Kayıtlı Nickleri Sıralar.
!hostreset : Tüm Kayıtlı Verileri Siler.

Açıklama:
Komutları Sadece kanalda Op Olanlar Kullanabilir. Op olmayan biri kullandığında kanala uyarı gönderecektir.
Deneme Amaçlı Komutların kullanılacağı kanalı #AzuLon olarak kaydettim. Siz de hangi kanalda kullanılmasını istiyorsanız #AzuLon olan yerleri #Kanalınız şeklinde değiştiriniz. Örneğin #Host kanalında kullanmak istiyorsunuz; #AzuLon olan yerleri #Host olarak değiştirmelisiniz.

Host - İdent - Fullname değiştirmeye gelince;
bunların hangi kanala girişte değiştirmesini istiyorsanız; #HostKanalı olan yeri kendi kanalınıza göre ayarlayınız. ( # koymayı unutmayın, aksi takdirde kod çalışmaz. )
Hostunuz olan kısımları hangi host almasını istiyorsanız o sekilde değiştiriniz. örnegin: Oper.Serveriniz.X
İdentiniz olan kısımları hangi identi almasını istiyorsanız o sekilde değiştiriniz. örneğin: Serveriniz
Fullnameniz olan kısımları hangi fullname almasını istiyorsanız o sekilde değiştiriniz. örnegin: İrc Operator in Serveriniz.X

*DipNot: Eğer Kod ile ilgili bir sorun yaşarsanız başlık altında belirtiniz.

Deneme Logu:

Alıntı:

[14:49:33] <aLias> !hostekle aLias
[14:49:34] <AzuLa> Eklenen Nick : aLias
[14:49:37] <aLias> !hostekle aLias
[14:49:38] <AzuLa> Bu Nicki Daha Önceden Eklemişsiniz.
[14:49:45] <aLias> !hostekle AzuLa
[14:49:46] <AzuLa> Eklenen Nick : AzuLa
[14:49:58] <aLias> !hostekle Lion
[14:49:58] <AzuLa> Eklenen Nick : Lion
[14:50:04] <aLias> !hostekle aSdaS
[14:50:06] <AzuLa> Eklenen Nick : aSdaS
[14:50:10] <aLias> !hostlist
[14:50:10] <AzuLa> Oto Host Listesi Sıralanıyor:
[14:50:11] <AzuLa> aLias
[14:50:11] <AzuLa> AzuLa
[14:50:11] <AzuLa> Lion
[14:50:11] <AzuLa> aSdaS
[14:50:11] <AzuLa> Oto Host Listesinin Sonu
[14:50:30] <aLias> !hostsil aLias
[14:50:31] <AzuLa> Silinen Nick : aLias
[14:50:33] <aLias> !hostsil aLias
[14:50:34] <AzuLa> Bu Nick Listede Yer Almamaktadır.
[14:50:38] <aLias> !hostlist
[14:50:38] <AzuLa> Oto Host Listesi Sıralanıyor:
[14:50:39] <AzuLa> AzuLa
[14:50:39] <AzuLa> Lion
[14:50:39] <AzuLa> aSdaS
[14:50:39] <AzuLa> Oto Host Listesinin Sonu
[14:50:44] <aLias> !hostreset
[14:50:45] <AzuLa> Tüm veriler silinmiştir.
[14:50:50] <aLias> !hostlist
[14:50:50] <AzuLa> Oto Host Listesi Sıralanıyor:
[14:50:51] <AzuLa> Oto Host Listesinin Sonu
[14:51:02] *** aLias mod değiştirdi:-o aLias
[14:51:07] <aLias> !hostlist
[14:51:08] <AzuLa> Bu komutu kullanabilmek için #AzuLon kanalında Op Olmalısınız.
[14:51:11] <aLias> !hostsil
[14:51:11] <AzuLa> Bu komutu kullanabilmek için #AzuLon kanalında Op Olmalısınız.
[14:51:14] <aLias> !hostekle
[14:51:14] <AzuLa> Bu komutu kullanabilmek için #AzuLon kanalında Op Olmalısınız.
[14:51:18] <aLias> !hostreset
[14:51:18] <AzuLa> Bu komutu kullanabilmek için #AzuLon kanalında Op Olmalısınız.

Benzer Konular
Konu	Konuyu Başlatan	Forum	Cevaplar	Son Mesaj
!badnick ekle nick ( Kill + nick değiştirme şeklinde )	Heavenly	mIRC Scripting Sorunları	20	09 Mayıs 2022 23:25
/forbid <nick> (nicke ait tüm kanalları yasaklama aliası)	Regex	mIRC Scripting Hazır Kodlar	7	28 Şubat 2010 15:08
Kanal Opları !op nick yazdıgında nicke op verme	Rom	mIRC Scripting Sorunları	4	14 Temmuz 2008 19:24
/ekle Nick Sqline ekletme..	cashmare	mIRC Scripting Sorunları	1	06 Mayıs 2008 19:08
Sock ßotta Nick Değiştirip Bad Nicke Gireni Atma	bLaCkdeviL	mIRC Scripting Sorunları	0	30 Ocak 2007 13:51

Konuyu Toplam 1 Üye okuyor. (0 Kayıtlı üye ve 1 Misafir)

5846 sayılı Fikir ve Sanat Eserleri Kanunu gereğince sitemizde telif hakkı bulunan mp3,video v.b. eserlerin paylaşımı yasaktır. Yasal işlem olması halinde paylaşan kişi yada kişilerin bilgileri gerekli kuruma verilecektir.