IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası
Sayfa 2 Toplam 2 Sayfadan 1 2
Konuya ait 40 Mesajı başka Sayfada göster

IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası (https://www.ircforumlari.net/)
-   mIRC Scripting Hazır Kodlar (https://www.ircforumlari.net/mirc-scripting-hazir-kodlar/)
-   -   Bigtext. IRC'te büyük yazmak (https://www.ircforumlari.net/mirc-scripting-hazir-kodlar/332625-bigtext-ircte-buyuk-yazmak.html)

oLd 22 Haziran 2010 15:04
@[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...] ,

Kanal ve nick listesi olan sag kösede genisligini çok fazlasiyla açmissiniz. Bu sebepten dolayida, yaziya sol tarafa dogru sıkıstırmıs ve siz ne kadar kısa kelime yazsanizda, aldiginiz sonucu sürekli alirsiniz.

Simdi siz, sag kösedeki Nick ve kanal listesini genisimini küçültün ve tekrardan deneyin.
Eger yine olmuyorsa, [Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...] adresinden Türkçe mIRC'i indirip deneyiniz.

iyi sanslar.

CLubber 14 Mayıs 2011 17:07
Cevap: Bigtext. IRC'te büyük yazmak
 
Çok güzel bir çalışma, elinize sağlık :)

Paint 13 Eylül 2011 02:43
Cevap: Bigtext. IRC'te büyük yazmak
 
/bigtext 6,8 S e l a m yazarak aldığım sonuç

[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]

Biraz renklerle yazmaya çalışırsanız iyi sonuç alırsınız.

WingmaN 16 Eylül 2011 02:51
Cevap: Bigtext. IRC'te büyük yazmak
 
Buyrun, sorunları giderildi.
Kod:
alias bigtext {
  if (!$1) {
    echo -ace info * BigText: Insufficient Parameters.
    return
  }
  tokenize 9 $1-
  if ($0 == 1) { var %fc = 01, %bc = 00, %fs = 10, %ff = Fixedsys }
  else {
    if ($3) { var %fc = $gettok($2,1,32), %bc = $gettok($2,2,32), %fs = $gettok($3,1,32), %ff = $gettok($3,2-,32) }
    else {
      if ($gettok($2,2-,32) isnum) { var %fc = $gettok($2,1,32), %bc = $gettok($2,2,32), %fs = 10, %ff = Fixedsys }
      else { var %fs = $gettok($2,1,32), %ff = $gettok($2,2-,32), %fc = 01, %bc = 00 }
    }
  }
  if (%bc !isnum 0-15) { %bc = 00 }
  if (%fc !isnum 0-15) { %fc = 01 }
  if (!%ff || !$isfontinstalled($qt(%ff))) { %ff = Fixedsys }
  if (!%fs || %fs !isnum) { %fs = 10 }
  var %text = $1, %i 0, %y 0
  %fc = $base(%fc,10,10,2)
  %bc = $base(%bc,10,10,2)
  window -hp @bigtext
  drawfill -r @bigtext $color(%bc) $color(%bc) 0 0
  drawtext -brp @bigtext $color(%fc) $color(%bc) $qt(%ff) %fs 0 0 %text
  var %heightend = $height(%text,%ff,%fs) + 1, %widthend = $width(%text,%ff,%fs,0,1) + 1
  while (%y <= %heightend) {
    var %x 0, %s = $null
    while (%x <= %widthend) {
      var %c = $iif($getdot(@bigtext,%x,%y) != $color(%bc),$coc($v1,%fc),%bc)
      if (%lc != %c) {
        var %lc = %c
        %c = $+($chr(3),%c,$chr(44),%c)
      }
      else %c = $null
      %s = $+(%s,%c,@)
      inc %x
    }
    %s = $+($chr(3),%bc,$chr(44),%bc,@,%s,$chr(3),%bc,$chr(44),%bc,@)
    if ($regex(%s,/\x03(?! $+ %bc $+ )/)) {
      .timerbig $+ %i 1 $calc(%i * 2) msg $active %s
      inc %i
    }
    inc %y
  }
  window -c @bigtext
}
alias coc {
  var %i 0
  while (%i < 16) {
    if ($color(%i) == $1) return $base(%i,10,10,2)
    inc %i
  }
  return $base($2,10,10,2)
}
;Alias by praetorian.
alias isfontinstalled {
  var %w = @isfontinstalled,%f = isfontinstalled.bmp
  window -ak0pBfh +d %w -1 -1 200 100
  drawfill -r %w $rgb(0,0,0) $rgb(0,0,0) 0 0
  drawtext -r %w $rgb(255,255,255) "this is surely not the name of an installed font" -9 5 5 test.
  drawsave %w %f
  var %crc = $crc(%f)
  clear %w
  drawfill -r %w $rgb(0,0,0) $rgb(0,0,0) 0 0
  drawtext -r %w $rgb(255,255,255) $+(",$1,") -9 5 5 test.
  drawsave %w %f
  var %crc2 = $crc(%f)
  .remove %f
  window -c %w
  if (%crc != %crc2) { return $true }
  else { return $false }
}
Gene iş başa düştü anlaşılan. :)

FirariSevdam 23 Eylül 2011 23:22
Cevap: Bigtext. IRC'te büyük yazmak
 
* /goto: 'son' bulunamadı (Satır 50, script2.txt)

Hatasını aLıyorum..

WingmaN 24 Eylül 2011 05:06
Cevap: Bigtext. IRC'te büyük yazmak
 
öle bi kod yok, kodların içinde onu nasıl aldın kardeşim?

muratt_aziz 25 Eylül 2011 13:30
Cevap: Bigtext. IRC'te büyük yazmak
 
Alıntı:
FirariSevdam Nickli Üyeden Alıntı (Mesaj 1040838482)
* /goto: 'son' bulunamadı (Satır 50, script2.txt)

Hatasını aLıyorum..
Satır 50, script2.txt
bu satıra dikkat edersen hatanın olduğu kodu bulabilrisin remotende script2.txt sayfasını ac 50 satıra bak kolay gelsin..

muratt_aziz 25 Eylül 2011 13:31
Cevap: Bigtext. IRC'te büyük yazmak
 
Elinize sağlık arkadaşlar güzel olmus

fav 28 Eylül 2011 18:34
Cevap: Bigtext. IRC'te büyük yazmak
 
SANIRIM KENARLARDA BİRAZ SORUN VAR BU RESIMDEKİ RENK FORMATI 8,4 YANDAKİ BEYAZLIKLAR ayarlanabilirmi[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]


Tüm Zamanlar GMT +3 Olarak Ayarlanmış. Şuanki Zaman: 01:42.
Sayfa 2 Toplam 2 Sayfadan 1 2
Konuya ait 40 Mesajı başka Sayfada göster

Powered by vBulletin® Version 3.8.11
Copyright ©2000 - 2025, vBulletin Solutions, Inc.
Search Engine Friendly URLs by vBSEO
Copyright ©2004 - 2025 IRCForumlari.Net Sparhawk