IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası

IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası (https://www.ircforumlari.net/)
-   mIRC Scripting Sorunları (https://www.ircforumlari.net/mirc-scripting-sorunlari/)
-   -   !seen nick hakkında (https://www.ircforumlari.net/mirc-scripting-sorunlari/162388-seen-nick-hakkinda.html)

OperServ 03 Aralık 2008 09:02

!seen nick hakkında
 
s.a arkadalar bana !seen nick yazınca nickin ne zaman görüldüğünü gösteren kod lazım diyerini biliyorum ama o telnet için onu bi türlü yapamadım :S
yardimcı olursanız sevinirim

OperServ 17 Aralık 2008 03:00

Cevap: yardim
 
yardim eden yokmu :(

Editor 17 Aralık 2008 20:08

Cevap: !seen nick hakkında
 
Kod:

;$_find($1,1) = nick, $_find($1,2) = time, $_find($1,3) == date
alias _find return $gettok($hget(seen. $+ $server,$hfind(seen. $+ $server,$+(*,$1,*),1,w).data),$2,46)
on *:JOIN:#: {
  if !$findfile($mircdir,$+(seen.,$server,.data),1) {
    hmake seen. $+ $server 50
    hsave seen. $+ $server $+(seen.,$server,.data)
  }
  elseif !$hget(seen. $+ $server) { hmake seen. $+ $server | hload seen. $+ $server $+(seen.,$server,.data) }
  if $_find($nick,1) { hdel seen. $+ $server $hfind(seen. $+ $server,$+(*,$1,*),1,w).data }
  hadd seen. $+ $server $r(0,99999999) $+($nick,$chr(46),$time,$chr(46),$date)
  hsave seen. $+ $server $+(seen.,$server,.data)
}
alias seen {
 if $1 == !seen {
  if $server {
      if $1 == !seen clear {
        hdel -w seen. $+ $server *
        echo -a Liste Temizlendi.
        hsave seen. $+ $server $+(seen.,$server,.data)
      }
      elseif $1 == !seen list {
        var %s = 1,%nick,%time,%date
        while %s <= $hget(seen. $+ $server,0).item {
          %nick = $gettok($hget(seen. $+ $server,%s).data,1,46)
          %time = $gettok($hget(seen. $+ $server,%s).data,2,46)
          %date = $gettok($hget(seen. $+ $server,%s).data,3,46)
          echo -a %s Nick: %nick Time: %time Date: %date
          inc %s
        }
      }
      elseif $_find($1,1) {
        echo -a $_find($1,1) $+ , En son $_find($1,3) Tarihinde Saat $_find($1,2) Saatinde $network 'da Görüldü.
      }
      else echo -a $1 $+ , Listemde mevcut değil.
    }
  }
  else echo -a Bağlı Değilsiniz.
}

!seen nick : Nickin enson nezaman server'da görüntüğüne bakar.
!seen list : listeyi gösterir.
!seen clear : listeyi temizler.

umarım işine yarar Kolay Gelsin.

OperServ 19 Aralık 2008 21:05

Cevap: !seen nick hakkında
 
calismiyor :(

Difuzyon 19 Aralık 2008 21:49

Cevap: !seen nick hakkında
 
Kod:

alias _find {
  return $gettok($hget(seen. $+ $server,$hfind(seen. $+ $server,$+(*,$1,*),1,w).data),$2,46)
}

on *:JOIN:#: {
  if !$findfile($mircdir,$+(seen.,$server,.data),1) {
    hmake seen. $+ $server 50
    hsave seen. $+ $server $+(seen.,$server,.data)
  }
  elseif !$hget(seen. $+ $server) { hmake seen. $+ $server | hload seen. $+ $server $+(seen.,$server,.data) }
  if $_find($nick,1) { hdel seen. $+ $server $hfind(seen. $+ $server,$+(*,$1,*),1,w).data }
  hadd seen. $+ $server $r(0,99999999) $+($nick,$chr(46),$time,$chr(46),$date)
  hsave seen. $+ $server $+(seen.,$server,.data)
}
alias seen {
  if $server {
    if $1 == clear {
      hdel -w seen. $+ $server *
      echo -a Liste Temizlendi.
      hsave seen. $+ $server $+(seen.,$server,.data)
    }
    elseif $1 == list {
      var %s = 1,%nick,%time,%date
      while %s <= $hget(seen. $+ $server,0).item {
        %nick = $gettok($hget(seen. $+ $server,%s).data,1,46)
        %time = $gettok($hget(seen. $+ $server,%s).data,2,46)
        %date = $gettok($hget(seen. $+ $server,%s).data,3,46)
        echo -a %s Nick: %nick Time: %time Date: %date
        inc %s
      }
    }
    elseif $_find($1,1) {
      echo -a $_find($1,1) $+ , En son $_find($1,3) Tarihinde Saat $_find($1,2) Saatinde $network 'da Görüldü.
    }
    else echo -a $1 $+ , Listemde mevcut değil.
  }
  else echo -a Bağlı Değilsiniz.
}


Kullanımı:

/seen Nick (Nick'in en son hangi tarihte giriş yaptığını gösterir)
/seen list (Tüm listeyi sıralar)
/seen clear (Tüm listeyi temizler)


Bu şekilde denedim çalışıyor.
İyi forumlar...

OperServ 20 Aralık 2008 00:18

Cevap: !seen nick hakkında
 
iyide ben bunu bota ekliyecem mesela kayitli nicklerden birisi !seen nick yazinca bot desin bu saate göründü

Difuzyon 20 Aralık 2008 02:16

Cevap: !seen nick hakkında
 
Kod:

on *:JOIN:#: {
  if !$findfile($mircdir,$+(seen.,$server,.data),1) {
    hmake seen. $+ $server 50
    hsave seen. $+ $server $+(seen.,$server,.data)
  }
  elseif !$hget(seen. $+ $server) { hmake seen. $+ $server | hload seen. $+ $server $+(seen.,$server,.data) }
  if $_find($nick,1) { hdel seen. $+ $server $hfind(seen. $+ $server,$+(*,$nick,*),1,w).data }
  hadd seen. $+ $server $r(0,99999999) $+($nick,$chr(46),$time,$chr(46),$date)
  hsave seen. $+ $server $+(seen.,$server,.data)
}
 
on *:text:*:#: {
  if $1 == !seen {
    if $server {
      if $2 == sil {
        if !$_find($3,1) { msg $chan $3 Listemde yok. }
        else { hdel seen. $+ $server $hfind(seen. $+ $server,$+(*,$3,*),1,w).data | msg $chan $3 seen listesinden silinmiştir. }
      }
      elseif $2 == clears {
        hdel -w seen. $+ $server *
        msg $chan Tüm Liste Temizlendi.
        hsave seen. $+ $server $+(seen.,$server,.data)
      }
      elseif $2 == list {
        var %s = 1,%nick,%time,%date
        while %s <= $hget(seen. $+ $server,0).item {
          %nick = $gettok($hget(seen. $+ $server,%s).data,1,46)
          %time = $gettok($hget(seen. $+ $server,%s).data,2,46)
          %date = $gettok($hget(seen. $+ $server,%s).data,3,46)
          msg $chan %s Nick: %nick Time: %time Date: %date
          inc %s
        }
      }
      elseif $_find($2,1) {
        msg $chan $_find($2,1) $+ , En son $_find($2,3) Tarihinde Saat $_find($2,2) Saatinde $network 'da Görüldü.
      }
      else msg $chan $2 Listede bulunamadı.
    }
  }
}
 
alias _find {
  return $gettok($hget(seen. $+ $server,$hfind(seen. $+ $server,$+(*,$1,*),1,w).data),$2,46)
}

Kodu botunuzun remote'una yükledikten sonra, #kanal 'da uygulanabilecek komutlar ;

!seen Nick (Nick'in son giriş yaptığı zamanı yazar)
!seen sil Nick (Nick'in zaman kaydını siler)
!seen list (Kayıtlı tüm listeyi yazar)
!seen clears (Kayıtlı tüm veriyi siler)

İyi forumlar...


Tüm Zamanlar GMT +3 Olarak Ayarlanmış. Şuanki Zaman: 22:58.

Powered by vBulletin® Version 3.8.11
Copyright ©2000 - 2025, vBulletin Solutions, Inc.
Search Engine Friendly URLs by vBSEO
Copyright ©2004 - 2025 IRCForumlari.Net Sparhawk