IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası
Sayfa 1 Toplam 4 Sayfadan 1 234
Konuya ait 40 Mesajı başka Sayfada göster

IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası (https://www.ircforumlari.net/)
-   mIRC Scripting Sorunları (https://www.ircforumlari.net/mirc-scripting-sorunlari/)
-   -   Badnick koruması (users bölümüne eklenerek) (https://www.ircforumlari.net/mirc-scripting-sorunlari/162826-badnick-korumasi-users-bolumune-eklenerek.html)

MerakLıuSer 04 Aralık 2008 17:11
Badnick koruması (users bölümüne eklenerek)
 
on *:join:#:{ if $bad($nick) && !$muaf($nick) { mode # +b $nick | kick # $nick Badnick } }
alias bad {
var %ğ = 1
while $read(badnicklist.txt,%ğ) {
if $v1 iswm $1- {
return $v1 on *:NICK:{ if $bad($newnick) && !$muaf($newnick) { mode # +b $newnick | kick # $newnick Badnick } }
}
inc %ğ
}
return $false
}
alias muaf {
var %x = 1
while $read(muaf.txt,%x) {
if $v1 iswm $1- {
return $v1
}
inc %x
}
return $false
}
on *:NICK:{ if $bad($newnick) && !$muaf($newnick) { mode # +b $newnick | kick # $newnick Badnick! } }


Bu kodemde birisi kanalda nick değiştiği zaman atmıyor :(
Muaf txtmın içinde muafnicklerim var birde muafkanal txtm olsun onun içinede kanalları yazayım istiyorum. Yardımlar için teşekkürler.

İyi paylaşımlar.

Difuzyon 06 Aralık 2008 02:13
Cevap: Codeme bir iki eklenti LÜTFEN.
 
Kod:
alias bad {
  var %ğ = 1
  while $read(badnicklist.txt,%ğ) {
    if $v1 iswm $1- {
      return $v1
      break
    }
    inc %ğ
  }
  return $false
}
 
alias muaf {
  var %x = 1
  while $read(muaf.txt,%x) {
    if $v1 iswm $1- {
      return $v1
      break
    }
    inc %x
  }
  return $false
}
 
on @*:JOIN:#:if $bad($nick) && !$muaf($nick) && !$read(muafkanal.txt,w,$chan) { mode # +b $nick | kick # $nick Badnick }
 
on *:NICK:{
  if $bad($newnick) && !$muaf($newnick) {
    var %cnk 1
    while %cnk <= $comchan($newnick,0) {
      if $me isop $comchan($newnick,%cnk) && !$read(muafkanal.txt,w,$comchan($newnick,%cnk)) {
        mode $comchan($newnick,%cnk) +b $newnick
        kick $comchan($newnick,%cnk) $newnick Badnick!
      }
      inc %cnk
    }
  }
}
Badnickleri kanaldan uzaklaştırmak için en zor yöntemi(txt'ye eklemek) tercih ediyorsun.Belirtilen aliaslara break eklemek suretiyle,mIRC'in kasmasına biraz olsun engel olmaya çalıştık.

İşine yaraması dileğiyle...

MerakLıuSer 06 Aralık 2008 11:33
Cevap: Codeme bir iki eklenti LÜTFEN.
 
Madem öyle kasar diyorsun peki fakat Difuzyon arkadaşım ben bu codeyi kasmayan şekline nasıl cevircem :S Mesela muafnick ve muafkanallarım olsun. Yeni değişen nick muafnick veya muafkanalımdan biriyse atmasın değilse atsın gibi. Bunu kasmayan şekline nasıl cevircez :( Kodeyi yazıp ayrıntılı bir şekilde neyi ve nasıl ekleyebileceğimi anlatırsanız o halde teşekkür ederim.

Difuzyon 06 Aralık 2008 13:18
Cevap: Codeme bir iki eklenti LÜTFEN.
 
Kod:
on @badnick:JOIN:*:{
  if ($ulist($nick,koruma,0) >= 1) { return }
  elseif !$istok(#Kanal1 #Kanal2 #Kanal3 #Kanal4 #Kanal5,$chan,32) {
    mode $chan +b $nick
    kick $chan $nick Badnick sebebiyle atıldın...
  }
}
on *:NICK:{
  if ($ulist($newnick,koruma,0) >= 1) { return }
  else {
    if ($level($newnick) == badnick) {
      var %Cnk = 1
      while $comchan($newnick,%Cnk) {
        var %e = $v1
        if $me isop %e && !$istok(#Kanal1 #Kanal2 #Kanal3 #Kanal4 #Kanal5,%e,32) {
          mode %e +b $newnick
          kick %e $newnick Dışarı!
        }
        inc %Cnk
      }
    }
  }
}
Kodu (Alt + r) REMOTE'a ekliyorsunuz.

Badnick eklemek :
Örnek) /auser badnick *gay*
Örnek) /auser badnick *****
Örnek) /auser badnick lez*
Örnek) /auser badnick *top*
Örnek) /auser badnick travesti

Koruma(nick) eklemek :
Örnek) /auser koruma gaye
Örnek) /auser koruma *tugay*
Örnek) /auser koruma turgay*
Örnek) /auser koruma leziz_yemek
Örnek) /auser koruma topcu_piyade

Badnick veya Koruma Silmek :
Örnek) /ruser koruma gaye
Örnek) /ruser badnick lez*

Bu işlemlerin nerde olup bittiğini görüntülemek için (Alt + r) ile açılan panelde "KULLANICI" başlığını tıklayınız.
Muaf kanal konusuna gelince hem JOIN hemde NICK event'larında " !$istok(#Kanal1 #Kanal2 #Kanal3 #Kanal4 #Kanal5,$chan,32) " gereken yerlere kanal isimlerini yazarsanız.Ben 5 kanal yazdım, kanalları çoğaltma imkanınız var.

