IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası

s.a. arkadaşlar kendi yazmış olduğum bir nick uyarı diyaloğunu paylaşmak istedim

özelliklerini anlatırsak kodda bir list mevcut uayrı vermesini istemediğiniz nicki ekleyip kurtulabilirsin ayrıca

flaşh ve kanalda yeşil ışık yanma özellikleri açıp kapamalı gibi ayarlanabilir bir kod
iyi kullanımlar.

Yenilendi
hatırlatma nickiniz yazıldığında ses çalması için sounds dosyasında seniseviyorum.wav ses dosyası olması lazım.

PHP- Kodu:

   menu channel,query,nicklist {

  -

  H » Nick Uyari Menüsü:/uyar

  -

}

alias uyar { .dialog -m uyar uyar }

dialog uyar {

  title "KiLLed Nick Uyarı Menüsü"

  size -1 -1 145 144

  option dbu

  edit "", 2, 10 15 60 10, return autohs

  list 3, 10 28 60 68, sort size

  button "Ekle", 4, 78 15 33 10

  button "SiL", 5, 78 28 33 10

  check "Uyarıyı Aç/Kapat", 10, 78 60 60 10

  check "Flash Aç/Kapat", 13, 78 72 60 10

  check "Yesil isik Aç/Kapat", 14, 78 84 60 10

  box "Nick Şeklinde Ekleyiniz...", 9, 6 4 134 110

  text " Eklenen nick nickinizi yazınca uyarı vermeyecektir", 11, 6 120 134 8

  button "Tamam", 12, 6 132 134 10, ok

  check "Ses Çal Aç/Kapat", 6, 78 48 60 10

  edit "", 7, 10 100 20 10, return autohs

  Text "Ctrl + Kod Kullanarak nick satırına Renk ver", 8, 34 101 104 8

}

on *:dialog:uyar:*:*:{

  if ($devent == edit) {

    if ($did == 7) { set %renks $did(7) }

  }

  if ($devent == sclick) {

    if ($did($dname,10).state == 1) { set %nuyar 1 } | else { set %nuyar 0 }

    if ($did($dname,13).state == 1) { set %fuyar 1 } | else { set %fuyar 0 }

    if ($did($dname,14).state == 1) { set %yiuyar 1 } | else { set %yiuyar 0 }

    if ($did($dname,6).state == 1) { set %suyar 1 } | else { set %suyar 0 }

    if ($did == 4) { .did -a uyar 3 $did(uyar,2) | .auser sus $did(uyar,2) | .did -r uyar 2 }

    if ($did == 5) { .ruser sus $did(uyar,3).seltext | .did -d uyar 3 $did(uyar,3).sel }

  }

  if ($devent == init) {

    if (%nuyar == 1) { did -c uyar 10 }

    if (%fuyar == 1) { did -c uyar 13 }

    if (%yiuyar == 1) { did -c uyar 14 }

    if (%suyar == 1) { did -c uyar 6 }

    did -ra $dname 7 %renks

    if $ulist(*,sus,0) > 0 {

      var %i 1

      while %i <= $ulist(*,sus,0) {

        .did -a uyar 3 $ulist(*,sus,%i)

        inc %i 

      }

    }

  }

}

on ^*:TEXT:$(* $+ $me $+ *):#:{ 

  if (%nuyar == 1) {

    if ($ulist($nick,sus,0) >= 1) { return }

    if ($active != $chan) {

      echo -a $timestamp 2 $nick $chan kanalında senden bahsediyor !!

      echo -a $timestamp 2 Yazdığı mesaj: " $+ $1- $+ " 

      echo $chan $timestamp 4[ < $+ $nick $+ > 4] %renks $1- 

      haltdef

    } 

    if (%suyar == 1) {

      if ($ulist($nick,sus,0) >= 1) { halt }

      if ($active != $chan) {

        .splay sounds\seniseviyorum.wav 

      }

    }

    if (%fuyar == 1) {

      if ($ulist($nick,sus,0) >= 1) { halt }

      else {

        flash $chan kanalından $nick size sesleniyor.

      }

    }

    if (%yiuyar == 1) {

      if ($ulist($nick,sus,0) >= 1) { halt }

      else {

        window -g2 #

      }

    }

  }

}

;-

on *:TEXT:$(* $+ $me $+ *):?:{ 

  if (%nuyar == 1) {

    if ($ulist($nick,sus,0) >= 1) { return }

    if ($active != $nick) {

      echo -a $timestamp 2 $nick Özelde senden bahsediyor !!

      echo -a $timestamp 2 Yazdığı mesaj: " $+ $1- $+ " 

    } 

  }

  if (%fuyar == 1) {

    if ($ulist($nick,sus,0) >= 1) { halt }

    else {

      flash $nick özelden size sesleniyor.

    }

  }

}

Koddan 2 görüntü

[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]

[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]