IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası

- mIRC Scripting Sorunları (https://www.ircforumlari.net/mirc-scripting-sorunlari/)

- - Otomatik mesaj atmak (https://www.ircforumlari.net/mirc-scripting-sorunlari/15329-otomatik-mesaj-atmak.html)

Otomatik mesaj atmak

kanala girenlere oto mesaj atmak mnasıl oluyor ayrıca oplara v.s ye oto mesaj atmak bilgilendirirseniz sevinirim

Yanıt: mesaj atmak

Auto Mesaj : on !*:join:#:{ msg $nick mesajın }
Op olanlara mesaj : on !*:op:#: { msg # $opnick mesajın }
vs kısmını anlamadım (;

Yanıt: mesaj atmak

şöle bişe kanala giren her nicke mesaj atmak istiyorum vede kanalda o an bulunan herkese mesaj atmak istiyorum.

Yanıt: mesaj atmak

Kanala giren herkeze mesaj atmak için yukarıda yazdığım kodu kullanabilirsin.

kanalda bulunan herkeze msaj atmak içinse

alias gonder {
var %nickler $nick(#,0)
while (%nickler >= 1) {
if ($nick(#,%nickler) != $me) {
msg $nick(#,%nickler) mesajın
}
dec %nickler
}
}

koyu renkte belirttiğim yere göndermek istediğin mesajı yazıp ve kanalda /gonder yazarsan istediğin olur.

Yanıt: mesaj atmak

bu kodun değişik şekli yokmu daha basiti diyalog gibi veya daha basit ne biliyim:)

Yanıt: mesaj atmak

Artık kodu yazmak yetmiyor , birde beğendirmesi kalıyor (; Neyshe buyur , denedim sorunsuz çalıştı

Kanalda bulunan herkeze mesaj atmak için hazırlanmış dialog, kullanımı : /at

Kod:

dialog Kmesaj {

  title "Kanaldakilere mesaj"

  size -1 -1 109 44

  option dbu

  text "  Hangi kanal", 1, 1 4 35 10

  edit "", 2, 42 4 59 10, multi

  text "   Mesajınız", 3, 1 17 35 10

  edit "", 4, 42 16 59 10, multi

  button "Tamam", 5, 11 31 35 10, ok

  button "Kapat", 6, 62 31 35 10, cancel

}

on *:dialog:kmesaj:*:*:{

  if ($devent == edit) {

    set %knl $did(2) | set %msj $did(4) 

  }

  if ($devent == sclick) {

    if ($did == 5) {

      gonder %msj

    }

  }

}

 

alias gonder { 

  var %nickler $nick(%knl,0) 

  while (%nickler >= 1) { 

    if ($nick(%knl,%nickler) != $me) { 

      msg $nick(%knl,%nickler) %msj

    } 

    dec %nickler

  } 

}

 

alias at { dialog -m kmesaj kmesaj }

Kanala giren ve çıkan kullanıcılara mesaj gönderebilmek için hazırlanmış dialog,kullanımı : /automesaj

Kod:

 

dialog amsg {

  title "Kanaldakilere mesaj"

  size -1 -1 143 44

  option dbu

  text " Kanala Girene", 1, 1 4 52 10

  edit "", 2, 59 4 79 10, multi

  text " Kanaldan çıkana", 3, 1 17 53 10

  edit "", 4, 59 16 79 10, multi

  button "Kapat", 6, 75 30 47 10, cancel

  check "Auto mesaj açık", 5, 2 30 50 10

}

 

on *:dialog:amsg:*:*:{

  if ($devent == edit) {

    set %jns $did(2) | set %prt $did(4) 

  }

  if $devent == init {

    if ($group(#ams) == On) {

      did -c amsg 5 

    } 

    did -a amsg 2 $iif(%jns != $null,%jns,Kanala girene ne göndericeksin) 

    did -a amsg 4 $iif(%prt != $null,%prt,Cıkana ne yollucaksın)

  }

  if ($devent == sclick) {

    if ($did == 5) { 

      if ($did($dname,5).state == 1) { 

        .enable #ams

      }  

      else { 

        .disable #ams 

      }

    }

  }

}

#ams on

on !*:join:#: {

  msg $nick %jns

}

on !*:part:#: {

  msg $nick %prt

}

#ams end

 

alias automesaj { dialog -m amsg amsg }

Yoruldum beee (((;

Cevap: Otomatik mesaj atmak

Ajan : Yoruldum beee (((;
Ajan: Artık kodu yazmak yetmiyor , birde beğendirmesi kalıyor (;

Kimseye yardim etmek zorunda degilsin, yardimci olacaksan karsiliksiz yardim yap.