IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası
Sayfa 1 Toplam 4 Sayfadan 1 234
Konuya ait 40 Mesajı başka Sayfada göster

IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası (https://www.ircforumlari.net/)
-   mIRC Scripting Hazır Kodlar (https://www.ircforumlari.net/mirc-scripting-hazir-kodlar/)
-   -   !arsiv [IP|Nick] (https://www.ircforumlari.net/mirc-scripting-hazir-kodlar/379627-arsiv-ip-nick.html)

Difuzyon 28 Ocak 2011 22:41
!arsiv [IP|Nick]
 
Merhabalar,

Sunucuya giriş satırı:
-irc.sunucu.adı- *** Notice -- Client connecting on port 6667: Cenk (paramilite@94.123.128.183) [clients]
Nick değişimleri satırı:
-irc.sunucu.adı- *** Notice -- Cenk (paramilite@94.123.128.183) has changed his/her nickname to Dify

Sunucuda IRCop düzeyinde bulunan mirc botunuz yukarıdaki snotice satırlarını görebiliyorsa aşağıdaki kodu mirc botunuzun remote kısmına eklemeniz halinde;sunucuya giriş yapan veya sunucuda nick değiştiren nicki,ident bilgisini ve ip numarasını kayıt altına alacaktır.
Bir nevi giriş yapan tüm nick ve ip noları arşivleyecektir.

Bu kayıtlar bir metin belgesine yazdırılıp istem halinde
(#KANAL'da uygulanacak komutlar)
!arsiv IP
veya
!arsiv Nick
komutlarını belirttiğiniz #kanal da uyguladığınızda istemde bulunan verileri filtreleyip size sunacaktır.

Kod:
on *:snotice:*:{
  if (*client*connect* iswm $1-) {
    var %difyip = $remove($token($10,2,64),$chr(41)), %difynick = $9, %difyident = $remove($token($10,1,64),$chr(40))
    if $read(arsiv.txt,w,$+(*,%difyip,$chr(32),%difynick,$chr(32),*)) { write $+(-dl,$readn) arsiv.txt }
    write arsiv.txt %difyip %difynick 14Ident: %difyident 02Son Girişi: $+($time,-,$date)
  }
  elseif (*changed*his*her*nickname* iswm $1-) {
    var %difyzip = $remove($token($5,2,64),$chr(41)), %difynickz = $11, %difyidentz = $remove($token($5,1,64),$chr(40))
    if $read(arsiv.txt,w,$+(*,%difyzip,$chr(32),%difynickz,$chr(32),*)) { write $+(-dl,$readn) arsiv.txt }
    write arsiv.txt %difyzip %difynickz 14Ident: %difyidentz 02Son Girişi: $+($time,-,$date)
  }
}
;kod içerisindeki #KANAL kısmını kendinize göre değişebilirsiniz
on *:text:!arsiv &:#KANAL:{
  if $regex($2,/^\d+.\d+/) {
    if $read(arsiv.txt,r,/^\Q $+ $2 $+ \E\s/) {
      msg $chan $2 arşivi listeleniyor
      filter -ffcg arsiv.txt depo.txt /^\Q $+ $2 $+ \E\s/
      play $chan depo.txt 750
    }
    else { msg $chan $2 arşivde bulunmuyor }
  }
  if $regex($2,/^[^\d]/) {
    if $read(arsiv.txt,r,/[^:]\s\Q $+ $2 $+ \E\s/i) {
      msg $chan $2 arşivi listeleniyor
      filter -ffcg arsiv.txt depo.txt /[^:]\s\Q $+ $2 $+ \E\s/i
      play $chan depo.txt 750
    }
    else { msg $chan $2 arşivde bulunmuyor }
  }
}
Uygulama Sonuçları:

[22:09] <Cenk> !arsiv eCe
[22:09] <@Difuzyon> eCe arşivde bulunmuyor

[22:10] <Cenk> !arsiv seref06
[22:10] <@Difuzyon> seref06 arşivi listeleniyor
[22:10] <@Difuzyon> 94.123.128.183 Seref06 Ident: trsohbet Son Girişi: 22:01:20-28/01/2011

[22:10] <Cenk> !arsiv 85.102.42.208
[22:10] <@Difuzyon> 85.102.42.208 arşivi listeleniyor
[22:10] <@Difuzyon> 85.102.42.208 deneme12345 Ident: Cenk Son Girişi: 21:37:39-28/01/2011
[22:10] <@Difuzyon> 85.102.42.208 deneme123 Ident: Cenk Son Girişi: 21:41:04-28/01/2011
[22:10] <@Difuzyon> 85.102.42.208 deneme1234 Ident: Cenk Son Girişi: 21:49:58-28/01/2011
[22:10] <@Difuzyon> 85.102.42.208 Cenk Ident: Cenk Son Girişi: 22:07:49-28/01/2011


Hoşca paylaşımlar...

Nokta 28 Ocak 2011 22:46
Cevap: !arsiv [IP|Nick]
 
eline sağlık

onNes 28 Ocak 2011 22:55
Cevap: !arsiv [IP|Nick]
 
Maşallah bu kadar işin içinden birşeyler çıkarmak :) güzel emeğine sağlık

Difuzyon 28 Ocak 2011 23:02
Cevap: !arsiv [IP|Nick]
 
Teşekkür ederim, oper düzeyindeki erişimlerle ilgili fikir edinmede bana kapılarını açtığın için.

Boreas 29 Ocak 2011 00:43
Cevap: !arsiv [IP|Nick]
 
Hocam emeğinize sağlık güzel bir çalışma olmuş, bunu bot'a deilde kendi mircimize eklediğimizde çalışması için nasıl bişey yapmalıyız.

xyL 29 Ocak 2011 11:00
Cevap: !arsiv [IP|Nick]
 
Güzel çalışma olmuş, tebrik ederim.

Heavenly 29 Ocak 2011 13:19
Cevap: !arsiv [IP|Nick]
 
Alıntı:
Boreas Nickli Üyeden Alıntı (Mesaj 1040663420)
Hocam emeğinize sağlık güzel bir çalışma olmuş, bunu bot'a deilde kendi mircimize eklediğimizde çalışması için nasıl bişey yapmalıyız.
Kod:
on *:snotice:*:{
  if (*client*connect* iswm $1-) {
    var %difyip = $remove($token($10,2,64),$chr(41)), %difynick = $9, %difyident = $remove($token($10,1,64),$chr(40))
    if $read(arsiv.txt,w,$+(*,%difyip,$chr(32),%difynick,$chr(32),*)) { write $+(-dl,$readn) arsiv.txt }
    write arsiv.txt %difyip %difynick 14Ident: %difyident 02Son Girişi: $+($time,-,$date)
  }
  elseif (*changed*his*her*nickname* iswm $1-) {
    var %difyzip = $remove($token($5,2,64),$chr(41)), %difynickz = $11, %difyidentz = $remove($token($5,1,64),$chr(40))
    if $read(arsiv.txt,w,$+(*,%difyzip,$chr(32),%difynickz,$chr(32),*)) { write $+(-dl,$readn) arsiv.txt }
    write arsiv.txt %difyzip %difynickz 14Ident: %difyidentz 02Son Girişi: $+($time,-,$date)
  }
}
;kod içerisindeki #KANAL kısmını kendinize göre değişebilirsiniz
on *:input:#: {
  if $1 == !arsiv {
    if $regex($2,/^\d+.\d+/) {
      if $read(arsiv.txt,r,/^\Q $+ $2 $+ \E\s/) {
        msg $chan $2 arşivi listeleniyor
        filter -ffcg arsiv.txt depo.txt /^\Q $+ $2 $+ \E\s/
        play $chan depo.txt 750
      }
      else { msg $chan $2 arşivde bulunmuyor
      }
    }
    if $regex($2,/^[^\d]/) {
      if $read(arsiv.txt,r,/[^:]\s\Q $+ $2 $+ \E\s/i) {
        msg $chan $2 arşivi listeleniyor
        filter -ffcg arsiv.txt depo.txt /[^:]\s\Q $+ $2 $+ \E\s/i
        play $chan depo.txt 750
      }
      else { msg $chan $2 arşivde bulunmuyor }
    }
  }
}

onNes 29 Ocak 2011 21:41
Cevap: !arsiv [IP|Nick]
 
Alıntı:
Difuzyon Nickli Üyeden Alıntı (Mesaj 1040663373)
Teşekkür ederim, oper düzeyindeki erişimlerle ilgili fikir edinmede bana kapılarını açtığın için.
Ne demek herzaman, küçükte olsa katkımız olsun.

Heavenly 30 Ocak 2011 14:51
Cevap: !arsiv [IP|Nick]
 
Yanlız bizim sunucuda arsivlerken böyle yapıyor
mIRC2011@88.227.69.14) 14Ident: 02Son Girişi: 14:45:22-30/01/2011
(Csohbet@78.187.223.116) 14Ident: 02Son Girişi: 14:45:22-30/01/2011

