IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası - Oper

Selam,

Forumda benim istediğim gibi hemen hemen tüm komutlar için uygun bir Oper - Admin diyalogu bulamadım. Bunun üzerine de kendime yeni bir diyalog oluşturdum. Çoğu oper/adminin işlemlerinde kullanmasına elverişli bir diyalog çıktı ortaya.

Tüm OS komutları (flag erişimlerine göre kısıtlamalı), yüksek öncelikli NS - CS komutları (forbid, suspend vb.) ve client komutları vardır. Ayrıca ban/yasaklama kaldırma seçenekleri de mevcuttur.

Sağ klik menüsünde eğer ki en az +o flagınız varsa aktif olan seçenek ile erişim yapabilirsiniz.
Kod:
menu status,query,channel { 

  Oper/Admin Dailog:dialog $iif($dialog(oa_dia),-v,-m) oa_dia oa_dia

}

dialog oa_dia {

  title "Oper - Admin İşlemleri"

  size -1 -1 260 250

  option dbu

  box "Host/Ident/FullName İşlemleri:", 1, 5 5 95 48

  edit "", 2, 25 15 70 10, autohs

  edit "", 3, 10 39 85 10, autohs

  text "Nick:", 4, 10 16 15 8

  button "Host", 5, 12 27 25 10

  button "Ident", 6, 39 27 25 10

  button "FullName", 7, 66 27 25 10

  box "SaJoin - SaPart - SaMode", 8, 5 53 95 42

  text "Nick:", 9, 10 63 15 8

  text "Kanal:", 10, 10 73 15 8

  text "Mod:", 11, 10 83 15 8

  edit "", 12, 25 62 40 10, autohs

  edit "", 13, 25 72 40 10, autohs

  edit "", 14, 25 82 40 10, autohs

  button "SaJoin", 15, 70 61 25 10

  button "SaPart", 16, 70 71 25 10

  button "SaMode", 17, 70 81 25 10

  box "(X):Line && OS Yasaklama İşlemleri:", 18, 105 5 150 90

  text "Nick` - IP* - Ident~ - FullName^:", 19, 111 16 80 8

  text "Sebep:", 20, 111 36 25 8

  text "Süre:", 21, 196 16 25 8

  edit "", 22, 110 24 80 10, autohs

  edit "", 23, 110 44 80 10, autohs

  combo 24, 195 24 55 50, size drop

  button "Gline", 25, 110 58 25 10

  button "Kline", 26, 139 58 25 10

  button "Zline", 27, 110 72 25 10

  button "Gzline", 28, 139 72 25 10

  button "Kill", 29, 168 58 24 10

  button "Shun", 30, 168 72 24 10

  button "Akill*", 31, 196 58 25 10

  button "Sqline`", 32, 225 58 25 10

  button "Sgline~", 33, 196 72 25 10

  button "Szline^", 34, 225 72 25 10

  check "Banı/Yasağı Kaldır :", 35, 195 44 55 10, left

  text "Simgelenmiş işlemlerde diğer parametreler uygulanamaz.", 82, 110 84 140 8, disable center

  box "NickServ İşlemleri:", 83, 5 98 122 60

  text "Nick:", 36, 10 107 15 8

  text "Sebep:", 37, 10 119 20 8

  text "Şifre:", 84, 70 107 15 8

  edit "", 38, 30 106 35 10, autohs

  edit "", 39, 30 118 90 10, autohs

  edit "", 85, 85 106 35 10, autohs

  button "Nicki Sil", 40, 15 131 30 10

  button "Get Pass", 41, 50 131 30 10

  button "Forbid", 42, 85 131 30 10

  button "Suspend", 43, 52 144 30 10

  button "UnSuspend", 44, 85 144 33 10

  button "Şifre Değiştir", 45, 12 144 37 10

  box "ChanServ İşlemleri:", 86, 132 98 123 60

  text "Kanal:", 46, 138 107 20 8

  text "Sebep:", 47, 138 119 20 8

  text "Şifre:", 87, 198 107 15 8

  edit "", 48, 158 106 35 10, autohs

  edit "", 49, 158 118 90 10, autohs

  edit "", 88, 213 106 35 10, autohs

  button "Kanalı Sil", 50, 143 131 30 10

  button "Get Pass", 51, 178 131 30 10

  button "Forbid", 52, 213 131 30 10

  button "Suspend", 53, 181 144 30 10

  button "UnSuspend", 54, 214 144 33 10

  button "Şifre Değiştir", 55, 141 144 37 10

  box "OperServ İşlemleri:", 89, 5 160 250 85

  text "Nick:", 56, 15 230 20 8

  text "Kanal:", 57, 95 230 20 8

  text "Server:", 58, 175 230 20 8

  edit "", 59, 45 170 205 10, autohs

  edit "", 60, 35 229 50 10, autohs

  edit "", 61, 115 229 50 10, autohs

  edit "", 62, 195 229 50 10, autohs

  button "Global Mesaj", 63, 10 170 35 10

  button "Oper Ekle", 64, 28 185 30 10

  button "Oper Sil", 65, 63 185 30 10

  button "Oper List", 66, 98 185 30 10

  button "Admin Ekle", 67, 133 185 30 10

  button "Admin Sil", 68, 168 185 30 10

  button "Admin List", 69, 203 185 30 10

  button "Modları Sil", 70, 13 200 35 10

  button "Kanalı Boşalt", 71, 53 200 35 10

  button "Klonları Kille", 72, 93 200 35 10

  button "Kanalı Akille", 73, 133 200 35 10

  button "Kanal Listesi", 74, 173 200 35 10

  button "User Listesi", 75, 213 200 35 10

  button "Jupe", 76, 28 215 30 10

  button "Shutdown", 77, 63 215 30 10

  button "Update", 78, 98 215 30 10

  button "Quit", 79, 133 215 30 10

  button "ReHash", 80, 168 215 30 10

  button "ReStart", 81, 203 215 30 10

}

