[Forbidden]

Merhabalar kodun amacı Disk dosyanızı görüntülemeye verilerinizi kontrol etmeye yarar.
Verileri ister sabitleyebilir ister görüntüleyebilir istersenizde cıkarabilirsiniz.
İsterseniz Disk dosyasınızı otomatik mIRC ile de baslatabilirsiniz.
Win 7 isletim sisteminde test edilmistir.

Kod:   Kodu kopyalamak için üzerine çift tıklayın!

alias -l w_r_kod_ana_dizin return 7
alias -l w_r_kod_alt_dizin return 5
alias -l w_r_kod_dosya return 2
alias -l w_r_kod_sabit_dizin return 3
alias -l w_secim_tek { if $sline(%wdyo_p,0) == 1 { return $true } | else { return $false } }
alias -l w_color { if ($2) { aline -ln %wdyo_p $2- | cline -l $1 %wdyo_p $$fline(%wdyo_p,$2-,1,1) } }
alias -l windiskmanager {
  set %wdyo_p @Dizin_Görüntüleyici
  unset %wdyo_discs
  if ($window(%wdyo_p)) { window -c %wdyo_p }
  if ($!window(%wdyo_p)) { window -aekn20Sl20z %wdyo_p }
  titlebar %wdyo_p Dizin Görüntüleyici v1.0
  echo $color(text) %wdyo_p [Dizin Görüntüleyici v1.0.17]
  echo $color(text) %wdyo_p -
  echo $color(text) %wdyo_p -
  echo $color(text) %wdyo_p -
  echo $color(text) %wdyo_p #Kullanım Bilgileri
  echo $color(text) %wdyo_p -
  echo $color(text) %wdyo_p * Disk bilgileri icin listedekilere cift tıklayın.
  echo $color(text) %wdyo_p * Geri gitmek icin listeden ogeyi secip  <--  Backspace tusuna basin.
  echo $color(text) %wdyo_p * Sag tiklayip listenize ogeleri sabitleyebilir veya kaldirabilirsiniz.
  echo $color(text) %wdyo_p * Yazı alanında sag tiklayip, Dizin Görüntüleyiciyi mIRC baslattiginiz zaman otomatik olarak açılmasını saglayabilirsiniz.
  echo $color(text) %wdyo_p * Win 7 isletim sisteminde test edilmistir.
  echo $color(text) %wdyo_p -
  echo $color(text) %wdyo_p #Renk Kodları
  echo $color(text) %wdyo_p -
  echo $color(text) %wdyo_p  $+ $w_r_kod_ana_dizin $chr(127)  Ana Dizinler
  echo $color(text) %wdyo_p  $+ $w_r_kod_alt_dizin $chr(127)  Alt Dizinler
  echo $color(text) %wdyo_p  $+ $w_r_kod_dosya $chr(127)  Dosyalar
  echo $color(text) %wdyo_p  $+ $w_r_kod_sabit_dizin $chr(127)  Sabit Dizinler (Sizin Ekledikleriniz)
  echo $color(text) %wdyo_p -
  var %z = 1 | while ($disk(%z).path) { aline -ln %wdyo_p $v1 | cline -l $w_r_kod_ana_dizin %wdyo_p $$fline(%wdyo_p,$v1,1,1) | set -e %wdyo_discs %wdyo_discs $v1 | inc %z }
  var %d_a = $mircdirwdyo_sabit.txt
  if ($isfile(%d_a) && $file(%d_a).size > 0 ) { var %c = 1 | while (%c <= $lines(%d_a)) { w_color $w_r_kod_sabit_dizin $read(%d_a,%c) | inc %c } }
}
menu status,@Dizin_Görüntüleyici,channel {
  dclick:{
    if ($mouse.lb && $sline(%wdyo_p,1)) {
      var %sci = $strip($sline(%wdyo_p,1))
      if ($isdir(%sci) && $finddir(%sci,*.*,1)) { noop $finddir(%sci,*.*,0,1,w_color $w_r_kod_alt_dizin $1- ) }
      if ($isdir(%sci) && $findfile(%sci,*.*,0,1)) { noop $findfile(%sci,*.*,0,1,w_color $w_r_kod_dosya $1-) }
      if ($isfile(%sci)) { run %sci }
      if (\* iswm %sci) { run $gettok(%sci,1-,$asc(\)) }
    }
  }
  Dizin Görüntüleyici
  .$iif(!$mouse.lb,Görüntüleyiciyi $iif(!$window(%wdyo_p),$null,Yeniden) Başlat):/windiskmanager
  .$iif(%wdyo_autost && !$mouse.lb,$style(1),$null) $iif(!$mouse.lb,mIRC baslattiğimda otomatik aç,$null):{ $iif(%wdyo_autost,unset %wdyo_autost,set %wdyo_autost on) }
  .$iif($mouse.lb && !$istokcs(%wdyo_discs,$1,32) && $w_secim_tek,Secili Yolu,$null)
  ..$iif($mouse.lb && !$read(wdyo_sabit.txt,w,\ $+ $1-) && \* !iswm $1- && $w_secim_tek,Listeye Sabitle):{
    write wdyo_sabit.txt $+(\,$1-)
    w_color $w_r_kod_sabit_dizin $+(\,$1-)
    echo %wdyo_p +> $qt($1-)
  }
  ..$iif($mouse.lb && \* iswm $1- && $read(wdyo_sabit.txt,w,$1-) && $w_secim_tek,Sabitlikten çıkar):{
    write $+(-dl,$readn) wdyo_sabit.txt
    echo %wdyo_p <- $qt($1-)
    dline -l %wdyo_p $sline($active,1).ln
  }
}
on *:start:{ if (%wdyo_autost) { /windiskmanager } }
on *:keydown:%wdyo_p:8:{
  if ($mouse.lb && $w_secim_tek) {
    var %slnd = $sline(%wdyo_p,1)
    if ($istokcs(%wdyo_discs,%slnd,32)) {
      var %c = 2 | while ($$fline(%wdyo_p,$+(%slnd,*),2,1)) { dline -l %wdyo_p $$fline(%wdyo_p,$+(%slnd,*),2,1) | inc %c }
      return
    }
    if ($finddir(%slnd,*.*,1)) { noop $finddir(%slnd,*.*,0,1,dline -l %wdyo_p $$fline(%wdyo_p,$1-,1,1).state) }
    if ($findfile(%slnd,*.*,0,1)) { noop $findfile(%slnd,*.*,0,1,dline -l %wdyo_p $$fline(%wdyo_p,$1-,1,1).state) }
  }
}

[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]

[Che]

Eline emeğine sağlık başarılar diliyorum.

[Birtürk]

Forbidden emegine saglık