Kod Mantığı; kanala giren "badnick" listesinden biri önce "koruma" listeden olup olmayacağı sorgulanacaktır.Değilse ve muaf kanallar bulunmuyorsa işlem yapacaktır.Nick değiştirme konusunda da işlem benzerini takip eder.
Üstteki txt'ye göre daha seri işlem yapacaktır ve en önemlisi gereksiz yere while döngüsüne sokmaktan(mIRC'i kasmak) kurtulmuş olduk.
Yeterince anlaşılır olduğunu düşünüyorum.

İyi paylaşımlar...

MerakLıuSer 08 Aralık 2008 14:31
Cevap: Codeme bir iki eklenti LÜTFEN.
 
Uğraştığın emek sarfettiğin çok güzel açıkladıgın için sana CANI GÖNÜLDEN TEŞEKKÜR EDİYORUM. ALLAH işlerini ras getirsin.

MerakLıuSer 19 Aralık 2008 00:15
Cevap: Codeme bir iki eklenti LÜTFEN.
 
Difuzyon bir noktasa sorun yaşadım. *msn* şeklinde badnick eklediğimde identi *msn* olan nicklerinde atıyor. İdente koruma nasıl ekleyebiliriz ?

Difuzyon 19 Aralık 2008 18:05
Cevap: Codeme bir iki eklenti LÜTFEN.
 
Kod:
on @badnick:JOIN:*:{
  if ($ulist($fulladdress,koruma,0) >= 1) { return }
  elseif !$istok(#kanal1 #kanal2 #kanal3 #kanal4 #kanal5,$chan,32) {
    mode $chan +b $nick
    kick $chan $nick Badnick sebebiyle atıldın...
  }
}
on *:NICK:{
  if ($ulist($+($newnick,!*@*),koruma,0) >= 1) { return }
  else {
    if $ulist($+($newnick,!*@*),badnick,0) {
      var %Cnk = 1
      while $comchan($newnick,%Cnk) {
        var %e = $v1
        if $me isop %e && !$istok(#kanal1 #kanal2 #kanal3 #kanal4 #kanal5,%e,32) {
          mode %e +b $newnick
          kick %e $newnick Dışarı!
        }
        inc %Cnk
      }
    }
  }
}
alias badnickekle {
  auser badnick $1 $+ !*@*
}
alias badnicksil {
  ruser badnick $1 $+ !*@*
}
alias nickkoruma {
  auser koruma $1 $+ !*@*
}
alias badidentekle {
  auser badnick *! $+ $1 $+ @*
}
alias badidentsil {
  ruser badnick *! $+ $1 $+ @*
}
alias identkoruma {
  auser koruma *! $+ $1 $+ @*
}

Badnick eklemek için:
/badnickekle *****
/badnickekle gay*

Badnick silmek için:
/badnicksil ***y
/badnicksil *lez*

Nick Koruma eklemek için:
/nickkoruma gaye*
/nickkoruma *tugay*

Badident eklemek için:
/badidentekle *msn*
/badidentekle gay

Badident silmek için:
/badidentsil *msn*
/badidentsil gay

İdent Koruma eklemek için:
/identkoruma msn
/identkoruma gaye*

İşlemleri takip için (ALT + r) "Kullanıcı" başlığından takip edebilirsiniz.Yeni kodlamayla Nick!Ident@Hostsisteminde çalışacaktır(Daha önce sadece *maske* olarak çalışıyordu).Kanala giren kullanıcının fulladdress bilgisi "badnick:" kullanıcı maskesiyle örtüşüyorsa; evvela "koruma:" maskesinde sorgulanacaktır, tutmuyorsa kanaldan atacaktır.
Nick değiştirme işleminde de sistem aynısı takip eder.Fakat nick değiştirme aşamasında ident kısmını sorgulamaz,sadece değişen nickin Nick kısmından sorgulama yapar.Bunu dikkate alırsınız...

İyi forumlar...

gncvoLkan 19 Aralık 2008 19:23
Cevap: Codeme bir iki eklenti LÜTFEN.
 
difüzyon Helal Valla hiç Üşenmeden sürekLi yazıyosun ne denilebilir ki :)

yabadabadu 12 Ağustos 2009 15:28
difüzyon
 
Gerek Forumlar da, gerek irc'lerin mirchelp kanallarında olsun istedigim bi sekilde kod bulamamıstım.
taki difüzyon arkadasımızın yazdıgı kod u görene kadar.
bu kod basit oldugu kadar diger kodların da yaptıgı bi cok islevi yapabildigi icin
remoteden fazla olan txt dosyalarını silip scriptti daha da hızlandırdım.
sadece 3 txt dosyası bulunuyor suan.
valla söyleyecek söz bulamıyorum.
bence difüzyon tşk etsekte azdır.
eline saglık kardes uzun zamandır düsünüp arayıpta bulamadıgım bi kodu sayen de buldum.
cok ama cok teşşekkür ederim.

Head 12 Kasım 2009 17:10
Cevap: Badnick koruması (users bölümüne eklenerek)
 
Güzel bir çalışma olmuş ve şu an kullanıyorum
Bu koda birde tarama kodu ekleyebilirsen daha güzel olurdu
teşekkürler


Tüm Zamanlar GMT +3 Olarak Ayarlanmış. Şuanki Zaman: 08:57.
Sayfa 1 Toplam 4 Sayfadan 1 234
Konuya ait 40 Mesajı başka Sayfada göster

Powered by vBulletin® Version 3.8.11
Copyright ©2000 - 2025, vBulletin Solutions, Inc.
Search Engine Friendly URLs by vBSEO
Copyright ©2004 - 2025 IRCForumlari.Net Sparhawk