IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası
Sayfa 1 Toplam 3 Sayfadan 1 23
Konuya ait 40 Mesajı başka Sayfada göster

IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası (https://www.ircforumlari.net/)
-   mIRC Scripting Sorunları (https://www.ircforumlari.net/mirc-scripting-sorunlari/)
-   -   kanala girenleri takip (https://www.ircforumlari.net/mirc-scripting-sorunlari/164522-kanala-girenleri-takip.html)

WeiLSiDe 12 Aralık 2008 03:26
kanala girenleri takip
 
12------» 12¦14 relax 12[14~xxxx12@14D7EA390F.34A1A42C.39F5C3D2.IP12]14 joins (joined before as yolal)


Yabancı bi scriptte böle bi özellik var bunu kendi scriptime eklemek istiyorum. mümkünse tabi.
Bunun için bişeyler yapılabilir mi?
Şimdiden tşk ler....

SuNSeT 12 Aralık 2008 05:02
Cevap: kanala girenleri takip
 
Kod:
on *:join:#:{
window -m @Join | aline @Join $nick nick'i $chan kanalına giriş yaptı. IP: $fulladdress }
Bunun gibi birşey istedin sanırım, kolay gelsin.

WeiLSiDe 12 Aralık 2008 21:03
Cevap: kanala girenleri takip
 
Aslında tam olarak öyle değil.
Şimdi diyelim kanala biri girdi ve cıktı. Sonra bu kişi nick değişip tekrar geldi. İşte bu anda script şöle diyo "bu kişinin bi önceki nicki şu idi (12------» 12¦14 relax 12[14~xxxx12@14D7EA390F.34A1A42C.39F5C3D2.IP12]14 joins (joined before as yolal) ) Sanırım bunu logları tarayarak yapıyo.
Umarım anlatabilmişimdir.

Ra` 12 Aralık 2008 21:55
Cevap: kanala girenleri takip
 
Alıntı:
on 1:start: { .hmake nicksch 100 }
on 1:part:#: { if ( $comchan($nick,0) < 2 ) { nicksgrab $nick $site } }
on 1:quit: { nicksgrab $nick $site }
on 1:kick:#: {
if ( $comchan($knick,0) < 2 ) {
if ( $ial($knick).host != $null ) { nicksgrab $knick $ifmatch }
}
}
alias nicksgrab {
.hadd nicksch $iif(($gettok($2,-1,46) == virtuel) && ($numtok($2,46) > 3),$+($gettok($2,1-2,46),.virtuel),$2) $1
}
alias NicksTrouve {
var %a = $iif(($gettok($2,-1,46) == virtuel) && ($numtok($2,46) > 3),$+($gettok($2,1-2,46),.virtuel),$2)
return $iif($hget(nicksch,%a) != $1,$ifmatch)
}
on 1:JOIN:#: {
var %NickPrecedent = $iif($NicksTrouve($nick,$site), 2 Bir Önceki Nick Alarmı 4:1 $ifmatch )
if ( %NickPrecedent ) { echo -tm $chan $ifmatch }
}
bu işini görür sanırım

WeiLSiDe 12 Aralık 2008 23:18
Cevap: kanala girenleri takip
 
Ra' hiç bi tepki vermedi....

Spectral 13 Aralık 2008 00:44
Cevap: kanala girenleri takip
 
Kod:
ON *:START: {
  ; Create a hash table and load the saved user data
  hmake trackusers 10
  if ($isfile(trackusers.dat)) {
    hload trackusers trackusers.dat
  }
}
on *:JOIN:#: {
  ; Check if there are any nicknames for this mask
  if ($hget(trackusers,$address($nick,3))) {
    var %n = $ifmatch
    ; Delete the current nickname from the list of used nicknames
    if ($istok(%n,$nick,32)) { var %d = $deltok(%n,$findtok(%n,$nick,1,32),32) }
    else { var %d = %n }
    ; If there are no nicknames left in the list then stop
    if (!%d) { return }
    ; Display the nicknames
    echo $colour(info) -ti2 $chan * $nick has also used the nickname $+ $iif($numtok(%d,32) > 1,s:,:) %d
    if (!$istok(%n,$nick,32)) {
      ; Add the current nickname to the list
      hadd trackusers $address($nick,3) %n $nick
    }
  }
  else {
    ; Create a new entry for this mask
    hadd trackusers $address($nick,3) $nick
  }
}
on *:NICK: {
  if ($hget(trackusers,$address($newnick,3))) {
    var %n = $ifmatch
    if (!$istok(%n,$newnick,32)) {
      ; Append the new nickname to the list for this mask
      hadd trackusers $address($newnick,3) %n $newnick
    }
  }
  else {
    ; Create a new entry for this mask
    hadd trackusers $address($nick,3) $newnick
  }
}
menu nicklist {
  Track Users
  .View Other Nicknames:{
    if (!$address($$1,3)) { echo $colour(info) -ti2 # * IAL not updated for $$1 $+ , performing userhost lookup | userhost $$1 | return }
    if ($hget(trackusers,$address($$1,3))) {
      var %n = $ifmatch
      if ($istok(%n,$$1,32)) { var %d = $deltok(%n,$findtok(%n,$$1,1,32),32) }
      else { var %d = %n }
      if (!%d) { goto notknown }
      echo $colour(info) -ti2 # * $$1 has also used the nickname $+ $iif($numtok(%d,32) > 1,s:,:) %d
    }
    else {
      :notknown
      echo $colour(info) -ti2 # * $$1 has not been known by any other nickname
    }
  }
  ; This resets the data for this nick's mask only
  .Reset:hdel trackusers $address($$1,3)
}
ON *:EXIT: {
  ; Save data on exit
  if ($hget(trackusers)) { hsave -o trackusers trackusers.dat }
}

WeiLSiDe 13 Aralık 2008 01:47
Cevap: kanala girenleri takip
 
Spectral
* /hadd: Böyle bir Tablo yok 'trackusers' (Satır 26, script3.amk)
böyle diyo

Difuzyon 13 Aralık 2008 02:58
Cevap: kanala girenleri takip
 
Kod:
on !*:join:#:{
set %nick $nick
set %mask $address($nick,2)
set %nick2 $readini profil.ini %mask nick
set %mask2 $readini profil.ini %mask mask
if %mask == %mask2 && %nick != %nick2 {
set %quand $readini profil.ini %mask quand | beep
$iif(!$window(@IP-Takip),window -z @IP-Takip)
aline -hp @IP-Takip - $- $+($time,-) $+($chr(40),#,$chr(41)) $nick nickinin,bundan önce aynı IP'den giriş yaptığı nick: %nick2 $+($chr(40),%quand,$chr(41))
}
if !$ini(profil.ini,mask) { hashtable }
}
alias hashtable {
if !$hget(profil) { .hmake profil 5 }
else { .hadd profil nick %nick | .hadd profil mask %mask | .hadd profil quand $+($time,-,$date) | .hsave -sai profil profil.ini $hget(profil,mask) | .hfree -s profil }
}
Daha önceden forumda paylaşılmıştı biraz refize ettim.
Kanala girenlerin host bilgisini profil.ini dosyasına başlık olarak açıyor.Bu hosttan farklı bir nick girince ,bir önceki nicki size bildiriyor.
Gün içerisinde 1 kanalda denedim gayet iyi çalışıyor,çoklu kanallarda umarım sorun yaratmaz.Şayet sorun yaratırsa yine bu başlık altında belirtirsiniz.

İyi paylaşımlar...

Spectral 13 Aralık 2008 03:08
Cevap: kanala girenleri takip
 
Alıntı:
WeiLSiDe Nickli Üyeden Alıntı (Mesaj 602922)
Spectral
* /hadd: Böyle bir Tablo yok 'trackusers' (Satır 26, script3.amk)
böyle diyo
kendi eklemesi gerekirdi ama su dosyayi mircin icine atarsan sorun kalmaz
[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]
deneme geregi duymadim cunku kendi mircimde kullaniyorum :)

WeiLSiDe 13 Aralık 2008 15:40
Cevap: kanala girenleri takip
 
Alıntı:
Difuzyon Nickli Üyeden Alıntı (Mesaj 602982)
Daha önceden forumda paylaşılmıştı biraz refize ettim.
Kanala girenlerin host bilgisini profil.ini dosyasına başlık olarak açıyor.Bu hosttan farklı bir nick girince ,bir önceki nicki size bildiriyor.
Gün içerisinde 1 kanalda denedim gayet iyi çalışıyor,çoklu kanallarda umarım sorun yaratmaz.Şayet sorun yaratırsa yine bu başlık altında belirtirsiniz.

İyi paylaşımlar...
Difuzyon bu güzel çalışıyo tşk ederim. Fakat yeni pencere değilde Örneğin
...Giriş asli(xxxx@78.161.176.D49EF966) (Önceki nick vs.) şeklinde yapabilirmiyiz.


Tüm Zamanlar GMT +3 Olarak Ayarlanmış. Şuanki Zaman: 18:14.
Sayfa 1 Toplam 3 Sayfadan 1 23
Konuya ait 40 Mesajı başka Sayfada göster

Powered by vBulletin® Version 3.8.11
Copyright ©2000 - 2025, vBulletin Solutions, Inc.
Search Engine Friendly URLs by vBSEO
Copyright ©2004 - 2025 IRCForumlari.Net Sparhawk