ve !arsiv yazdığımızda bir sonuç alamıyoruz

Giriş mesajları bu şekilde

(14:46:50) -access.mirctr.net- *** Notice -- Client connecting at web.mirctr.net: burak01 (Csohbet@213.43.67.237)
-
(14:46:52) -access.mirctr.net- *** Notice -- Client exiting at irc.mirctr.net: Bilinmez`!TurkmIRC@78.165.84.37 (4mIRCTR.2NET 2Birlikte, daha 4iyiye!)

Nick değişimide bu şekilde

(13:21:38) 2°4°12° 5Nick Change: 2(4HelpClient-2102) 2(
Bu forumdaki linkleri ve resimleri görebilmek için en az 25 mesajınız olması gerekir.
2)5 is now known as 2(4HeavenLy2)

Difuzyon 30 Ocak 2011 15:23
Cevap: !arsiv [IP|Nick]
 
var %difyip = $remove($token($10,2,64),$chr(41)), %difynick = $9, %difyident = $remove($token($10,1,64),$chr(40))
satırını aşağıdaki gibi yapmalısın:
var %difyip = $remove($token($9,2,64),$chr(41)), %difynick = $8, %difyident = $remove($token($9,1,64),$chr(40))

Nick değişim kısmında ise snotice mesajının orjinalini görmek lazım,edit gibi duruyor.


Tüm Zamanlar GMT +3 Olarak Ayarlanmış. Şuanki Zaman: 12:16.
Sayfa 1 Toplam 4 Sayfadan 1 234
Konuya ait 40 Mesajı başka Sayfada göster

Powered by vBulletin® Version 3.8.8 Beta 3
Copyright ©2000 - 2024, vBulletin Solutions, Inc.
Search Engine Friendly URLs by vBSEO
Copyright ©2004 - 2024 IRCForumlari.Net