IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası - @Küfür

- mIRC Scripting Sorunları (https://www.ircforumlari.net/mirc-scripting-sorunlari/)

- - @Küfür | Kick/Akick/Msg (https://www.ircforumlari.net/mirc-scripting-sorunlari/168555-kufur-kick-akick-msg.html)

@Küfür | Kick/Akick/Msg

Merhaba değerli arkadaşlar,

Bana lazım olan bir kod var. Yapmaya çalıştım malesef hiç bir sonuç alamadım, yüzüme gözüme bulaştırdım ve sizlere danışmaya karar verdim. :)

Bulunduğum kanal genellerin de küfür içerikli birisi konuştuğu zaman bu küfürlü logu hangi kanalda söylediğini, ve logla beraber ayrı bir pencerede gösterecek bir kod. Aynı durum kick ve akick içinde geçerli. Küfür mesajlarınıda belirleyeceğim txt. dosyasından okuyabilecek böyle bir koda ihtiyacım var.

Bu konuda yardımcı olan arkadaşlara şimdiden teşekkür ederim.

Cevap: @Küfür | Kick/Akick/Msg

anlamadığım veya tereddüt yaşadığım noktaları sorayım gerisi gelir
1- kişi küfür edince @küfür penceresine ne zaman hangi kanalda kim küfür etmiş ve küfürlü mesajı ne bunu pencereye yansıtacaz peki bu küfürleri dosyadan mı okutacaz yoksa kod içerisinden mi? peki sadece bu işlem mi yapacak yoksa atacak mı kicklicek mi ?
2- kanalda bir kick veya akick olduğunda pencereye mi yansıtmak istiyorsun?
3- küfür nedeni ile atacağın kişilere sebep olarak dosyadan mı okutmak istiyorsun
-
daha açık olursan daha iyi olur :)

Cevap: @Küfür | Kick/Akick/Msg

1- Dosyadan okutucaz mümkünse eğer, sadece bu işlemi yapacak, küfür olan logu ayrı pencerede, hangi kanalda söylediğini göstericek logda dahil.

2- Kanalda küfürlü kick ve akick olduğu zaman da ayrı pencerede olacak.

3- Küfür eden kişi kanaldan uzaklaştırılmicak, sebepe gerek yok yani :)

Cevap: @Küfür | Kick/Akick/Msg

Alıntı:

Software Nickli Üyeden Alıntı (Mesaj 611392)

PHP- Kodu:

   on *:text:*:#: {
  var %kufur $lines(kufur.txt)
  while (%kufur > 0) {
    if ($read(kufur.txt,%kufur) isin $strip($1-)) {
      if ($window(@Kufur) == $null) { window -ne @Kufur }
      echo 12 -t @Kufur $Nick Nicki $Chan Kanalında $time Saatinde Şunu Yazdı: $1- 
    }
    dec %kufur
  }
}
 
on *:Kick:#: {
  if *AKICK by* iswm $1-) { $kmsjc(2,$chan,$knick,$remove($4-,$chr(40),$chr(41))) } 
  else { $kmsjc(1,$nick,$knick,$chan,$1-) }
}
alias kmsjc {
  if $1 == 2 {
    var %i = 1 
    while (%i <= $numtok($5-)) {
      if $read(kufur.txt,w,$gettok($5-,%i,32)) { 
        if (!$window(@Kick)) { window -ne @Kick }
        echo 4 -t @Kick Kick: $2 $3 nickli kişiyi $4 kanalından şu sebeple attı: $5- | break
      }
      inc %i 1
    }
  }
  elseif  $1 == 2 { 
    var %i = 1 
    while (%i <= $numtok($3-)) {
      if $read(kufur.txt,w,$gettok($3-,%i,32)) { 
        if (!$window(@Kick)) { window -ne @Kick }
        echo 4 -t @Kick AKICK: $2 kanalından $3 nickli kişi akick nedeniyle atıldı : $3- | break
      }
      inc %i 1
    }
  }
  else { halt }
}

bu kod kick ve akick mesajları eğer kufur.txt'de geçiyorsa @kick penceresine yansıtmakta, yok ben @akick ve @kick pencereleri farklı olsun diyorsan,

PHP- Kodu:

   on *:text:*:#: {
  var %kufur $lines(kufur.txt)
  while (%kufur > 0) {
    if ($read(kufur.txt,%kufur) isin $strip($1-)) {
      if ($window(@Kufur) == $null) { window -ne @Kufur }
      echo 12 -t @Kufur $Nick Nicki $Chan Kanalında $time Saatinde Şunu Yazdı: $1- 
    }
    dec %kufur
  }
}