on *:dialog:oa_dia:init:*:{

  didtok $dname 24 44 30 dakika,1 saat,12 saat,1 gün,3 gün,14 gün,30 gün

  if a !isincs $usermode { did -b $dname 12-17,40-44,50-54,64,65,67,68,76-81 }

  if a isincs $usermode { did -a $dname 24 Kalıcı(+0) }

}

on *:dialog:oa_dia:sclick:5-7:{

  if $did(2) && $did(3) {

    if $did == 5 { chghost $did(2) $did(3) } 

    if $did == 6 { chgident $did(2) $did(3) } 

    if $did == 7 { chgname $did(2) $did(3) } 

  }

  did -r $dname 2,3

}

on *:dialog:oa_dia:sclick:15-17:{

  if $did(12) {

    if $did == 15 && $did(13) { sajoin $did(12) $did(13) }  

    if $did == 16 && $did(13) { sapart $did(12) $did(13) } 

    if $did == 17 && $did(14) { samode $did(13) $did(14) } 

  }

  did -r $dname 12-14

}

on *:dialog:oa_dia:sclick:25-34:{

  if $did(35).state != 1 {

    if $did == 25 { gline $oa_ip($did(22)) $iif($did(24), $süre_oa($did(24))) $iif($did(23), $did(23)) }

    if $did == 26 { kline $oa_ip($did(22)) $iif($did(24), $süre_oa($did(24))) $iif($did(23), $did(23)) }

    if $did == 27 { zline $oa_ip($did(22)) $iif($did(24), $süre_oa($did(24))) $iif($did(23), $did(23)) }

    if $did == 28 { gzline $oa_ip($did(22)) $iif($did(24), $süre_oa($did(24))) $iif($did(23), $did(23)) }

    if $did == 29 { if !$did(23) { noop $input(Bu işlem için sebep girmelisiniz.,ohud,Hata!) }

    else kill $oa_ip($did(22)) $did(23) }

    if $did == 30 { shun $oa_ip($did(22)) $iif($did(24), $süre_oa($did(24))) $iif($did(23), $did(23)) }

    if $did == 31 { if !$did(23) { noop $input(Bu işlem için sebep girmelisiniz.,ohud,Hata!) }

    else .os akill add $iif($did(24), $süre_oa($did(24))) $oa_ip($did(22)) $did(23) } 

    if $did == 32 { if !$did(23) { noop $input(Bu işlem için sebep girmelisiniz.,ohud,Hata!) }

    else .os sqline add $iif($did(24), $süre_oa($did(24))) $did(22) $did(23) }

    if $did == 33 { if !$did(23) { noop $input(Bu işlem için sebep girmelisiniz.,ohud,Hata!) }

    else .os sgline add $iif($did(24), $süre_oa($did(24))) $iif($chr(32) isin $did(22), $qt($did(22))) $did(23) }

    if $did == 34 { if !$did(23) { noop $input(Bu işlem için sebep girmelisiniz.,ohud,Hata!) }

    else .os szline add $iif($did(24), $süre_oa($did(24))) $did(22) $did(23) }

  }

  if $did(35).state == 1 {

    if $istok(25.26.27.28.30,$did,46) { $did($did) $oa_ip($did(22)) }

    if $did == 31 { .os akill del $oa_ip($did(22)) }

    if $istok(32.33.34,$did,46) { .os $left($did($did),-1) del $did(22) }

  }

  did -r $dname 22,23

  did -u $dname 24

}

