IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası

- mIRC Scripting Sorunları (https://www.ircforumlari.net/mirc-scripting-sorunlari/)

- - Çözüldü Mobil Kod Sorunu (https://www.ircforumlari.net/mirc-scripting-sorunlari/1026631-mobil-kod-sorunu.html)

Mobil Kod Sorunu

Kodu düzenlemeye çaliştim lakin çalişmada kodda hatalı bölümler nerelerdir

Kod:

on *:snotice:*: { $iif(*Client connecting* iswm $1-,.timer 1 15 ctcp $9 version) }

on *:ctcpreply:*version*: {

  elseif $regex($4,/VERSION/Si) {      

    if $regex($5-,/(qwebirc|Mobile IRC|Android|iphone|SekerSHell v4 html5 irc client|ChatV2.1-ofs|SekerShell Mobile IRC)/Si) && $regex($token($5-,-1,32),/^(\d+)$/Si) {

      if ($token($hget(Mobil-Vers,$nick($1)),1,191) == ekle) {

        .hadd -ms Mobil-Ver $regml(1) Ekleyen: $token($hget(Mobil-Vers,$nick($1)),2,191) Eklenen: $nick($1) Sebep: $token($hget(Mobil-Vers,$nick($1)),3-,191)

        .hsave -o Mobil-Ver hash/mobil-ver.tprk

        msg #kontrol $+(:4,$nick($1),) version cevapı yasaklandı..

        msg #kontrol Version: $strip($5-)

        msg #kontrol Yakalanan ID: $regml(1)

        gzline $nick ($1) - Kurallara aykırı davranıdığınızdan dolayı sunucudan uzaklaştırıldınız.

        .hdel -ms Mobil-Vers $nick($1)

      }

      elseif $hget(Mobil-Ver,$regml(1)) {

        msg #kontrol (4Yasak mobil giriş )---

        msg #kontrol 

        msg #kontrol Nick: $nick($1) $hget(Mobil-Ver,$regml(1))

        msg #kontrol 

        msg #kontrol Mobil veriyi silmek için !mobil sil $regml(1) yazabilirsiniz.

        gzline $nick($1) - Kurallara aykırı davranıdığınızdan dolayı sunucudan uzaklaştırıldınız.

      }

      else { msg #kontrol :[5 $+ $iif($regex($5-,/Mobile/Si),Mobil,WEB) Giriş Uyarı] $nick($1) nicki için $iif($regex($5-,/Mobile/Si),Mobil,WEB) giriş bulundu Yasaklamak için: 4!mobil ekle $nick($1) Sebep }

    }

    elseif ($token($hget(Mobil-Vers,$_nick($1)),1,191) == ekle) {

      msg #kontrol $+(:4,$nick($1),) mobil/web girişi olmadığından yasaklanamaz..

      msg #kontrol Version: $5-

      .hdel -ms Mobil-Vers $nick($1)

    }

  }

}

Cevap: Mobil Kod Sorunu

Kod @[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...] a ait.

Cevap: Mobil Kod Sorunu

dogru paylasılan botunda vardı .

Cevap: Mobil Kod Sorunu

@[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]
Kodda hata yok fakat sen hem düzenlemeye calistim diyorsun hem de kodda hatali yerleri soruyorsun.
Bari nerelerde düzenleme yaptigini soyle de ona göre yardımcı olmaya calisalim.

Cevap: Mobil Kod Sorunu

Alıntı:

manikdepresif Nickli Üyeden Alıntı (Mesaj 1042862477)

Kod:

    elseif $regex($4,/VERSION/Si) {      

      if $regex($5-,/(qwebirc|Mobile IRC|Android|SekerSHell v4 html5 irc client|ChatV2.1-ofs)/Si) && $regex($token($5-,-1,32),/^(\d+)$/Si) {

        if ($token($hget(Mobil-Vers,$_nick($1)),1,191) == ekle) {

          .hadd -ms Mobil-Ver $regml(1) Ekleyen: $token($hget(Mobil-Vers,$_nick($1)),2,191) Eklenen: $_nick($1) Sebep: $token($hget(Mobil-Vers,$_nick($1)),3-,191)

          .hsave -o Mobil-Ver hash/mobil-ver.tprk

          swjbot privmsg $_bots $+(:4,$_nick($1),) version cevapı yasaklandı..

          swjbot privmsg $_bots :Version: $strip($5-)

          swjbot privmsg $_bots :Yakalanan ID: $regml(1)

          swjbot gzline $_nick($1) - Kurallara aykırı davranıdığınızdan dolayı sunucudan uzaklaştırıldınız.

          .hdel -ms Mobil-Vers $_nick($1)

        }

        elseif $hget(Mobil-Ver,$regml(1)) {

          swjbot privmsg $_bots :----(4Yasak mobil giriş )---

          swjbot privmsg $_bots :

          swjbot privmsg $_bots :Nick: $_nick($1) $hget(Mobil-Ver,$regml(1))

          swjbot privmsg $_bots :

          swjbot privmsg $_bots :Mobil veriyi silmek için !mobil sil $regml(1) yazabilirsiniz.

          swjbot gzline $_nick($1) - Kurallara aykırı davranıdığınızdan dolayı sunucudan uzaklaştırıldınız.

        }

        else { swjbot privmsg $_bots :[5 $+ $iif($regex($5-,/Mobile/Si),Mobil,WEB) Giriş Uyarı] $_nick($1) nicki için $iif($regex($5-,/Mobile/Si),Mobil,WEB) giriş bulundu Yasaklamak için: 4!mobil ekle $_nick($1) Sebep }

      }

      elseif ($token($hget(Mobil-Vers,$_nick($1)),1,191) == ekle) {

        swjbot privmsg $_bots $+(:4,$_nick($1),) mobil/web girişi olmadığından yasaklanamaz..

        swjbot privmsg $_bots :Version: $5-

        .hdel -ms Mobil-Vers $_nick($1)

      }

    }

  }

}

bu orjinal hali kodda sorun var bence yansıtmıyor

Cevap: Mobil Kod Sorunu

kodun tamami yok mu bir parçasını atmışsın. Bu socket kodudur normal mircte calismaz.

Cevap: Mobil Kod Sorunu

Kodun tamamı

Kod:

;----------------------------------------

;-     Başlangıç Tarihi: 11.04.2021

;-              JOIN BOTU

;----------------------------------------

;- Bot'un gireceği kanallar.

alias _j-kanallar return $_log $_bots $_kontrol

;----------------------------------------
 

alias swjbot $iif($sock(jbot).status == active,sockwrite -nt jbot $1-)

on *:sockclose:jbot:$+(.timer,_saatkontrol) 1 2 _saatkontrol

on *:sockopen:jbot:{

  if ($sockerr) { sockclose $sockname | $+(.timer,_saatkontrol) 1 2 _saatkontrol }

  else { swjbot NICK $+($_bot,$left($calc($ticks * $r(10,99999)),$r(5,7))) | swjbot USER $_ident "" $+(",$ip) $+(:,$_username) | sockmark $sockname $_jbot }

}

on *:sockread:jbot:{

  var %;jbot | sockread -f %;jbot | tokenize 32 %;jbot

  if $regex($1,/^PING$/) { swjbot pong $remove($2,:) }

  elseif $regex($1,/^ERROR$/i) { sockclose $sockname | $+(.timer,_saatkontrol) 1 2 _saatkontrol }

  elseif $regex($2,/^(471|473|474|475)$/) { swjbot sajoin $_jbot $4 }

  elseif $regex($2,/^(411|481)$/) { swjbot oper $_oper | swjbot nick $_jbot | swjbot nickserv identify $_pass }

  elseif $regex($2,/^(001|433)$/) {

    $iif($regex($1-,/(\d+\.\d+\.\d+\.\d+)/Si),set %:myip $regml(1))

    swjbot oper $_oper

    swjbot ns ghost $_jbot $_pass

    swjbot ns release $_jbot $_pass

    swjbot join #0,0 

    .timer 1 3 swjbot nick $_jbot

  }

  elseif $regex($2,/^NICK$/i) { 

    if ($_nick($1) == $_jbot) { swjbot ns ghost $_jbot $_pass | swjbot ns release $_jbot $_pass | .timer 1 3 swjbot nick $_jbot }

    elseif ($right($3,-1) == $_jbot) {

      swjbot ns identify $_pass

      swjbot oper $_oper

      swjbot os su $_supass

      swjbot join #0,0

      swjbot mode $right($3,-1) +qHp-hY

      swjbot chghost $right($3,-1) $_host

      swjbot os raw swhois $right($3,-1) :4,1 ®0,1 $token($_sunucu,2,46) IRCd 4,1®0,1 $remove($strip($_username),•,™) ® 

      $+(.timer,_saatkontrol) 0 20 _saatkontrol

      $+(.timer,jbot-gir) 1 3 swjbot sajoin $right($3,-1) $replace($_j-kanallar,$chr(32),$chr(44))

    }

  }

  elseif $regex($2,/^PART$/i) && ($_nick($1) == $_jbot) && $istok($_j-kanallar,$3,32) { swjbot sajoin $_nick($1) $3 }

  elseif $regex($2,/^KICK$/i) && ($4 == $_jbot) && $istok($_j-kanallar,$3,32) { swjbot sajoin $4 $3 }

  elseif $regex($2,/^JOIN$/i) {

    if ($_nick($1) == $_jbot) {

      if $istok($_j-kanallar,$right($3,-1),32) { swjbot mode $right($3,-1) -qao+h $str($+($_nick($1),$chr(32)),5) | swjbot chghost $_nick($1) $_host }

      else { swjbot sapart $_nick($1) $right($3,-1) }

    }

  }

  elseif $regex($2,/^MODE$/i) && $regex($3,/^#/) {

    if $regex($4,^\+(\S+)?(b)(\S+)?) && $regex($5-,/(^|\s) $+ $_jbot $+ !\*@\*/i) { swjbot mode $3 -b $_jbot }

    elseif $regex($5-,/(^|\s) $+ $_jbot $+ (\s|$)/i) && ($_nickler($_nick($1)) == 0) { swjbot mode $3 -qao+h $str($+($_jbot,$chr(32)),5) }

  }

  elseif $regex($2,/^401$/) { if $hget(Mobil-Vers,$4) { swjbot privmsg $_bots $+(:4,$4,) nick'i sunucuda bulunmamaktadır, mobil ekleme yapılmamaktadır.. | .hdel -ms Mobil-Vers $4 } }

  elseif $regex($2,/^PRIVMSG$/i) && ($3 == $_bots) {

    if $regex($remove($4,:),/^([!.&]mob[ıiİ]l)$/Si) { 

      if ($scbul($_nick($1)) == 0) { swjbot privmsg $3 :Güvenlik departmanında ekli olmadığınızdan, komut kullanamazsınız. }

      elseif !$regex($5,/^(ekle|s[ıiİ]l|l[ıiİ]st)$/Si) { swjbot privmsg $3 :Lütfen 4!mobil <4ekle|4sil|4list> olarak belirtiniz. }

      elseif $regex($5,/^ekle$/Si) {

        if !$regex($6,/^([a-zA-ZĞğıİöÖüÜşŞçÇ_^\133\135}{`][a-zA-ZĞğıİöÖüÜşŞçÇ0-9_|^}\{\133\135`-]{0,30})$/i) { swjbot privmsg $3 :Lütfen 4!mobil <4ekle> <4Nick> <4Sebep> olarak belirtiniz. }

        elseif !$7 { swjbot privmsg $3 :Lütfen 4!mobil <4ekle> <4Nick> <4Sebep> olarak belirtiniz. }

        elseif $regex($7-,/./Sg) <= 10 { swjbot privmsg $3 :Sebep kısa olamaz. }

        else { .hadd -msu10 Mobil-Vers $strip($6) $+(ekle,¿,$_nick($1),¿,$strip($7-)) | swjbot privmsg $strip($6) $+(:,$chr(1)i,VERSION,$chr(1)) }

      }

      elseif $regex($5,/^s[ıiİ]l$/Si) {

        if !$regex($6,/\d+/S) { swjbot privmsg $3 :Lütfen 4!mobil <4sil> <4ID> olarak belirtiniz. }

        elseif !$hget(Mobil-Ver,$strip($6)) { swjbot privmsg $3 :Bu ID'e ait kayıt bulunmamaktadır. }

        else {

          .hdel -ms Mobil-Ver $strip($6)    

          .hsave -o Mobil-Ver hash/mobil-ver.tprk

          swjbot privmsg $3 $+(:,$strip($6),) ID'e ait version silinmiştir..

        }

      }

      elseif $regex($5,/^l[ıiİ]st$/Si) {

        if !$hget(Mobil-Ver,0).data { swjbot privmsg $3 :Mobil version listesi boş. }

        else {

          swjbot privmsg $3 :Mobil version listesi

          swjbot privmsg $3 :

          var %:mobil = $hget(Mobil-Ver,0).data | while %:mobil {

            swjbot privmsg $3 :ID: $hget(Mobil-Ver,%:mobil).item $hget(Mobil-Ver,%:mobil).data

            dec %:mobil

          }

          swjbot privmsg $3 :

        }

      }

    }

  }

  elseif $regex($2,/^NOTICE$/Si) {

    if $regex($4-,/Client connecting (on port|at) (.+)\: (.+) \(.+@(.+)\)/Si) && (@ !isin $1) {

      var %_jp = $regml(2), %_jn $regml(3), %_ji $regml(4), %_jhub $regml(1)

      if $istok($_sunucuip %:myip,%_ji,32) || $istok($_mobilport $_webport,%_jp,32) || $hget(MuafIP,%_ji) || $hget(IGS-Muaf,%_ji) || $hget(MuafPort,%_jp) || $hget(MuafNick,%_jn) { return }

      else { 

        swjbot notice %_jn :[2/]

        swjbot notice %_jn :[2\] 1Güvenlik taramalarından geçiriliyorsunuz. Lütfen bekleyiniz.

        swjbot notice %_jn :[2/]

      }

    }

    elseif $regex($4,/VERSION/Si) {      

      if $regex($5-,/(qwebirc|Mobile IRC|Android|SekerSHell v4 html5 irc client|ChatV2.1-ofs)/Si) && $regex($token($5-,-1,32),/^(\d+)$/Si) {

        if ($token($hget(Mobil-Vers,$_nick($1)),1,191) == ekle) {

          .hadd -ms Mobil-Ver $regml(1) Ekleyen: $token($hget(Mobil-Vers,$_nick($1)),2,191) Eklenen: $_nick($1) Sebep: $token($hget(Mobil-Vers,$_nick($1)),3-,191)

          .hsave -o Mobil-Ver hash/mobil-ver.tprk

          swjbot privmsg $_bots $+(:4,$_nick($1),) version cevapı yasaklandı..

          swjbot privmsg $_bots :Version: $strip($5-)

          swjbot privmsg $_bots :Yakalanan ID: $regml(1)

          swjbot gzline $_nick($1) - Kurallara aykırı davranıdığınızdan dolayı sunucudan uzaklaştırıldınız.

          .hdel -ms Mobil-Vers $_nick($1)

        }

        elseif $hget(Mobil-Ver,$regml(1)) {

          swjbot privmsg $_bots :----(4Yasak mobil giriş )---

          swjbot privmsg $_bots :

          swjbot privmsg $_bots :Nick: $_nick($1) $hget(Mobil-Ver,$regml(1))

          swjbot privmsg $_bots :

          swjbot privmsg $_bots :Mobil veriyi silmek için !mobil sil $regml(1) yazabilirsiniz.

          swjbot gzline $_nick($1) - Kurallara aykırı davranıdığınızdan dolayı sunucudan uzaklaştırıldınız.

        }

        else { swjbot privmsg $_bots :[5 $+ $iif($regex($5-,/Mobile/Si),Mobil,WEB) Giriş Uyarı] $_nick($1) nicki için $iif($regex($5-,/Mobile/Si),Mobil,WEB) giriş bulundu Yasaklamak için: 4!mobil ekle $_nick($1) Sebep }

      }

      elseif ($token($hget(Mobil-Vers,$_nick($1)),1,191) == ekle) {

        swjbot privmsg $_bots $+(:4,$_nick($1),) mobil/web girişi olmadığından yasaklanamaz..

        swjbot privmsg $_bots :Version: $5-

        .hdel -ms Mobil-Vers $_nick($1)

      }

    }

  }

}

alias _dagit {

  swjbot notice $1 :[2\]

  swjbot notice $1 :[2/] 1Taramalardan geçtiniz. Kanallara aktarılıyorsunuz. $+(4,$chr(40),1,$2-,4,$chr(41))

  swjbot notice $1 :[2\]

  $+(.timer,gec¿,$1) 1 2 swjbot gec $1

  $+(.timer,version¿,$1) 1 4 swjbot privmsg $1 $+(:,$chr(1)i,VERSION,$chr(1))

  $iif($hget(IGS-IP,$1),.hdel -ms IGS-IP $1)

  swjbot privmsg $_bots $+(:,$chr(40),3,$2-,,$chr(41)) $1 global kanallara aktarıldı.

}

Cevap: Mobil Kod Sorunu

Socket kodunu eğer kendi mIRC'in içerisinde çalıştırmaya çalışıyorsan arkadaşında dediği gibi çalışmaz ama bot olarak sunucunda çalıştırmak istiyorsan @[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]'ın botlarında genelde sistem hep birbiri üzerinden çalışan botlar oluyor yani bu bot muhtemelen diğer botlar üzerinden veri çekerek yapıyor bazı noktalarda hata yapıyor olabilirsin ve Unreal üzerinde ayarlanması gereken yerler oluyor bunlarıda yapman lazım.

Alttaki konuya bi bak
[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]

Cevap: Mobil Kod Sorunu

anladım verdiniz linkteki kodu biliyorum birazda nasıl parca halinde düzeltirilir onu görmek istemiştim nomercy benzeri botlardada hep böyle bazen kucuk kısımdakı kodu kullanmak istedimizde dedin gibi baglantılı oldu icin çalışmıyor amac onlardan cekip nasıl mircde calısır halinde yapmaktı

Cevap: Mobil Kod Sorunu

hallettin mi @[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...] ?

Cevap: Mobil Kod Sorunu

@[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...] yok olmadı mirce göre

Cevap: Mobil Kod Sorunu

bulundugun sunucuda nick giris cikislarini gorebiliyor musun
Client connecting seklinde

Cevap: Mobil Kod Sorunu

@[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...] @Girişler pencerisinde bu şekilde görüyorum [21:24:14] Giriş ] *** Notice -- Client connecting on

Cevap: Mobil Kod Sorunu

Vision'un verdigi kodu denedin mi sanirim kod blackforce'a ait.
-

Kod:

menu * {

  MobilBAN System

  .Aç:/.enable #Version | echo -a 4MobilBAN2 System aktif edildi.

  .Kapat:/.disable #Version | echo -a 7MobilBAN2 System deaktif edildi.

}

#Version off

on *:snotice:*:{

  if $regex($1-,/Client connecting (on port|at) (.+)\: (.+) \((.+)@(.+)\)/Si) {

    var %_port = $regml(2), %_nick $regml(3), %_ident $regml(4), %_ip $regml(5)

    if $hget(MuafNick,%_nick) || $hget(MuafIP,%_ip) || $hget(Muafident,%_ident) { return }

    ctcp %_nick version

  }

}

on *:ctcpreply:*version*: {

  var %:uid $token($1-,-1,32)

  if $hget(banlist,%:uid) {

    msg #Xline 11-> 0[5YASAKLI GiRiŞ0]2 Giriş yapmaya çalışan kullanıcı4 $nick 2Uygulanan işlem:4 G:LiNED

    echo #Güvenlik $timestamp 11-> 5[VERSION]0 $nick 2yasak id numarasi 0 ( %:uid ) 2ile giriş yapmaya çalıştı.

    Gline $nick 0 2Sunucu kurallarına uymadığınız için girişiniz,4 Yasaklanmıştır.

  }

  else {

    .hadd -m mban $nick %:uid

  }

}

on *:input:#:{

  if $regex($1,/^[.!]mban/Si) {

    if $2 = ekle {

      .hadd -m banlist $hget(mban,$3) $3

      hsave banlist banlist.bf

      msg #Güvenlik 11-> 5[VERSION]0 $hget(mban,$3) 2Yasaklanan Versiona ait Nick0 $3 2Version bilgileri listeye eklendi.

      Gline $3 0 2Sunucu kurallarına uymadığınız için girişiniz,4 Yasaklanmıştır.

    }

    if $2 = list {

      var %w = 1 | while %w <= $hget(banlist,0).item {

        msg # 11-> 5[VERSION]4 ID:0 $hget(banlist,%w).item 4Nick:0 $hget(banlist,%w).data

        inc %w

      }

    }

    if $2 = sil {

      msg # 5[VERSION]0 $3 2id numaralı4 MobilBAN2 listesinden silindi 4Nick:0 $hget(banlist,$3) 

      .hdel banlist $3

      hsave banlist banlist.bf

    }

  }

}

#Version end

Kullanımı : 

!mban ekle nick 

!mban sil nick

!mban list
 

on *:start: {

  hmake banlist

  $iif($isfile(banlist.bf),hload banlist banlist.bf)

}

Cevap: Mobil Kod Sorunu

@[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...] denedim dedim gibi amac nomercy benzeri botlardan nasıl mirce uyarlanır onu denemekti

Cevap: Mobil Kod Sorunu

Peki denedigin sey calisti mi ?

Cevap: Mobil Kod Sorunu

Alıntı:

manikdepresif Nickli Üyeden Alıntı (Mesaj 1042863086)

Peki denedigin sey calisti mi ?

çalışmadı yansıtmıyor nedense

Cevap: Mobil Kod Sorunu

mouse ile sag tiklayip mobilban sistemini Aç yap öyle dene

Cevap: Mobil Kod Sorunu

Alıntı:

manikdepresif Nickli Üyeden Alıntı (Mesaj 1042863094)

mouse ile sag tiklayip mobilban sistemini Aç yap öyle dene

@[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...] ilk kod ile ugrasıyorum dediniz koda bakmadım neyse tşk ederim destek için zamanla karıştırarak çözerim inş

Cevap: Mobil Kod Sorunu

sorun yok o zaman kardeşim.

Cevap: Mobil Kod Sorunu

Version sonuçların spama mı düşüyor yoksa hepsini ctcp olarak görebiliyor musun ?

Cevap: Mobil Kod Sorunu

Alıntı:

Enes Nickli Üyeden Alıntı (Mesaj 1042863104)

Version sonuçların spama mı düşüyor yoksa hepsini ctcp olarak görebiliyor musun ?

@[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...] hayır spama düşmüyor version statusta gözüküyor ama kontrol odasına yansıtmıyor

Cevap: Mobil Kod Sorunu

Alıntı:

NasiR Nickli Üyeden Alıntı (Mesaj 1042863118)

@[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...] hayır spama düşmüyor version statusta gözüküyor ama kontrol odasına yansıtmıyor

Kodu socketten çevirdiğin için sorunlar muhtemelen $ değerlerinde $4 değerlerini $1 / $5 değerlerini $2 yaparak dener misin. @[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...] üstadın verdiği kodu kullan ama bence

Cevap: Mobil Kod Sorunu

@[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...] deniyim

Cevap: Mobil Kod Sorunu

Alıntı:

Enes Nickli Üyeden Alıntı (Mesaj 1042863104)

Version sonuçların spama mı düşüyor yoksa hepsini ctcp olarak görebiliyor musun ?

@[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...] yukarıda "Version sonuçların spama mı düşüyor yoksa hepsini ctcp olarak görebiliyor musun " yazmışsın da "version" çektiğin de dediğin gibi spama düşüyor user version cevabında onu nasıl düzelteceğiz?

Ayrıca bir çok remote de olduğu gibi bunda da /mode Musti +s kcfFjveGnNqSso yapılmadığında version dahi çekmiyor $noticeler görünmüyor.

Cevap: Mobil Kod Sorunu

Alıntı:

Musti Nickli Üyeden Alıntı (Mesaj 1042874303)

onun için spamdaki filtrelerin silinmesi lazım veya kodu spama düşen sonuca göre aksiyon alacak şekilde düzenlemek lazım