mirc 6.17 yeniliklerinin incelenmesi
 

mirc 6.17 de remoteye kopyalayıp /clt yazmanız yeterli

;clt : Check Listbox Testi
alias clt { if !$dialog(clt) { dialog -m clt check_listbox_testi } }
dialog check_listbox_testi {
title "Check Listbox testi"
size -1 -1 198 180
option dbu
list 1, 1 0 142 179, check
button "Seçilileri echo'la", 2, 145 2 53 12
button "Tüm listeyi echo'la", 3, 145 16 53 12
button "Seçilileri sil", 4, 145 30 53 12
edit "", 5, 153 47 45 10
check "" , 6, 145 48 7 7
button "Ekle", 7, 145 58 53 12
button "Kapat", 8, 144 166 53 12, cancel
}
on *:dialog:clt:*:*: {
if $devent == init {
var %i = 1
;check box eklemek normal liste item eklemenin aynısı
while %i <= 35 { did -a $dname 1 Deneme itemi %i | inc %i 1 }

;eklediklerimizden 3. ile 15. itemler dahil aralarındakileri seçili yapalım
;3-15 parametresini kullanamıyoruz :S
var %i = 3
while %i <= 15 {
did -s $dname 1 %i
inc %i 1
}

;11. itemimizi de seçili olmasın istiyorum
did -l $dname 1 11
}
if $devent == sclick {
if $did == 2 {
var %i = 1
echo 4 -a $dname dialogu seçililerin echolanması
;Kaç tane seçili itemimiz olduğunu $did(1,0).csel ile alıyoruz, buaradaki 1 listbox id si
while %i <= $did(1,0).csel {
echo 7 -a seçilen:5 $did(1,%i).csel 7string:5 $did(1,$did(1,%i).csel)
inc %i 1
}
}
if $did == 3 {
var %i = 1
echo 4 -a $dname dialogu tüm listenin echolanması
;Kaç tane itemimiz olduğunu $did(1,0).lines ile alıyoruz
while %i <= $did(1,0).lines {
echo 7 -a seçilen:5 %i 7string:5 $did(1,%i)
inc %i 1
}
}
if $did == 4 {
var %i = $did(1,0).csel
;Kaç tane seçili itemimiz olduğunu $did(1,0).csel ile alıyoruz
while %i {
did -d $dname 1 $did(1,%i).csel
dec %i 1
}
}
;&& $did(5) kısmı eğer editboxta birşey var ise
;-c yeni itemi highlight(slect) etmek için
;$did(6).state eğer editboxun önündeki check işaretli ise s parametresini kullanıp onu seçili hale getir.
if $did == 7 && $did(5) {
did -ca $dname 1 $did(5)
;-sa veya -sca çalışmadığı için alttaki kısıma eklemek zorunda kaldım :)
if $did(6).state { did -s $dname 1 $did(1,0).lines }
}
}
}

$mouse.key denemesi
 

eskiden $mouse.key & 2 ve $mouse.key & 4 ü biliyorduk yeni versiyon ile birlikt 2 ve 4 e ek olarak 8 ve 16 da dahil edilmiş. Kodu remoteye kopyalayıp yazı ile mousekey yazın eğer entere bastıgınız anda alt tuşu basılı ise koddaki if $mouse.key & 8 { echo 7 -a Alt tuşu şu anda basılı durumda } kısmı işlem görecektir bu bir nevi scripttinizde nasıl kullanacağınıza ilişkin bir örnektir $mouse.key & 2 ile ilgili forumumuzda örnekler mevcuttur.

on *:input:*: {
;alttaki kısım sadece mausekey yazılı iken aktif olması için
if $regex($1-,^mousekey$) {
if $mouse.key & 2 { echo 7 -a Ctrl tuşu şu anda basılı durumda }
if $mouse.key & 4 { echo 7 -a Shift tuşu şu anda basılı durumda }
if $mouse.key & 8 { echo 7 -a Alt tuşu şu anda basılı durumda }
if $mouse.key & 16 { echo 7 -a sağ mouse tuşu şu anda basılı durumda }
halt
}
}

artık dosya adlarında $+(",dosya,") a gerek yok aynı işlemi gören $qt(dosya) ve bunun tam tersi "dosya" gibi quoteli(alıntı) ları iptal eden $noqt("dosya") identifieri eklenmiş.

dialoglarda /did -[parametre] dialog_adi 1-6 gibi 1 ile 6 arası aralığı seçebiliyoruz ama yukarıdaki checkbox örneğindeki gibi listboxun içindeki itemler için tek tek yapmak zorundayız aralıkları ve , leri hala kullanamıyoruz

$findfile identifierine ; ile 1 den fazla dosya araması ekleyebiliyoruz
//echo : $findfile($mircdir,*.exe,0)
//echo : $findfile($mircdir,*.exe;*.txt;*.ini,0)
gibi.

ve eklenen $regsubex chek box lu list ten sonra en çok hoşuma giden yenilik:
[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]
deki kodumu artık
sreplace {
var %x, %i = $regsub($2-,/(http:\/\/[a-z]{3}\.[a-z].+\.[a-z]{3})/g, $1 ,%x)
return %x
}

gibi değilde sadece:
sreplace { return $regsubex($2-,/(http:\/\/[a-z]{3}\.[a-z].+\.[a-z]{3})/g, $1) }
olarak yazabilirim :D

/set komutuna getirilen -e flagını sevdim, /set -e %var <değer> ile kurduğumuz %var değişkeni mIRC kapatıldıktan sonra otomatik olarak siliniyor.

$input'a timeout (zaman aşımı) parametresi getirilmesi hoşuma gitti.

$decode'un mIRC yüklenir yüklenmez disable/locked olması ve kilitlenebilir olması mIRC'ye yeni başlayanlar adına sevindim. Gereksiz spamler böylece bir nebze de olsa engellenebilir.

$ibl (internal ban list) olduğu halde önceden internal exception ve internal invite list için identifier yoktu ama artık var. $iel ve $iil.

DCC ile ilgili sorun yaşayanlar için Passive DCC özelliğini de sevdim. Yabancı mIRC'ye yeni başlayanların en çok sordukları sorulardan DCC göndermede sorun böylece çözülmüş oldu. (/dcc passive on|off)

Şimdilik dikkatimi çeken bunlar, 6.16'dan daha iyi olduğu kesin. -)

Trylock'u Tuş ve mouse kombinasyonundan da kurtarmıs khaled, sağolsun..

/showmirc -l