IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası
Sayfa 1 Toplam 2 Sayfadan 1 2
Konuya ait 40 Mesajı başka Sayfada göster

IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası (https://www.ircforumlari.net/)
-   mIRC Scripting Sorunları (https://www.ircforumlari.net/mirc-scripting-sorunlari/)
-   -   clone (https://www.ircforumlari.net/mirc-scripting-sorunlari/213167-clone.html)

sniper 25 Mayıs 2009 14:44
clone
 
/clone #kanal yaptığımda o kanaldaki cloneleri nasıl görebilirim arkadaşlar aynı ipten kaç kişi var ayrı bir pencerede görmemiz mümkünmü acaba nick leri

insane 25 Mayıs 2009 17:09
Cevap: clone
 
Kod:
menu menubar {
  .-
  » Clone Tarayıcı :Clonescan
}
alias clonescan {
  if ($chan == $null) && ($1 == $null) { echo -a [clones]: Syntax: /clonescan #chan $+ $chr(124) $+ config | halt  }
  if ($1 == $null) { %cscan.chan = $chan }
  elseif ($1 ischan) { %cscan.chan = $1 }
  if ($dialog(clone.dialog) == $null) { dclonescan }
  filldialogchan
  if ($1 != config) { .timercallcscan -m 1 10 cscan %cscan.chan }
}
alias cscan {
  %cscan.chan = $1 | %cscan.total = $nick($1,0) | %cscan.clone.num = 0
  .enable #who.halt | .quote WHO %cscan.chan
  :loop
  if (%cscan.total == 0) { goto end }
  %cscan.clone = $ialchan($address($nick(%cscan.chan,%cscan.total),2),%cscan.chan,0)
  %cscan.host = $address($nick(%cscan.chan,%cscan.total),2)
  if (%cscan.clone > 1) {
    if (%cscan.info. [ $+ [ %cscan.host ] ] != $null) { goto endb }
    %cscan.info. [ $+ [ %cscan.host ] ] = 1
    :loopa
    if (%cscan.clone == 0) { goto enda }
    inc %cscan.clone.num
    if ($istok(%cscan.clone.nicks,$ialchan(%cscan.host,%cscan.chan,%cscan.clone).nick,32) == $true) { dec %cscan.clone | goto loopa }
    %cscan.clone.nicks = %cscan.clone.nicks $ialchan(%cscan.host,%cscan.chan,%cscan.clone).nick
    dec %cscan.clone | goto loopa 
    :enda
    did -a clone.dialog 14 $space(3) $ialchan(%cscan.host,%cscan.chan,0) $space(6) $right(%cscan.host,$calc($len(%cscan.host) - 4)) ( $+ %cscan.clone.nicks $+ )
    unset %cscan.clone.nicks
  }
  :endb
  dec %cscan.total | goto loop
  :end
  if (%cscan.clone.num == 0) { did -a clone.dialog 14 $space(3) 0 $space(6) no clones found | unset %cscan* | halt }
  unset %cscan*
}
alias jcscan {
  %cscan.chan = $1 | %cscan.total = $nick(%cscan.chan,$2) | %cscan.clone.num = 0
  %cscan.clone = $ialchan($address($nick(%cscan.chan,%cscan.total),2),%cscan.chan,0)
  %cscan.host = $address($nick(%cscan.chan,%cscan.total),2)
  if (%cscan.clone > 1) {
    if (%cscan.info. [ $+ [ %cscan.host ] ] != $null) { goto end }
    %cscan.info. [ $+ [ %cscan.host ] ] = 1
    :loop
    if (%cscan.clone == 0) { goto end }
    inc %cscan.clone.num
    if ($istok(%cscan.clone.nicks,$ialchan(%cscan.host,%cscan.chan,%cscan.clone).nick,32) == $true) { dec %cscan.clone | goto loopa }
    %cscan.clone.nicks = %cscan.clone.nicks $ialchan(%cscan.host,%cscan.chan,%cscan.clone).nick
    dec %cscan.clone | goto loop
    :end
    echo %cscan.chan 10 clones :  $+ $ialchan(%cscan.host,%cscan.chan,0) $+  10Aynı İp  $+ $right(%cscan.host,$calc($len(%cscan.host) - 4)) $+  4[10 $+ %cscan.clone.nicks $+ 4]
    if ($me !isop %cscan.chan) { goto e }
    if ($readclones(clones,joinkickban) == on) { .quote MODE %cscan.chan +b *!*@ $+ $right(%cscan.host,$calc($len(%cscan.host) - 4)) }
    if ($readclones(clones,joinkick) == on) || ($readclones(clones,joinkickban) == on) { if ($readclones(clones,kickm) == on) { _ckick %cscan.chan $right(%cscan.host,$calc($len(%cscan.host) - 4)) $readclones(clones,kickmsg) } | else { _ckick %cscan.chan $right(%cscan.host,$calc($len(%cscan.host) - 4)) } }
    :e
    unset %cscan*
  }
}
 
on !*:join:#:{ if ($readclones(clones,joindetect) == on) { jcscan $chan $nick } }
 
#who.halt off
raw 352:*:halt
raw 315:*:.disable #who.halt | halt
#who.halt end
alias dclonescan { dialog -m clone.dialog clone.dialog }
dialog clone.dialog {
  title "HiperAlem Clone Scan"
  option dbu
  size -1 -1 200 180
  box " Kanal ", 1, 5 2 70 24
  combo 2, 10 10 60 40, drop
  box " Action ", 3, 5 30 70 36
  button "Tarama", 4, 9 39 30 10
  button "Ban", 5, 41 39 30 10
  button "Kick", 6, 9 51 30 10
  button "Akick", 7, 41 51 30 10
  box "", 8, 5 71 189 85
  text "Kisi", 9, 14 78 14 10
  text "Nick/Adres", 10, 32 78 25 10
  list 14, 9 86 181 74, vsbar hsbar
  box "", 15, 80 2 114 64
  check " Clone Girisini Göster", 16, 85 7 62 12
  check " Giren Clonu Kickle", 17, 85 18 60 12
  check " Giren Clonu Banla", 18, 85 29 70 12
  check " Clone Kick Sebebi", 19, 85 40 64 11
  edit "", 20, 85 51 104 11, autohs limit 150
  button "Kapat", 21, 83 157 36 13, cancel
  box "Coded by Dusunceler", 22, 60 170 78 10
}
on *:dialog:clone.dialog:init:*:{ unset %cfg.* | did -r clone.dialog 14 | did -m clone.dialog 20 | fillcloneoptions }
on *:dialog:clone.dialog:sclick:*:{
  if ($did == 4) { if ($did(clone.dialog,2) == $null) { halt } | else { did -r clone.dialog 14 | cscan $did(clone.dialog,2) } }
  if ($did == 5) { if ($did(clone.dialog,2) == $null) { halt } | else { if ($me isin $did(clone.dialog,2)) { halt } | /cs akick $did(clone.dialog,2) add *!*@ $+ $gettok($did(clone.dialog,14,$did(clone.dialog,14).sel),4,32) 1,7 « Clone Girişi Yasaktır »  7,1 « HiperAlem Script »  | /cs akick $did(clone.dialog,2) enforce | /cs akick $did(clone.dialog,2) del *!*@ $+ $gettok($did(clone.dialog,14,$did(clone.dialog,14).sel),4,32) 1,7 ~ Clone Protections ~   } }
  if ($did == 6) { if ($did(clone.dialog,2) == $null) { halt } | else { if ($me isin $did(clone.dialog,2)) { halt } | /cs akick $did(clone.dialog,2) add *!*@ $+ $gettok($did(clone.dialog,14,$did(clone.dialog,14).sel),4,32) 1,7 « Clone Girişi Yasaktır »  7,1 « HiperAlem Script »  | /cs akick $did(clone.dialog,2) enforce | /cs akick $did(clone.dialog,2) del *!*@ $+ $gettok($did(clone.dialog,14,$did(clone.dialog,14).sel),4,32) 1,7 ~ Clone Protections ~   } }
  if ($did == 7) { if ($did(clone.dialog,2) == $null) { halt } | else { if ($me isin $did(clone.dialog,2)) { halt } | /cs akick $did(clone.dialog,2) add *!*@ $+ $gettok($did(clone.dialog,14,$did(clone.dialog,14).sel),4,32) 1,7 « Clone Girişi Yasaktır »  7,1 « HiperAlem Script »  | /cs akick $did(clone.dialog,2) enforce | /cs akick $did(clone.dialog,2) del *!*@ $+ $gettok($did(clone.dialog,14,$did(clone.dialog,14).sel),4,32) 1,7 ~ Clone Protections ~   } }
  if ($did == 16) { if ($did(clone.dialog,16).state == 1) { %cfg.joindetect = on } | else { %cfg.joindetect = off } }
  if ($did == 17) { if ($did(clone.dialog,17).state == 1) { did -u clone.dialog 18 | %cfg.kick = on | %cfg.kickban = off } | else { %cfg.kick = off | if ($did(clone.dialog,18).state == 1) { %cfg.kickban = on } | else { %cfg.kickban = off } } }
  if ($did == 18) { if ($did(clone.dialog,18).state == 1) { did -u clone.dialog 17 | %cfg.kickban = on | %cfg.kick = off } | else { %cfg.kickban = off | if ($did(clone.dialog,17).state == 1) { %cfg.kick = on } | else { %cfg.kick = off } } }
  if ($did == 19) { if ($did(clone.dialog,19).state == 0) { did -m clone.dialog 20 | %cfg.kickm = off } | else { did -n clone.dialog 20 | %cfg.kickm = on | %cfg.kickmsg = $did(clone.dialog,20).text } }
  if ($did == 21) { %cfg.kickmsg = $did(clone.dialog,20).text | .timersavecloneS -  m 1 100 savecloneoptions }
}
alias fillcloneoptions {
  if ($readclones(clones,joindetect) == on) { did -c clone.dialog 16 | %cfg.joindetect = on }
  if ($readclones(clones,joinkick) == on) { did -c clone.dialog 17 | %cfg.kick = on }
  if ($readclones(clones,joinkickban) == on) { did -c clone.dialog 18 | %cfg.kickban = on }
  if ($readclones(clones,kickm) == on) { did -c clone.dialog 19 | did -n clone.dialog 20 | did -a clone.dialog 20 $readclones(clones,kickmsg) | %cfg.kickm = on }
}
alias savecloneoptions {
  if (%cfg.joindetect != $null) { writeclones clones joindetect %cfg.joindetect }
  if (%cfg.kick != $null) { writeclones clones joinkick %cfg.kick | if (%cfg.kickban == off) { writeclones clones joinkickban off } }
  if (%cfg.kickban != $null) { writeclones clones joinkickban %cfg.kickban | if (%cfg.kick == off) { writeclones clones joinkick off } }
  if (%cfg.kickm != $null) { writeclones clones kickm %cfg.kickm | writeclones clones kickmsg %cfg.kickmsg }
}
alias space { if ($1 == $null) { return $chr(160) } | if ($1 !isnum) { halt } | return $str($chr(160),$1) }
alias _ckick {
  var %ckick.chan $1, %ckick.total $nick($1,0), %ckick.host *!*@ $+ $2, %ckick.reason $3-
  if ($1 == $null) || ($2 == $null) { halt }
  :loop
  if (%ckick.total == 0) { goto end }
  if ($nick(%ckick.chan,%ckick.total) == $me) { dec %ckick.total | goto loop }
  if (%ckick.host == $address($nick(%ckick.chan,%ckick.total),2)) { if (%ckick.reason == $null) { .quote KICK %ckick.chan $nick(%ckick.chan,%ckick.total) :10Clones Forbidden!  3 %ckick.host )( %soul  } | else { .quote KICK %ckick.chan $nick(%ckick.chan,%ckick.total) : $+ %ckick.reson } }
  dec %ckick.total
  goto loop
  :end
}
alias filldialogchan {
  var %dchan $chan(0), %daux 1
  :loop
  if (%daux > %dchan) { goto end }
  did -a clone.dialog 2 $chan(%daux)
  if ($chan(%daux) == %cscan.chan) { did -c clone.dialog 2 %daux }
  inc %daux
  goto loop
  :end
}
alias readclones {
  if ($1 == $null) || ($2 == $null) { halt }
  return $readini clones.ini $1 $2
}
alias writeclones {
  if ($1 == $null) || ($2 == $null) || ($3 == $null) { halt }
  .writeini clones.ini $1 $2 $3-
}
alias makeclonesconf { writeclones clones joindetect on | writeclones clones joinkick off | writeclones clones joinkickban off | writeclones clones kickm off }
Elimde böyle bir Clone tarama addonu var...
Umarım işine yarar..

-X- 25 Mayıs 2009 18:36
Cevap: clone
 
eline sağlık.

sniper 25 Mayıs 2009 19:07
Cevap: clone
 
iyi güzel ama çokuzun code script'i kasar diye düşünüyom, Başka yardımcı olacak arkadaş varmı acaba veya yazacak şimdiden tşk.

-X- 25 Mayıs 2009 19:33
Cevap: clone
 
PHP- Kodu:
 ;Clone Koruması
#cLonekorumaSi on
on @!*:JOIN:#:{
  if ($ialchan($wildsite,#,0) > %clonesayi) {
    var %' = $ifmatch, %. | while %' {
      var %7 = $gettok($ialchan($wildsite,#,%'),1,33)
    if (%7 !isop #) { %. = $addtok(%.,%7,44) | dec %' } | else { return } }
    if %. { mode # +b $wildsite | var %~ = $numtok(%.,44) | while %~ { kick # $gettok(%.,%~,44) %clonekorumasebep | dec %~ } }
  }
}
#cLonekorumaSi end
alias clonekoruma { dialog -m clonekorumasi clonekorumasi }
dialog clonekorumasi {
  title "Clone Korumasi"
  size -1 -1 144 88
  option dbu
  text "Kanal'a", 1, 9 7 20 8
  edit "", 2, 30 6 13 10
  text "Den Fazla Clone Girerse o Adresi Banla", 3, 43 7 100 8
  box "Durum", 4, 5 19 135 37
  button "Aç", 5, 23 27 37 12
  button "Kapat", 6, 83 27 37 12
  text "Durum:", 7, 35 44 22 8
  edit "", 8, 57 44 50 10, read
  edit "", 9, 44 60 97 10, autohs
  text "Kick Sebebiniz", 10, 4 61 40 8
  button "Kaydet Ve Çık", 11, 22 72 46 12, ok
  button "İptal", 12, 73 72 46 12, cancel
}
on *:dialog:clonekorumasi:*:*:{
  if ($devent == init) {
    did -a $dname 8 %clonekorumadurum
    did -a $dname 9 %clonekorumasebep
    did -a $dname 2 %clonesayi
  }
  if ($devent == sclick) {
    if ($did == 5) { .enable #cLoneKorumaSi | set %clonekorumadurum Açık | set %clonekorumasebep $did(9) | set %clonesayi $did(2) | dialog -x clonekorumasi clonekorumasi | clonekoruma }
    if ($did == 6) { .disable #cLoneKorumaSi | set %clonekorumadurum Kapalı | set %clonekorumasebep $did(9) | set %clonesayi $did(2) | dialog -x clonekorumasi clonekorumasi | clonekoruma }
    if ($did == 11) {  set %clonekorumasebep $did(9) | set %clonesayi $did(2) }
  } 

arkadaşım variableslere girip bunlari oraya yapistirdiginizda Koruma dialogunda otomatik olarak yazdiginiz ayarla cikacak.. Yada Korumayi Yüklediginizde Bos gelicek ayarlar O bos olan yerlere gerekenleri eklediginizde asagida verdigim bilgiler otomatik olarak variableslere eklenecektir..


%clonekorumasebep (Kendiniz Ayarlayabilirsiniz)
%clonesayi (Kendiniz ayarlayabilirsiniz)
%clonekorumadurum Açık

Skys 25 Mayıs 2009 19:39
Cevap: clone
 
alias Clone {
var %ğ = $nick(#,0)
while %ğ {
if !$hget(host,$address($nick(#,%ğ),2)) { hadd -m host $address($nick(#,%ğ),2) 1 }
else { hinc host $address($nick(#,%ğ),2) }
dec %ğ
}
echo 4 -a # kanalı için clone taraması başlatıldı...
echo -s -
.timer 1 1 .h_al #
}
alias h_al {
var %ı = $hget(host,0).item
while %ı {
if $hget(host,%ı).data > 1 {
set %y_k yes
var %ç = $nick($1,0)
while %ç {
if $hget(host,%ı).item == $address($nick($1,%ç),2) { set %_cln $addtok(%_cln,$nick($1,%ç),32) }
dec %ç
}
echo 12 -a 2Adres: $hget(host,%ı).item --- 10Bağlı kullanıcı sayısı: $hget(host,%ı).data --- 4Bağlı rumuzlar: 5 $gettok(%_cln,1-,32)
unset %_cln
}
dec %ı
}
echo -s -
$iif($(%y_k,2) != yes,echo 4 -a $1 kanalında clone bulunamadı.,echo 4 -a $1 kanalı için clone taraması tamamlandı.)
unset %y_k
hfree host
}
menu channel {
.-
.Clone Tara:.Clone #
}


Sniper ,
işine Yarıcağına Eminim.

Difuzyon 25 Mayıs 2009 21:44
Cevap: clone
 
[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]

İncelemeni tavsiye ederim...

sniper 25 Mayıs 2009 23:51
Cevap: clone
 
Hepsi süper sağolun ağalar.

DeccaLAop 13 Ağustos 2009 17:16
Cevap: clone
 
Arkadaşlar oto klone taraması yapıp normal bulunduğumuz pencerelerde göstericek olan 1 remote var mı ??? ;(

dennis 14 Ağustos 2009 01:34
Cevap: clone
 
Kod:
on *:join:#: {
  %clone = $ialchan($wildsite,#,0)
  if (%clone == 2) {
    var %c = 1
    set %clonenck csr
    while (%c <= %clone)  {
      %clonenck = %clonenck  $ial($wildsite,%c).nick
    inc %c  }
    dialog -m clone clone
    .set %den1 $gettok($remove(%clonenck,csr),1,32)
    .set %den2 $gettok($remove(%clonenck,csr),2,32)
    .set %den3 $gettok($remove(%clonenck,csr),3,32)
  }
  set %change $read -s $+ $address($nick,4) notes.ini
  if (%change == $null) {
    haltdef
    halt 
  }
}
dialog Clone {
  title "Clone İşlem"
  size -1 -1 106 54
  option dbu
  box "Clonelere Uygulanacak  Komut?", 1, 2 0 102 52
  button "Kick", 2, 71 13 27 12, ok
  button "Kill", 3, 38 13 27 12, ok
  button "Z-Line", 4, 6 13 27 12, ok
  button "Kapat", 5, 33 33 37 12, ok cancel
}
on *:dialog:clone:sclick:*:{
  if ($did == 2) { kick %den1 Clone | unset %den1 %den2 %den3 }
  if ($did == 3) { kill %den1 Clone | kill %den2 Clone | kill %den3 Clone | unset %den1 %den2 %den3 }
  if ($did == 4) { zline %den1 Clone | unset %den1 %den2 %den3 }
  if ($did == 5) { unset %den1 %den2 %den3 }
}
Sanırım Böyle bişe arıyosunuz. Kanala clone girdiğinde Panel acılır secilen işlemi uygular


Tüm Zamanlar GMT +3 Olarak Ayarlanmış. Şuanki Zaman: 13:22.
Sayfa 1 Toplam 2 Sayfadan 1 2
Konuya ait 40 Mesajı başka Sayfada göster

Powered by vBulletin® Version 3.8.8 Beta 3
Copyright ©2000 - 2024, vBulletin Solutions, Inc.
Search Engine Friendly URLs by vBSEO
Copyright ©2004 - 2024 IRCForumlari.Net