IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası

IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası (https://www.ircforumlari.net/)
-   mIRC Scripting Hazır Kodlar (https://www.ircforumlari.net/mirc-scripting-hazir-kodlar/)
-   -   Kötü Rumuz Koruması... (https://www.ircforumlari.net/mirc-scripting-hazir-kodlar/27275-kotu-rumuz-korumasi.html)

TiPiTiP 03 Şubat 2007 21:18

Kötü Rumuz Koruması...
 
[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]

Kullandığım kodların tamamı IRCForumları'nda mevcuttur ve el33t'e aittir, ben sadece bir dialog hazırlayıp forumdaki kodları topladım kullanışlı olması açısından, umarım yararlı olur...

Kurulum:
Kodu çalıştırmak için aşağıdaki 2 işlemden birini uygulayabilirsiniz.

1) Kodları ALT+R yapıp açılan pencereye yapıştırın.
2) Bir not defteri açıp içine yapıştırın ve mIRC klasörünüzün içine atın. Daha sonra mIRCte /load -rs Dosyanız.txt komutunu uygulayın.

Kodlar:

Kod:

;--------------------------------------------------
; Kötü Rumuz Koruması
; Kodlamaların tamamı ve bazı dialog kodları el33t'e aittir...
; Dialog hazırlaması bana aittir...
; /KötüRumuz Yazarak Çalıştırabilirsiniz...
; [Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]
;---------------------------------------------------------
alias kötürumuz { if (!$dialog(kötürumuz)) dialog -m kötürumuz kötürumuz }
dialog kötürumuz {
  title "Kötü Rumuz Koruması"
  size -1 -1 200 180
  option dbu
  text "..:: Rumuz Listesi ::..", 999, 20 10 60 10
  combo 1, 5 20 90 130
  button "Ekle (+)", 2, 4 146 27 13
  button "Çıkar (-)", 3, 32 146 27 13
  button "Temizle (!)", 4, 60 146 35 13
  box "Seçenekler", 5, 101 17 93 40
  check "OP olduğumda tarama yap!", 6, 106 28 73 10
  check "Yeni rumuz kötüyse at!", 7, 106 40 70 10
  button "?", 8, 182 28 9 9
  button "?", 9, 182 40 9 9
  box "Kick Mesajınız", 10, 101 60 93 40
  edit "", 11, 106 76 83 10, autohs
  box "Açıklamalar", 12, 101 103 93 55
  text "Kötü Rumuz Koruması  [Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]              S1y4H", 13, 106 110 85 40
  link "[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]", 14, 108 164 52 15
  button "Kapat!", 15, 168 161 27 13
  text "..:: Kötü Rumuz Koruması ::..", 16, 13 165 80 10,disable
}
on *:dialog:kötürumuz:*:*:{
  if ($devent == init) {
    loadbuf -o $dname 1 $shortfn(nickler.txt) | did -c $dname 1 1
    if (%oto-tara == on) { did -c kötürumuz 6 }
    if (%NickDeğiş == on) { did -c kötürumuz 7 }
    did -a $dname 11 %kckmsg
  }
  if ($devent == sclick) {
    if ($did == 2) {
      var %kötürmz = $did(1).text
      if $read(nickler.txt,w,%kötürmz) {
        echo -a $timestamp *** Eklemek istediğiniz rumuz listede mevcut.
      }
      else {
        write nickler.txt %kötürmz | did -a $dname 1 %kötürmz | did -d $dname 1 $did(1).text
      }
    }
    if ($did == 3) {
      if $read(nickler.txt,w,$did(1).seltext) { write $+(-dl,$readn) nickler.txt | did -d $dname 1 $did(1).sel }
    }
    if ($did == 4) {
      if ($$?!="Bütün listeyi silmek istediğinizden emin misiniz?" == $true) { set %satırsayısı $lines(nickler.txt) | write -c nickler.txt | did -r $dname 1 | echo -a $timestamp *** Listedeki  $+ %satırsayısı $+  adet rumuz silindi. | unset %satırsayısı } | else { return }
    }
    if ($did == 8) {
      did -a $dname 13 +o modunu aldığınızda otomatik olarak kötü rumuz arar, bulunanları Nick!*@* şeklinde banlayıp atar. Özellikle kanala girdiğinizde (@ olursanız) oto. tarama yapacağından işinize yaracaktır.
    }
    if ($did == 9) {
      did -a $dname 13 @ olduğunuz kanallarda kullanıcı nick değiştirdiğinde seçtiği yeni rumuz listedeki tanımlamalarınızdan biriyle uyuşursa @ olduğunuz tüm kanallarda Nick!*@* ban şeklinde uzaklaştırılır.
    }
    if ($did == 6) {
      if (%oto-tara == off) { .set %oto-tara on | .enable #oto-tara | echo -a $timestamp *** Otomatik rumuz tarama 4aktif. }
      elseif (%oto-tara == on) { .set %oto-tara off | .disable #oto-tara | echo -a $timestamp *** Otomatik rumuz tarama 4kapatıldı. }
    }
    if ($did == 7) {
      if (%NickDeğiş == off) { .set %NickDeğiş on | .enable #NickDeğiş | echo -a $timestamp *** Yeni kötü rumuz koruması 4aktif. }
      elseif (%NickDeğiş == on) { .set %NickDeğiş off | .disable #NickDeğiş | echo -a $timestamp *** Yeni kötü rumuz koruması 4kapatıldı. }
    }
    if ($did == 14) {
      run [Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]
    }
    if ($did == 15) {
      if ($did(11) == $Null) {
        echo -a $timestamp *** Kick Mesajı belirlenmedi, orjinal mesaj kullanılacak.
        dialog -x kötürumuz kötürumuz
        set %kckmsg 4Rumuzunuz 1kanal seviyesine uygun olmayan nitelikler taşımaktadır. 4/Nick YeniRumuz 1komutuyla rumuzunuzu değiştirmeden kanala giriş yapamazsınız.
      }
      else {
        set %kckmsg $did(11)
        dialog -x kötürumuz kötürumuz
      }
    }
  }
}
;--------------------
; Kodlamalar...
;--------------------
on @*:join:#:if $kotunick($nick) { mode # +b $nick | kick # $nick %kckmsg }
#NickDeğiş on
on *:NICK:{ if $kotunick($newnick) { var %_ = 1, %< = $v1 | while $comchan($newnick,%_) { if $me isop $v1 { mode $v2 +b %< | kick $v2 $newnick %kckmsg } | inc %_ } } }
#NickDeğiş end
alias kotunick { var %_ = 1 | while $read(nickler.txt,%_) { if $v1 iswm $1 { return $v1 } | inc %_ } | return $false }
alias krt {
  if $1 ischan && $me isop $1 {
    var %` = $lines(Nickler.txt)
    while %` {
      if $fline($1,$read(Nickler.txt,%`),0,1) >= 1 { var %~ = $ifmatch | while %~ { if $line($1,$fline($1,$read(Nickler.txt,%`),%~,1),1) isreg $1 { mode $1 +b $+($read(Nickler.txt,%`),!*@*) | kick $1 $line($1,$fline($1,$read(Nickler.txt,%`),%~,1),1) %kckmsg } | dec %~ } }
      dec %`
    }
  }
}
#oto-tara on
on *:OP:#:if $opnick == $me { krt $chan }
#oto-tara end
;-----------------------------------------
on *:LOAD:{
  echo -a $timestamp *** Kötü Rumuz Koruması başarıyla yüklendi.
  echo -a $timestamp *** S1y4H
  run notepad.exe nickler.txt
  set %oto-tara on
  set %NickDeğiş on
  set %kckmsg 4Rumuzunuz 1kanal seviyesine uygun olmayan nitelikler taşımaktadır. 4/Nick YeniRumuz 1komutuyla rumuzunuzu değiştirmeden kanala giriş yapamazsınız.
}

on *:UNLOAD:{
  echo -a $timestamp *** Kötü Rumuz Koruması kaldırıldı.
  unset %oto-tar
  unset %NickDeğiş
  unset %kckmsg
}

Kodda herhangi bir sorun çıkarsa lütfen bu başlıkta belirtin...

тєαм 04 Şubat 2007 02:42

Yanıt: Kötü Rumuz Koruması...
 
Emeğine Sağlık. Güzel...

RapStar 04 Şubat 2007 11:15

Yanıt: Kötü Rumuz Koruması...
 
[00:14] *** mIRC versiyonunuz çok düşük. [Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...] adresinden son sürüm mIRC edinin.

Hangi Versiyonlarda Çalışıyor Kardeş ?

тєαм 04 Şubat 2007 11:53

Yanıt: Kötü Rumuz Koruması...
 
Kod:


if ($version < 6.17) {

sanırım mIRC 6.17'nin üzerlerinde çalışıyor.

TiPiTiP 04 Şubat 2007 11:54

Yanıt: Kötü Rumuz Koruması...
 
Version engellemesini sildim, şimdi yüklediğinde çalışır. Yalnız yine de versiyonunun çok eski olmamasına dikkat et. ($v1, $v2 gibi identifierların çalışması açısından...)

тєαм 04 Şubat 2007 12:10

Yanıt: Kötü Rumuz Koruması...
 
Sanırım böyle daha iyi :) bilmeyenler açısından en azından çalışmıyor gibi post mesajlarından kurtulmuş olursun az da olsa
:)

RapStar 04 Şubat 2007 17:26

Yanıt: Kötü Rumuz Koruması...
 
:) Çalışmasına Birşey Demedim Bende Versiyon 6,0 Ama Kod Çalışmadı Sanırım Versiyon Eski Geldi. Eğer Çalışıyorsa Güzel Paylaşım. Ben Beğendim Yani.
if ($version < 6.17) {
Bu Kısmı 6.0 Yaptım Denedim Yine Çalışmadı Sanırım Bende Eski :/

тєαм 04 Şubat 2007 17:40

Yanıt: Kötü Rumuz Koruması...
 
Code'yi baştan alıp denermisin ? RapStar

hami 14 Mart 2007 17:51

Cevap: Kötü Rumuz Koruması...
 
Ya Çok güzelde bu mesala sadece ekledıgım nicklerı atıyor örnek:''salak''ekledım ya ''salakkk''ı atmıyor.. ''salak'' gecen cümleleri atması için ne yapmam gerekiyor Yardım edebilirmisiniz bana.?

MavipikSeL 14 Mart 2007 17:53

Cevap: Kötü Rumuz Koruması...
 
Alıntı:

hami Nickli Üyeden Alıntı
Ya Çok güzelde bu mesala sadece ekledıgım nicklerı atıyor örnek:''salak''ekledım ya ''salakkk''ı atmıyor.. ''salak'' gecen cümleleri atması için ne yapmam gerekiyor Yardım edebilirmisiniz bana.?

Wilcard kullanmalısın. Örneğin bahsettiğin salak kelimesini atması için, *salak* olarak eklemelisin.


Tüm Zamanlar GMT +3 Olarak Ayarlanmış. Şuanki Zaman: 11:37.

Powered by vBulletin® Version 3.8.11
Copyright ©2000 - 2025, vBulletin Solutions, Inc.
Search Engine Friendly URLs by vBSEO
Copyright ©2004 - 2025 IRCForumlari.Net Sparhawk