Çevrimdışı

Argo Kelime Listesine ekledigim kelimeler scrpt kapatıp acılıdıgında silniyor silinmemesi için ne yapabılırım..emeği gecen arkadaşlara tşk ederım

dialog argolist {
title "Argo Kelime Listesi"
size -1 -1 217 277
option pixels
box "Kelime Ekle Kaldır", 1, 7 27 204 202
button "Ekle", 2, 138 46 65 25, flat
list 3, 16 73 109 138, hsbar vsbar
button "Kaldır", 4, 139 78 65 25, flat
button "Temizle", 5, 140 131 65 25, flat
edit "", 6, 16 46 109 25, limit 182
button "ÇIKIŞ", 7, 7 239 203 25, ok flat
text "Argo Kelime Listesi", 8, 7 3 202 20
}
on *:dialog:argolist:*:*: {
if ($devent == init) {
var %i = 1
while (%i <= $hget(wordlist, 0).item) {
did -a $dname 3 $word_unstrip($hget(wordlist, %i).item)
inc %i
}
}
if ($devent == sclick) {
if ($did == 2) {
var %seltext = $did($dname, 6).text
if (!%seltext) {
print_message -a Lütfen Öncelikle Girmek isediğiniz Kelimeyi Yazın ve Ekle Butonuna Basın!
did -f $dname 6
halt
}
if ($add_word(%seltext)) {
did -a $dname 3 $word_strip(%seltext)
}
did -r $dname 6
}
if ($did == 4) {
var %sel = $did($dname, 3).sel, %seltext = $did($dname, 3).seltext
if (!%sel) {
print_message -a Lütfen Silmek istediğiniz Kelimeyi Seçin
return $false
}
if ($remove_word(%seltext)) {
did -d $dname 3 %sel
}
}
if ($did == 5) {
if (!$hget(wordlist)) {
hfree wordlist
.remove -b wordlist.db
hmake wordlist 100
hsave wordlist wordlist.db
}
did -r $dname 3
}
}
}
alias print_message {
var %flag, %message, %param1, %param2
;Flaglarımız standard olarak a: alert, i: info, ca: confirm alert, ci: confirm info şeklindedir.
;Bakalım ilk parametre flaglarımıza uygun mu...
if ($regex(parameters, $1, /^-?(a|i|ca|ci)$/i)) {
%flag = $regml(parameters, 1)
%message = $2-
}
else { ;Bu noktada herhangi bir parametremiz yok. Bu nedenle Standard olarak Bilgi Parametresini (i) kullanacağız.
%flag = i
%message = $1-
}
if (%flag == i) {
%param1 = oi
%param2 = Bilgi Mesajı
}
elseif (%flag == ci) {
%param1 = yi
%param2 = Doğrulama Mesajı
}
elseif (%flag == a) {
%param1 = ow
%param2 = Hata Mesajı!
}
elseif (%flag == ca) {
%param1 = yw
%param2 = Doğrulama Mesajı!
}
%result = $input(%message, %param1, %param2)
return %result
}
alias word_strip {
var %word = $1-
%word = $replace(%word, ###, \#\#\#)
var %junk = $regsub(%word, /(\s)+/g, ###, %word)
return %word
}
alias word_unstrip {
var %word = $1-
var %junk = $regsub(%word, /(###)+/g, \s, %word)
%word = $replace(%word, \#\#\#, ###)
return %word
}
alias do_add_word {
hadd wordlist $1 1
hsave -i wordlist wordlist.db
return $true
}
alias add_word {
var %word = $1-
if (!%word) {
print_message -a Lütfen Kelime Girin!
return $false
}
if (!$hget(wordlist)) {
if ($print_message(ca, Kelimelerin Kayıt Edilip Okunacağı Veri Tabanı Bulunamadı. Oluşturulsun mu?)) {
hmake wordlist 100
hsave -i wordlist wordlist.db
}
else {
print_message -a Kelime Veri Tabanı Olmadığı için Eklenemedi...
return $false
}
}
if ($len(%word) > 100) {
print_message -a Ekleyeceğiniz Kelime 182 Karekteri Geçmemelidir
return $false
}
%word = $word_strip(%word)
if ($hget(wordlist, %word)) {
print_message -a Kelime Zaten Listenizde Mevcut
return $false
}
return $do_add_word(%word)
}
alias remove_word {
var %word = $word_strip($1-)
if (!$hget(wordlist) || !$hget(wordlist, %word)) {
print_message -a Kaldırmak istediğiniz Kelime Zaten Sistemde Mevcut Değil
return $false
}
hdel wordlist %word
hsave -i wordlist wordlist.db
return $true
}
alias argolist dialog -ma argolist argolist
on *:text:*:#: {
if ($me isop $chan && $nick !isop $chan) {
var %i = 1, %text = $1-
while (%i <= $numtok(%text, 32)) {
if ($hget(wordlist, $word_strip($gettok(%text, %i, 32)))) {
kick $chan $nick Argo Kelime Kullanımı yasaktır
halt
}
inc %i
}
}
}
on *:start: {
if ($is_file(wordlist.db)) {
hmake wordlist
hload wordlist wordlist.db
}
else {
hmake wordlist 100
hsave -i wordlist wordlist.db
}
}

 

Çevrimdışı

Kod'da $isfile identifier'ı yanlış kullanılmış.
Ayrıca on start event'inde hload komutunda -i parametresini kullanmalısın.
Yüklenicek dosyanın "ini" dosyası olduğu belirtilmeli.
Yani kısacası;

on *:start: {
if $isfile(wordlist.db) {
hmake wordlist
hload -i wordlist wordlist.db
}
else {
hmake wordlist 100
hsave -i wordlist wordlist.db
}
}

Şeklinde değişirsen, sorunun çözülecektir.

 

Çevrimdışı

Sorun Çözüldü tşk ederim..