Bayadır kendi botumda kullandığım bir sistem, cok sık istenmesinden dolayı müsait bir zamanımda paylaşacağımı söylemiştim bazı arkadaşlara, içlerinden bazılarının ısrarları rahatsız edici derecedede olsa düzenleyip paylaştım.
Özellikler 1-Kod bir çok Unreal sunucuda gördüğünüz gibi Son kayıt edilen nick ve kanalı servera girişlerde bildirir. Aşağıdaki gibi.
§~¤§¤~~¤§¤~~¤§¤~~¤§¤~~¤§¤~~¤§¤~~¤§¤~~¤§
En Son kaydedilen Nick: uMuT
En Son kaydedilen Kanal: #deneme
§~¤§¤~~¤§¤~~¤§¤~~¤§¤~~¤§¤~~¤§¤~~¤§¤~~¤§
2- Kayıt edilen nick veya kanal olursa #bilgi kanalına uyarıda bulunur.
3- Kayıt edilen kanala girer ve kanal kurallarını bildirip ayrılır.
4- Daha önceden kayıtlı bir nick identify edilirse #bilgi kanalına nickin login olduğu bilgisini verir. Kayıtsız bir nick servera girerse nick kayıt etme komutunu gönderir. Guest bir nick girerse nick değişme komutunu gönderir.
Nasıl Kurulacağı Hakkında bilgi. Adım-1 Link Kurulumu
/as server serverlink add
/as server serverlink set name stats.umut.com
/as server serverlink set port 7000
/as server serverlink set ping 240
/as server serverlink set inpass
Şifre
/as server serverlink set outpass
Şifre
/as server serverlink enable
/as server serverlink set leaf
serverlink yazan yerleree istediğinizi yazabilirsiniz. "
Şifre" yazan yere belirlediğiniz şifreyi yazdıktan sonra aşağıdaki kodda kırmızı ile belirtilen şifre kısmına yazınız.
Bunun dışında herhangi bir değişklik yapmayınız link kurulumunda, kod aksi halde çalışmayacaktır. Adım-2 Mirce Ekleyip Çalıştırma
Sunucunuzda sürekli aktif olan bir mirc bot varsa onun
remotesine(alt+R) kodları ekleyiniz. Kodda kırmızı ile belirtilen yerleri doldurunuz. Bütün işlemleri tamamladıktan sonra mircinizi açıp kapatırsanız otomatik baglanır yada manuel olarak
/ns-cs komutuylada çalıştırabilirsiniz.
UYARI-1: Notice mesajlarının orjinali değiştirilmemiş ingilizce olan sunucularda sorun yaşanmayacaktır. Türkçeleştirilmiş sunucularda belirtilen noticelerden farklı ise tam çalışmama durumu olabilir.
UYARI-2: Kodlarda yapılacak herhangi bir değişiklik çalışmamasına büyük ihtimalle neden olacaktır; o yüzden sadece kırmızı kısımları doldurunuz.
Kod:
/* ConferenceRoom
* Nick ve Kanal Bilgi Sistemi
* By uMuT (Med Cezir)
*/
alias ns-cs unset %nickdenetle | sockclose cr-bot | sockopen cr-bot irc.sunucunuzunadı.com 6667
alias nsbotname return Nick $+ $chr(160) $+ Service
alias csbotname return Channel $+ $chr(160) $+ Service
alias bilgichan return #bilgi
alias komut.ua { if $sock(cr-bot) { sockwrite -tn cr-bot $1- } }
on *:start:ns-cs
on *:sockopen:cr-bot:{
if ($sockerr) { echo $color(info) -st 4Socket botun bağlantısı kesildi. | .timerbagla 1 30 .ns-cs | return }
;Şifre kısmı buraya girilecektir.
sockwrite -tn $sockname pass Şifre
sockwrite -tn $sockname server stats.umut.com 1 7aSpeRa 10Server N14ick 10& K14anal Service System
sockwrite -tn $sockname NICK $csbotname 0 1112988092+oiwghmX2szAa ChanServ chanserv.umut.com stats.umut.com -28kMQCN9xGI2p5UQA $+ $rand(a,z) $+ > :1 $decode(80V]D960@0GD@=4UU5"A-960@0V5Z:7 $+ $chr(40) $+ I````)
sockwrite -tn $sockname NICK $nsbotname 0 1112988092+oiwghmX2szAa NickServ nickserv.umut.com stats.umut.com -28kMQCN9xGI2p5UQA $+ $rand(a,z) $+ > :1 $decode(80V]D960@0GD@=4UU5"A-960@0V5Z:7 $+ $chr(40) $+ I````)
}
on *:sockread:cr-bot:{
if ($sockerr) { echo $color(info) -st Socket botun bağlantısı kesildi3. | .timerbagla 1 30 .ns-cs | return }
var %; | sockread %; | tokenize 32 %;
swalias $1-
}
alias swalias {
if $sock(cr-bot) {
if :VERSION iswm $4- { komut.ua NOTICE $gettok($gettok($1,1,33),1,58) : $+ $chr(1) $+ VERSION mIRC v6.16 Khaled Mardam-Bey $+ $chr(1) }
if :FINGER iswm $4- { komut.ua NOTICE $gettok($gettok($1,1,33),1,58) : $+ $chr(1) $+ FINGER uMuT (MedCezir) $+ $chr(1) }
if $1 == PING { komut.ua PONG $2- }
if $1 == ERROR { ns-cs }
if $5 == :[127.0.0.1] {
.echo -as Servera Bağlanıldı
.timerdnton $+ $rand(0,999999) 1 30 set -e %nickdenetle on
}
if $1 == NICK && %nickdenetle == on {
komut.ua $+(:,stats.umut.com) 006 $2 §~¤§¤~~¤§¤~~¤§¤~~¤§¤~~¤§¤~~¤§¤~~¤§¤~~¤§
komut.ua $+(:,stats.umut.com) 006 $2 En Son kaydedilen Nick: %sonnick
komut.ua $+(:,stats.umut.com) 006 $2 En Son kaydedilen Kanal: %sonkanal
komut.ua $+(:,stats.umut.com) 006 $2 §~¤§¤~~¤§¤~~¤§¤~~¤§¤~~¤§¤~~¤§¤~~¤§¤~~¤§
if (Guest* iswm $2) {
komut.ua : $+ $nsbotname privmsg $2 /nick yeninick Yaparak Nickinizi Degiştirebilirsiniz.
}
else {
komut.ua : $+ $nsbotname privmsg nickserv acc $2
}
}
if $2 == NOTICE && ((*umuzu*kayıtlı*değildir* iswm $4-) || (*The nickname*is not registered* iswm $4-)) {
komut.ua : $+ $nsbotname privmsg $remove($4,:) Merhaba $remove($4,:) Sunucumuza Hoşgeldiniz
komut.ua : $+ $nsbotname privmsg $remove($4,:) 1Rumuzunuz sunucumuza kayitli degildir. Kayit(REGISTER) edebilmek ve sadece size ait olmasini saglamak icin kullanmanız gereken komut 4/NickServ REGISTER SIFRENIZ E-MAILINIZ
komut.ua : $+ $nsbotname privmsg $6 Merhaba $6 Sunucumuza Hoşgeldiniz
komut.ua : $+ $nsbotname privmsg $6 1Rumuzunuz sunucumuza kayitli degildir. Kayit(REGISTER) edebilmek ve sadece size ait olmasini saglamak icin kullanmanız gereken komut 4/NickServ REGISTER SIFRENIZ E-MAILINIZ
}
if $2 == MODE && ($4 == +r || $4 == +rtn) && $islower($4) == $true { set %acilankanal $3 | set -e %kanalacildi on | komut.ua : $+ $csbotname privmsg chanserv info $3 }
if $2 == TOPIC && $3 == %acilankanal { unset %kanalacildi %acilankanal }
if $2 == NOTICE {
if %Kanalacildi == on && $regex($4-,/(Founder|Kanal Sahibi)/i) {
var %knlacan $7
;Kanalı Acana Mesaj
komut.ua : $+ $csbotname join %acilankanal $csbotname
komut.ua : $+ $csbotname mode %acilankanal +o $csbotname
komut.ua : $+ $csbotname NOTICE %acilankanal 4 %acilankanal Kanalının Kaydı Gerçekleştirilmiştir.
komut.ua : $+ $csbotname NOTICE %acilankanal -
komut.ua : $+ $csbotname NOTICE %acilankanal Sunucu Kuralları:
komut.ua : $+ $csbotname NOTICE %acilankanal $qt(Nick) ve $qt(Kanal) şifrelerinin sorumluluğu tamamen kullanıcılara aittir.
komut.ua : $+ $csbotname NOTICE %acilankanal Sunucuda huzuru bozucu haraketler, lamer faliyetler, her türlü flood yasaklanmıştır.
komut.ua : $+ $csbotname NOTICE %acilankanal Sunucuda başka sunucuların reklamı, Kanallarda başka kanalların reklamı yapılması, kesinlikle yasaktır.
komut.ua : $+ $csbotname NOTICE %acilankanal "Bu kurallara uymadıgınız takdirde sunucudan cezalar alacaksınız."
komut.ua : $+ $csbotname NOTICE %acilankanal Hos Sohbetler.
;Bilgi kanalına Mesaj
komut.ua : $+ $csbotname privmsg $bilgichan Kanal sifrelendi:3 * %acilankanal * 1kanali kayit edilmiştir.
komut.ua : $+ $csbotname privmsg $bilgichan
komut.ua : $+ $csbotname privmsg $bilgichan Kayit eden:10 $7-
komut.ua : $+ $csbotname privmsg $bilgichan
komut.ua : $+ $csbotname privmsg $bilgichan Sunucu Kuralları,3 %acilankanal 1 Kanalına bildirilmiştir..
komut.ua : $+ $csbotname part %acilankanal
set %sonkanal %acilankanal
unset %kanalacildi %acilankanal
}
}
if $2 == MODE && $4 == :+R { komut.ua : $+ $nsbotname mode $3 | set %bakbakim on }
if $2 == 324 && (*+*R* iswm $5) && %bakbakim == on {
set %rnick $4
set %kayitsor on
komut.ua : $+ $nsbotname privmsg nickserv info %rnick
unset %bakbakim
}
if $2 == NOTICE && %kayitsor == on {
if $regex($4-,/(Kayıt Zamanı|Time registered)/i) { set %nkayit $+($7,$chr(160),$gettok($8,1-2,58)) }
if $regex($4-,/(uan Zaman|Time now)/i) { set %nsuan $+($7,$chr(160),$gettok($8,1-2,58)) }
if $regex($4-,/(Nick Bilgisisonu|End of nick info)/i) {
if (%nkayit != %nsuan) {
komut.ua : $+ $nsbotname privmsg $bilgichan %rnick Sunucuya %nsuan itibariyle Login oldu. Nick Kayıt Zamanı %nkayit
unset %kayitsor %rnick %nkayit %nsuan
halt
}
else {
komut.ua : $+ $nsbotname privmsg $bilgichan Sunucuya Yeni Nick Kaydı Gerçekleştirildi.
komut.ua : $+ $nsbotname privmsg $bilgichan
komut.ua : $+ $nsbotname privmsg $bilgichan Kayıt Edilen Nick : 4 %rnick 1 Kayıt Zamanı :4 %nsuan
set %sonnick %rnick
unset %kayitsor %rnick %nkayit %nsuan
halt
}
}
}
;###The End ###
}
}
