IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası

- mIRC Scripting Sorunları (https://www.ircforumlari.net/mirc-scripting-sorunlari/)

- - Küfür ve Argo Cümle İçinde (https://www.ircforumlari.net/mirc-scripting-sorunlari/212453-kufur-ve-argo-cumle-icinde.html)

Cevap: Küfür ve Argo Cümle İçinde

Alıntı:

LanetLy Nickli Üyeden Alıntı (Mesaj 1040296957)

PoLye'nin verdiği addonu biLiyorum aynısını uzun yaziLar icin kuLLanıyorum fakat küfür oLarak ayarLadığımda çaLısmıyordu burda görünce burdan aLdım aynısı fakat yine çaLışmıyor aynı kod

arkadaşlar kusura bakmayın karısmamam lazım ama faydam olsun ıstıyorum

bende paylaşım bendekını guzel opers ve ops olarak ayarladım her ıkısındede calısıyor buyurun kulanın

#golge on
on *:text:*:#: {
if ($nick isop #) && (%oplari == on) { return }
if ($nick isvoice #) && (%vlar == on) { return }
if (*buraya muaf tutulacak serveri yazınız iswm $fulladdress) && (%operler == on) { return }
kelimelerim $1-
}
on *:action:*:#: {
if ($nick isop #) && (%oplari == on) { return }
if ($nick isvoice #) && (%vlar == on) { return }
if (*buraya muaf tutulacak serveri yazınız iswm $fulladdress) && (%operler == on) { return }
kelimelerim $1-
}
on *:notice:*:#: {
if ($nick isop #) && (%oplari == on) { return }
if ($nick isvoice #) && (%vlar == on) { return }
if (*buraya muaf tutulacak serveri yazınız iswm $fulladdress) && (%operler == on) { return }
kelimelerim $1-
}
alias kelimelerim {
var %x $strip($1-) , %i $numtok(%soybakalim,44)
while (%i) {
if ($gettok(%soybakalim,%i,44) iswm %x) || ($gettok(%soybakalim,%i,44) isin %x) {
if (%kiketi == on) { /kick $chan $nick %kuralmsg 4(2 $server 4) }
if (%baneti == on) { /shun $nick 1800s 4Dostluk ortamını 2bozmaya calıştıgınızdan uzaklaştırıldınız.! 1 $me }
if (%killeti == on) { /kill $nick 4Dostluk ortamını 2bozmaya calıştıgınızdan uzaklaştırıldınız.! 1 $me }
if (%banlt == on) { /raw -q mode $chan +b $mask($fulladdress,2) | /banac }
if (%zileti == on) { /zline $nick 1800s 4Dostluk ortamını 2bozmaya calıştıgınızdan uzaklaştırıldınız.! 1 $me }
return
}
dec %i
}
}
dialog kelimelerim {
title "Küfür-Reklam Koruma"
size -1 -1 105 183
option dbu
box "Eklenecek Kelimeyi Girin", 1, 5 1 94 79
combo 2, 9 10 87 53, size
button "Ekle", 3, 13 66 31 10
button "Sil", 4, 60 65 31 10
box "", 5, 11 60 36 18
box "", 6, 58 60 36 18
check "Kick ", 8, 62 100 28 10
check "Shun ", 9, 62 111 32 10
edit "", 10, 9936 30 23 12, disable
text "Saniye", 11, 562 32 21 8, disable
check "@plar", 13, 6 98 33 10
check "@perler", 17, 6 87 31 10
check "voice", 14, 6 109 30 10
box "Ayır", 7, 1 80 41 44
check "Ban", 12, 62 122 25 10
check "Kill", 15, 62 133 32 10
check "Z-Line", 16, 62 90 29 8
button "Kapat", 19, 27 155 53 20, ok
box "Ceza-Tipi", 18, 55 82 46 67
}
alias bad { .dialog -m kelimelerim kelimelerim }
on *:dialog:kelimelerim:init:*:{
if (%soybakalim) didtok $dname 2 44 $ifmatch
if (%kiketi) { .did -c $dname 8 }
if (%baneti) { .did -c $dname 9 }
if (%banlt) { .did -c $dname 12 }
if (%oplari) { .did -c $dname 13 }
if (%vlar) { .did -c $dname 14 }
if (%killeti) { .did -c $dname 15 }
if (%zileti) { .did -c $dname 16 }
if (%operler) { .did -c $dname 17 }
did -a $dname 10 %banvaxti
}
on *:dialog:kelimelerim:sclick:*:{
if ($did == 3) {
if ($did(2) != $null) { set -u %artir $did(2) | if (%artir) && (!$istok(%soybakalim,%artir,44)) { .set %soybakalim $addtok(%kifirler,%artir,44) | did -a $dname 2 %artir } }
}
if ($did == 4) { if ($did(2).sel > 0) { .set %soybakalim $remtok(%soybakalim,$did(2).seltext,1,44) | did -d $dname 2 $did(2).sel | did -c $dname 2 1 } }
if ($did == 8) { if ($did(8).state == 1) { .set %kiketi on } | else { .unset %kiketi } }
if ($did == 9) { if ($did(9).state == 1) { .set %baneti on | did -e $dname 10,11 } | else { .unset %baneti | did -b $dname 10,11 } }
if ($did == 12) { if ($did(12).state == 1) { .set %banlt on | did -e $dname 10,11 } | else { .unset %banlt | did -b $dname 10,11 } }
if ($did == 15) { if ($did(15).state == 1) { .set %killeti on | did -e $dname 10,11 } | else { .unset %killeti | did -b $dname 10,11 } }
if ($did == 16) { if ($did(16).state == 1) { .set %zileti on | did -e $dname 10,11 } | else { .unset %zileti | did -b $dname 10,11 } }
if ($did == 13) { if ($did(13).state == 1) { .set %oplari on } | else { .unset %oplari } }
if ($did == 14) { if ($did(14).state == 1) { .set %vlar on } | else { .unset %vlar } }
if ($did == 17) { if ($did(17).state == 1) { .set %operler on } | else { .unset %operler } }
}
on *:dialog:kelimelerim:edit:*:{
%banvaxti = $did(10)
}
#golge end

Cevap: Küfür ve Argo Cümle İçinde

On *:text:*:#: {
var %:kelimeler $lines(kelime.txt)
while %:kelimeler {
if $read(kelime.txt,%:kelimeler) iswm $1- {
kick $chan Kötü kelime kullandınız!
}
dec %:kelimeler
}
}

alias kelime {
if $1 == ekle && $2 {
write kelime.txt $2
}
elseif $1 == sil && $2 {
if $read(kelime.txt,w,$2) {
write $+(-dl,$readn) kelime.txt
}
}
}

kısa bir kod, geliştirmek size kalmış, tabi ben burda öyle text kullandım ama tavsiyem, hash veya users kullanmanızdır.

Cevap: Küfür ve Argo Cümle İçinde

Alıntı:

Difuzyon Nickli Üyeden Alıntı (Mesaj 717443)

Serhat paylaşım yapmış ama bende can sıkıntısından ufak birşeyler hazırlamıştım,belki kullanmak isteyenlere lazım olur.

Kod:

#difiprotect on

on @*:text:*:#:var %jnk = 0, %cenk | while %jnk <= $numtok($1-,32) { %cenk = $strip($token($1-,$v1,32)) | if $hregex(Küfürler,%cenk,0) { ban -k $chan $nick 2 Argo\Küfür sebebiyle atıldın. | halt } | inc %jnk }

#difiprotect end

alias küfürekle {

  if $hget(Küfürler,$1) { echo 06 -a $1 listede mevcut. }

  else {

    hadd -m Küfürler $1 1

    hsave -i Küfürler Küfürler.data

    echo 07 -a $1 Argo\Küfür listesine eklendi.

  }

}

alias küfürsil {

  if !$hget(Küfürler,$1) { echo 06 -a $1 listede yok }

  else {

    hdel Küfürler $1

    hsave -i Küfürler Küfürler.data

    echo 07 -a $1 Argo\Küfür listesinden silindi.

  }

}

alias küfürlist {

  $iif(!$window(@Küfürler),window -nz @Küfürler,clear @Küfürler)

  aline 04 @Küfürler Küfür Listesi

  var %dify 1 | while %dify <= $hget(Küfürler,0).item { aline -h 02 @Küfürler $hget(Küfürler,%dify).item | inc %dify }

  aline -h 05 @Küfürler Toplam $hget(Küfürler,0).item veri mevcut.

}

on *:start:.hload Küfürler Küfürler.data

menu channel {

  .Küfür Koruması

  ..Aç:.enable #difiprotect | echo 04 -a Koruma Açık | echo 02 -a Küfür eklemek için /küfürekle kelime | echo 02 -a Küfür silmek için /küfürsil kelime | echo 02 -a Liste için /küfürlist

  ..Kapa:.disable #difiprotect | echo 12 -a Koruma Kapalı

}

Hoşca paylaşımlar...

Arkadaşlar kod güzel çalışıyor ama kelimeleri tam olarak nasıl eklememiz gerekiyor? Bu kod hakkında bilgi verebilecek arkadaş var mı? yani
Örnek ; /küfürekle salak şeklinde mi? yoksa /küfüekle *salak* gibi mi eklemek gerekiyo

Cevap: Küfür ve Argo Cümle İçinde

Alıntı:

Difuzyon Nickli Üyeden Alıntı (Mesaj 717443)

Serhat paylaşım yapmış ama bende can sıkıntısından ufak birşeyler hazırlamıştım,belki kullanmak isteyenlere lazım olur.

Kod:

#difiprotect on

on @*:text:*:#:var %jnk = 0, %cenk | while %jnk <= $numtok($1-,32) { %cenk = $strip($token($1-,$v1,32)) | if $hregex(Küfürler,%cenk,0) { ban -k $chan $nick 2 Argo\Küfür sebebiyle atıldın. | halt } | inc %jnk }

#difiprotect end

alias küfürekle {

  if $hget(Küfürler,$1) { echo 06 -a $1 listede mevcut. }

  else {

    hadd -m Küfürler $1 1

    hsave -i Küfürler Küfürler.data

    echo 07 -a $1 Argo\Küfür listesine eklendi.

  }

}

alias küfürsil {

  if !$hget(Küfürler,$1) { echo 06 -a $1 listede yok }

  else {

    hdel Küfürler $1

    hsave -i Küfürler Küfürler.data

    echo 07 -a $1 Argo\Küfür listesinden silindi.

  }

}

alias küfürlist {

  $iif(!$window(@Küfürler),window -nz @Küfürler,clear @Küfürler)

  aline 04 @Küfürler Küfür Listesi

  var %dify 1 | while %dify <= $hget(Küfürler,0).item { aline -h 02 @Küfürler $hget(Küfürler,%dify).item | inc %dify }

  aline -h 05 @Küfürler Toplam $hget(Küfürler,0).item veri mevcut.

}

on *:start:.hload Küfürler Küfürler.data

menu channel {

  .Küfür Koruması

  ..Aç:.enable #difiprotect | echo 04 -a Koruma Açık | echo 02 -a Küfür eklemek için /küfürekle kelime | echo 02 -a Küfür silmek için /küfürsil kelime | echo 02 -a Liste için /küfürlist

  ..Kapa:.disable #difiprotect | echo 12 -a Koruma Kapalı

}

Hoşca paylaşımlar...

bu kode muaf kanal ve muaf nick eklenebilir mi ?

Cevap: Küfür ve Argo Cümle İçinde

Kod:

#difiprotect on

on @*:text:*:#:{ if $istok(#kanal #kanal1,#,32) || $istok(nick nick1 nick2,$nick,32) { return } 

var %jnk = 0, %cenk | while %jnk <= $numtok($1-,32) { %cenk = $strip($token($1-,$v1,32)) | if $hregex(Küfürler,%cenk,0) { ban -k $chan $nick 2 Argo\Küfür sebebiyle atıldın. | halt } | inc %jnk } }

#difiprotect end

alias küfürekle {

  if $hget(Küfürler,$1) { echo 06 -a $1 listede mevcut. }

  else {

    hadd -m Küfürler $1 1

    hsave -i Küfürler Küfürler.data

    echo 07 -a $1 Argo\Küfür listesine eklendi.

  }

}

alias küfürsil {

  if !$hget(Küfürler,$1) { echo 06 -a $1 listede yok }

  else {

    hdel Küfürler $1

    hsave -i Küfürler Küfürler.data

    echo 07 -a $1 Argo\Küfür listesinden silindi.

  }

}

alias küfürlist {

  $iif(!$window(@Küfürler),window -nz @Küfürler,clear @Küfürler)

  aline 04 @Küfürler Küfür Listesi

  var %dify 1 | while %dify <= $hget(Küfürler,0).item { aline -h 02 @Küfürler $hget(Küfürler,%dify).item | inc %dify }

  aline -h 05 @Küfürler Toplam $hget(Küfürler,0).item veri mevcut.

}

on *:start:.hload Küfürler Küfürler.data

menu channel {

  .Küfür Koruması

  ..Aç:.enable #difiprotect | echo 04 -a Koruma Açık | echo 02 -a Küfür eklemek için /küfürekle kelime | echo 02 -a Küfür silmek için /küfürsil kelime | echo 02 -a Liste için /küfürlist

  ..Kapa:.disable #difiprotect | echo 12 -a Koruma Kapalı

}

Buyrun

Cevap: Küfür ve Argo Cümle İçinde

on *:text:$(* $+ salak $+ *):#: /kick sebep $nick
on *:text:$(* $+ manyak $+ *):#: /kick sebep $nick

bu şekilde uzata bilirsin denemedim buna benzer bişey yapmıştım ondan editledim dene haber ver

İstediğin kadar uzun cümle içerisinde yukarıdakilerden biri yazsa dahi işlem yapar

Cevap: Küfür ve Argo Cümle İçinde

Alıntı:

eXLove Nickli Üyeden Alıntı (Mesaj 1041494333)

on *:text:$(* $+ salak $+ *):#: /kick # $nick Sebep-
on *:text:$(* $+ manyak $+ *):#: /kick # $nick Sebep-

bu şekilde uzata bilirsin denemedim buna benzer bişey yapmıştım ondan editledim dene haber ver

İstediğin kadar uzun cümle içerisinde yukarıdakilerden biri yazsa dahi işlem yapar

doğrusu böyle olucak

Cevap: Küfür ve Argo Cümle İçinde

Kod:

on *:text:$(* $+ salak $+ *):#: /kick # $nick Sebep-

on *:text:$(* $+ manyak $+ *):#: /kick # $nick Sebep-

Text event'ında bir tanım(identifier), alias vb. kullanmıyorsanız $() evaluate etmeye gerek yok.

Örnek:

Kod:

on *:text:*salak*:#: /kick # $nick Sebep-

üstteki şekilde kullanabilirsiniz.

Ayrıca text event'ında matchtext(eşleşen/yakalanan metin) kısmında regex ile çoklu kelime belirtebilirsiniz. Bu sayede birden fazla event kullanılmamış olur.

Örnek:

Kod:

on $*:text:/salak|manyak|aptal/Si:#: /kick # $nick Sebep-