on *:Kick:#: {
  if *AKICK by* iswm $1-) { 
    var %i $lines(kufur.txt)
    while (%i > 0) {
      if ($read(kufur.txt,%i) isin $strip($4-)) {
        if ($window(@Akick) == $null) { window -ne @Akick }
        echo 4 -t @Akick $nick $knick nickli kişiyi $chan Kanalından şu sebeple attı: $1- 
      }
      dec %i
    }
  }
  else {
    var %i $lines(kufur.txt)
    while (%i > 0) {
      if ($read(kufur.txt,%i) isin $strip($1-)) {
        if ($window(@Kick) == $null) { window -ne @Kick }
        echo 4 -t @Kick $nick $knick nickli kişiyi $chan Kanalından şu sebeple attı: $1- 
      }
      dec %i
    }
  }
}

bu şekilde :)

Cevap: @Küfür | Kick/Akick/Msg

Kod tıkır tıkır saat gibi çalışıyor, teşekkür ederim. Buna sadece kayıtlı nicklerde işlevsel olması için ekleyeceğimiz ne olabilir? Yani sadece kayıtlı nicklerin, küfürlü kick/akicklerin de ve küfürlü mesajlarında

Cevap: @Küfür | Kick/Akick/Msg

pardon ama bir kişi kayıtlı değilse kanalda op olabiliyor mu?

Cevap: @Küfür | Kick/Akick/Msg

Kodun opla alakası yok ki :)

Cevap: @Küfür | Kick/Akick/Msg

kick atacak kişi akick eklicek kişi heralde op olmak zorunda değil mi ben burdan alaka kurdum da çok yorgun olduğumdan dolayı anlamakta bazen güçlük çekiyorum sen tam istediğini gene açıklarsan gerisi gene elir :)

Cevap: @Küfür | Kick/Akick/Msg

Kod:

on *:text:*:#: {

  var %kufur $lines(kufur.txt)

  while (%kufur > 0) {

    if ($read(kufur.txt,%kufur) isin $strip($1-)) { set -e %kfrbz $nick $chan $time $1- | who $nick | .enable #wholist }

    dec %kufur

  }

}

#wholist off

raw 352:*: {

  haltdef

  if $gettok(%kfrbz,1,32) == $6 {

    if *r* iswm $7 { 

      if ($window(@Kufur) == $null) { window -ne @Kufur }

      echo 12 -t @Kufur $6 Nicki $gettok(%kfrbz,2,32) Kanalında $gettok(%kfrbz,3,32) Saatinde Şunu Yazdı: $gettok(%kfrbz,4-,32)

    }

  }

  unset %kfrbz

  if $gettok(%kickfrbz,2,32) == $6 {

    if *r* iswm $7 { 

      if ($window(@Kick) == $null) { window -ne @Kick }

      echo 4 -t @Kick $gettok(%kickfrbz,2,32) $gettok(%kickfrbz,3,32) nickli kişiyi $gettok(%kickfrbz,1,32) Kanalından şu sebeple attı: $gettok(%kickfrbz,4-,32)   

    }

  } 

  unset %kickfrbz

}

raw 315:*:haltdef | .disable #wholist

#wholist end
 

on *:Kick:#: {

  if *AKICK by* iswm $1- { 

    var %i $lines(kufur.txt)

    while (%i > 0) {

      if ($read(kufur.txt,%i) isin $strip($4-)) {

        if ($window(@Akick) == $null) { window -ne @Akick }

        echo 4 -t @Akick $nick $knick nickli kişiyi $chan Kanalından şu sebeple attı: $1- 

      }

      dec %i

    }

  }

  else {

    var %i $lines(kufur.txt)

    while (%i > 0) {

      if ($read(kufur.txt,%i) isin $strip($1-)) { set -e %kickfrbz $chan $nick $knick $1- | who $nick | .enable #wholist }

      dec %i

    }

  }

}

Kanalda geçen küfürlü text mesajlarında ve kick mesajlarında,nick kayıtlı biriyse @uyarı verir.Değilse pas geçecektir.

Akick komutunu uygulayacak kişinin kayıtlı bir nick olması gerektiğinden, küfürlü mesaj varsa direk @uyarı verecektir.

Kolay gelsin.