on *:dialog:oa_dia:sclick:35:{ did $iif($did(35).state == 1,-b,-e) $dname 23,24,29 }

on *:dialog:oa_dia:sclick:40-45:{ 

  if $did(38) {

    if $did == 40 { .ns dropnick $did(38) }

    if $did == 41 { .ns getpass $did(38) }

    if $did == 42 { .ns forbid $did(38) }

    if $did == 43 { if !$did(39) { noop $input(Bu işlem için sebep girmelisiniz.,ohud,Hata!) }

    else .ns suspend +0 $did(38) $did(39) }

    if $did == 44 { .ns unsuspend $did(38) }

    if $did == 45 { .ns set $did(38) password $did(85) }

  }

  did -r $dname 38,39,85

}

on *:dialog:oa_dia:sclick:50-54:{

  if $did(48) {

    if $did == 50 { .cs drop $iif($chr(35) !isin $did(48), $+(#,$did(48))) }

    if $did == 51 { .cs getpass $iif($chr(35) !isin $did(48), $+(#,$did(48))) }

    if $did == 52 { .cs forbid $iif($chr(35) !isin $did(48), $+(#,$did(48))) }

    if $did == 53 { if !$did(49) { noop $input(Bu işlem için sebep girmelisiniz.,ohud,Hata!) }

    else .cs suspend +0 $iif($chr(35) !isin $did(48), $+(#,$did(48))) $did(49) }

    if $did == 54 { .cs unsuspend $iif($chr(35) !isin $did(48), $+(#,$did(48))) }

    if $did == 55 { .cs set $did(48) password $did(88) }

  }

  did -r $dname 48,49,88

}

on *:dialog:oa_dia:sclick:63:{ if $did(59) { .os global $did(59) | did -r $dname 59 } }

on *:dialog:oa_dia:sclick:64-81:{

  if $did(60) {

    if $did == 64 { .os oper add $did(60) }

    if $did == 65 { .os oper del $did(60) }

    if $did == 67 { .os admin add $did(60) }

    if $did == 68 { .os admin del $did(60) }

    if $did == 72 { .os killclones $did(60) }

  }

  if $did(61) {

    if $did == 70 && $did(61) { .os clearmodes $did(61) all }

    if $did == 71 && $did(61) { .os clearchan $did(61) }

    if $did == 73 { .os akillchan kill +0 $did(61) $$?="Akill Mesajı Giriniz:" }

  }

  if $did == 69 { .os admin list }

  if $did == 66 { .os oper list }

  if $did == 74 { .cs list $$?="Liste İçin Maske Giriniz:" } 

  if $did == 75 { .ns list $$?="Liste İçin Maske Giriniz:" } 

  if $did == 76 && $did(62) { .os jupe $did(62) }

  if $did == 77 { .os shutdown }

  if $did == 78 { .os update }

  if $did == 79 { .os quit }

  if $did == 80 { .os rehash }

  if $did == 81 { .os restart }

  did -r $dname 60-62

}

alias -l süre_oa { 

  if gün isin $1- { return $+(+,$replace($1-,$+($chr(32),gün),d)) }

  if dk. isin $1- { return $+(+,$replace($1-,$+($chr(32),dakika),m)) }

  if saat isin $1- { return $+(+,$replace($1-,$+($chr(32),saat),h)) }

  else { return +0 }

}

alias -l oa_ip { 

  if !$1 { return $null }

  else { return $iif($regex($1,/(((\d{1,3}|\*)\.){3}(\d{1,3}|\*))/),$+(*@,$remove($regml(1),*@)),$1) }

}