[manikdepresif]

Hostu ayni olan yada farkli olan nickleri dosyaya kaydeder ve asagida yazilmis komut uygulandiginda o nickin girmis oldugu hostlari ve nickleri tarihli olarak @takip penceresinde gosterir.
-
Not1: Eger nick 2 kez ya da daha fazla girmisse, son girdigi tarihi verir.
Not2: Sunucunun vermis oldugu hostdan dolayi bazi nickleri karisik olarak gostermesi normal bir durumdur. (DJ, Admin vs.)
Not3: Herkes kullanabilir, herhangi bir yetki gerektirmez. Sunucunun giriste nickleri otomatik soktugu bir global kanalda bulunmaniz yeterlidir.
Not4: Belirli bir sureden sonra @takip penceresinde sag tik yaparak menuden "Nick takip listesini sil" secenegini secerek listeyi silebilirsiniz.
-
Komut: /nickara nick
-

Kod:   Kodu kopyalamak için üzerine çift tıklayın!

on *:join:#:{
  if $regex($nick,/^(bot1|bot2|bot3)/i) {  halt }
  dosyayayaz $nick $token($address,2,64)
}
on *:nick:{
  if $regex($newnick,/^(bot1|bot2|bot3)/i) {  halt }
  dosyayayaz $newnick $token($address,2,64)
}
alias -l dosyayayaz {
  var %hstnick_ = $2
  var %np_ = /( $+ $1 $+ !(\d+)) $+ /i
  var %frst_ = $token($read(ipnicktakip.txt,w,$+(%hstnick_,*)),2-,32)
  write $+(-w,%hstnick_,*) ipnicktakip.txt  %hstnick_  $iif($regex(%frst_ ,%np_),$remove(%frst_,$regml(1)),%frst_) $+($1,!,$ctime)
}

alias nickara {
  if !$1 { echo $color(info) > Nick belirtmelisiniz | return }
  if ($1 == * || $1 == ? || $1 == .) { halt }
  if (!$window(@takip)) { window -ae @takip }
  if (!$window(@takip).title) { titlebar @takip [ Nick aramak icin /nickara nick komutunu kullaniniz. ]  } 
  clear @takip
  filter -fkg ipnicktakip.txt pencereyeyaz $+(/,$1,!,(\d+)/i) 
}
alias -l pencereyeyaz {
  echo @takip $str(-,50)
  echo @takip [HOST BILGISI] $token($$1,1,32)
  echo @takip $str(-,50)
  var %m_ = 2
  while ($token($$1,%m_,32)) {
    echo @takip  Nick: $token($v1,1,33)  Tarih: $asctime($token($v1,2,33),dd/mm/yy HH:nn)
    inc %m_
  }
  echo @takip $str(-,1)
}
menu @takip {
  Nick takip listesini sil :/write -c ipnicktakip.txt | echo $color(info) > Takip Listesi Silindi.
}

;istek uzerine yazilmistir.