IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası
Sayfa 1 Toplam 2 Sayfadan 1 2
Konuya ait 40 Mesajı başka Sayfada göster

IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası (https://www.ircforumlari.net/)
-   mIRC Scripting Hazır Kodlar (https://www.ircforumlari.net/mirc-scripting-hazir-kodlar/)
-   -   ileti yazıyor - iletildi - okundu vs. (https://www.ircforumlari.net/mirc-scripting-hazir-kodlar/761274-ileti-yaziyor-iletildi-okundu-vs.html)

CoCoRiCo 27 Ekim 2016 14:26
ileti yazıyor - iletildi - okundu vs.
 
paslarımızı dökelim birazcık..
eksik gedik bişiler görürseniz öneriniz de varsa başlık altına yazın..
iyi eglenceler.

Kod:
;*** Olaylar
on *:START: read_t
on *:CLOSE:?: { $iif($hget(read_t,$target),$read_t($target).cls) }
on *:OPEN:?: $read_t($nick).ilt
on *:ACTIVE:*: { if $window($active).type == Query { $read_t($active).akt  } }
;on *:APPACTIVE: { if $appactive && $window($active).type == Query { read_t  APP $window($active)  } }
on ^*:TEXT:*:?: {
  if $window($active) == $nick || $mouse.win == $nick { $read_t($nick).win }
  if $window($active) != $nick && $query($nick) { $read_t($nick).ilt }
  hadd -m read_t $nick $md5($1-)
}

;**** durum motoru
alias  read_t {
  if $prop == ilt { .timer_i 1 1 .ctcp $1 \\ccrc ilt  }
  if $prop == cls { .timer_o 1 1 .ctcp $1 \\ccrc ret  }
  if $prop == akt && $hget(read_t,$1) || $prop == win {  .timer_a 1 1 .ctcp $1 \\ccrc ok | hdel read_t $1 }
  if !$isid  {
    .timer_typ_w 0 3 read_t
    if $window($active).type == Query && $editbox($active,0)  && $md5($editbox($active,0)) != $hget(read_typ,$active)  {
      hadd -mu10 read_typ $active $md5($editbox($active,0))
      .ctcp $window($active) \\ccrc  typ
    }
  }
}

;**** eylem yorumlama

CTCP *:\\ccrc*:?: {
  haltdef
  if $2 == ilt { titlebar $nick iletildi.. }
  if $2 == ret { titlebar $nick reddedildi.! }
  if $2 == ok { titlebar $nick okundu }
  if $2 == typ { _typ $nick ileti yazıyor }
}

;**** ileti yaziyor animasyonu
alias _typ { 
  inc %:o
  if %:o < 5 { titlebar $1 $+($active Ileti yaziyor,$left(....,%:o),$gettok(|./.\,$r(1,3),46)) | .timer_anim -m 1 300 _typ  }
  if %:o > 4 { unset %:o | titlebar $1 }
}

Chelt 27 Ekim 2016 15:02
Cevap: ileti yazıyor - iletildi - okundu vs.
 
@[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...] paslanmaz çelik gibisin. Eline sağlık

CoCoRiCo 28 Ekim 2016 08:40
Cevap: ileti yazıyor - iletildi - okundu vs.
 
bazı hataları düzelttim yenisi de şudur.
Kod:
;*** Olaylar
on *:START: read_t
on *:CLOSE:?: { if *serv* !iswm $nick { $iif($hget(read_t,$target),$read_t($target).cls) } }
on *:OPEN:?:  { if *serv* !iswm $nick { $read_t($nick).ilt } }
on *:ACTIVE:*: { if $window($active).type == Query &&  *serv* !iswm $nick { $read_t($active).akt  } | else titlebar }
;on *:APPACTIVE: { if $appactive && $window($active).type == Query { read_t  APP $window($active)  } }

on ^*:TEXT:*:?: {
  if *serv* !iswm $nick {
    if $window($active) == $nick || $mouse.win == $nick { $read_t($nick).win }
    if $window($active) != $nick && $query($nick) { $read_t($nick).ilt }
    hadd -m read_t $nick $md5($1-)
  }
}

;**** durum motoru
alias  read_t {
  if $prop == ilt { .timer_i 1 1 .ctcp $1 \\ccrc ilt  }
  if $prop == cls { .timer_o 1 1 .ctcp $1 \\ccrc ret  }
  if $prop == akt && $hget(read_t,$1) || $prop == win { 
  .timer_a 1 1 .ctcp $1 \\ccrc ok | hdel read_t $1 }
  if !$isid  {
    .timer_typ_w 0 3 read_t
    if $window($active).type == Query && $editbox($active,0)  && $&
      $md5($editbox($active,0)) != $hget(read_typ,$active)  {
      hadd -mu10 read_typ $active $md5($editbox($active,0))
      .ctcp $window($active) \\ccrc  typ
    }
  }
}

;**** eylem yorumlama

CTCP *:\\ccrc*:?: {
  haltdef
  if $2 == ilt &&  $window($nick) { titlebar $nick Ileti Gonderildi. }
  if $2 == ret &&  $window($nick) { titlebar $nick Ileti Reddedildi.! }
  if $2 == ok &&  $window($nick) { titlebar $nick Ileti Okundu }
  if $2 == typ { _typ $nick }
}

;**** ileti yaziyor animasyonu
alias _typ { 
  inc %:o
  if %:o < 5 {
    if $window($1) {  titlebar $1 $+($active Ileti yaziyor,$left(....,%:o),$gettok(|./.\,$r(1,3),46))  }
    .timer_anim -m 1 300 _typ
  }
  if %:o > 4 { unset %:o | titlebar  }
}

Disconnected 28 Ekim 2016 10:48
Cevap: ileti yazıyor - iletildi - okundu vs.
 
Bir zaman aklıma gelmişti, imkanı var mı acaba diye düşünmüştüm.
Bizim sadece düşündüklerimizi, sen gerçekleştiriyorsun :)
Emeğine, eline sağlık @[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]

CoCoRiCo 28 Ekim 2016 12:30
Cevap: ileti yazıyor - iletildi - okundu vs.
 
sanki böyle daha iyi gibi.
biraz daha geliştirebiliriz zaman bulursam..
karşı tarafın kullanıp kullanmadığı gibi kontroller filan..
şimdilik bu kdar..

[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]


Kod:
;*** Olaylar
on *:LOAD: read_t
on *:START: read_t
on *:CLOSE:?: { if *serv* !iswm $nick { $iif($hget(read_t,$target),$read_t($target).cls) } }
on *:OPEN:?:  { if *serv* !iswm $nick { $read_t($nick).ilt } }
on *:ACTIVE:*: { if $window($active).type == Query &&  *serv* !iswm $nick { $read_t($active).akt  }  }
on *:APPACTIVE: {  if $window($active).type != Query { window -c @`  } }


on ^*:TEXT:*:?: {
  if *serv* !iswm $nick {
    if $window($active) == $nick || $mouse.win == $nick { $read_t($nick).win }
    if $window($active) != $nick && $query($nick) { $read_t($nick).ilt }
    hadd -m read_t $nick $md5($1-)
  }
}

;**** durum motoru
alias  read_t {
  if $prop == ilt { .timer_i 1 1 .ctcp $1 \\ccrc ilt  | w_pos }
  if $prop == cls { .timer_o 1 1 .ctcp $1 \\ccrc ret  }
  if $prop == akt && $hget(read_t,$1) || $prop == win { 
  .timer_a 1 1 .ctcp $1 \\ccrc ok | hdel read_t $1 }
  if !$isid  {
    .timer_typ_w 0 3 read_t
    if $window($active).type == Query && $editbox($active,0)  &&  $md5($editbox($active,0)) != $hget(read_typ,$active)  {
      hadd -mu10 read_typ $active $md5($editbox($active,0))
      .ctcp $window($active) \\ccrc  typ
    }
  }
}

;**** eylem yorumlama

CTCP *:\\ccrc*:?: {
  haltdef
  if $2 == ilt &&  $window($nick) { _tw $nick Ileti Gonderildi. }
  if $2 == ret &&  $window($nick) { _tw $nick  $nick Ileti Reddedildi.! }
  if $2 == ok &&  $window($nick) { _tw $nick  $nick Ileti Okundu }
  if $2 == typ { _typ $nick }
}

;**** ileti yaziyor animasyonu
alias _typ { 
  $iif(!%:o,set %:o 1,inc %:o)
  if %:o < 6 {
    if $window($1) {
      _tw $1 $+(Ileti yaziyor,$left(....,%:o),$gettok(|./.\,$r(1,3),46)) 
    }
    .timer_anim -m 1 300 _typ $1
  }
  if %:o > 6 { unset %:o | titlebar @` | window -c @` |  .timer_winp off }
}

alias _tw {  w_pos | titlebar @` $1 $2- }
alias w_pos {
  .timer_winp -m 1 100 w_pos
  if $window($active).type == Query {
    window $iif($window(!$query($active)).ontop,-dahHzk0 +L,-dhoHzk0  +L) @` $&
      $window($query($active)).dx  $calc($window($query($active)).dy + $window($active).h -90)  200 10
  }
  else { window -c @` | .timer_winp off }
}

PauL 28 Ekim 2016 12:36
Cevap: ileti yazıyor - iletildi - okundu vs.
 
Kalite ..

IrCbaStarD 28 Ekim 2016 14:29
Cevap: ileti yazıyor - iletildi - okundu vs.
 
Eline sağlık abi. Böyle bi şevk gelmesi iyi olmuş. Darisi l4 ile umuta hasgdkjssa :D

Ali 29 Ekim 2016 04:19
Cevap: ileti yazıyor - iletildi - okundu vs.
 
Eline sağlık gerçekden bunu tek taraflımı ekliyoruz yoksa karşı tarafındamı eklemesi gerek..

L4roXyL 29 Ekim 2016 11:51
Cevap: ileti yazıyor - iletildi - okundu vs.
 
Tek taraf için hedef 2023.
Teşekkürler Alo 186

Feragat 29 Ekim 2016 15:30
Cevap: ileti yazıyor - iletildi - okundu vs.
 
Ben sevmem böyle görsel şeysileri.

Kokoriko şarap gibi adamsın abiiiii


Tüm Zamanlar GMT +3 Olarak Ayarlanmış. Şuanki Zaman: 10:25.
Sayfa 1 Toplam 2 Sayfadan 1 2
Konuya ait 40 Mesajı başka Sayfada göster

Powered by vBulletin® Version 3.8.11
Copyright ©2000 - 2025, vBulletin Solutions, Inc.
Search Engine Friendly URLs by vBSEO
Copyright ©2004 - 2025 IRCForumlari.Net Sparhawk