| Heavenly | 27 Mayıs 2009 13:39 |
Cevap: ame amsg yasaklama
Kod:
dialog amele {
title "Ame-Amsg Muaf Menu"
size -1 -1 125 104
option dbu
tab "Ame", 1, 3 2 119 99
combo 3, 10 28 60 68, tab 1 size
button "Ekle", 4, 78 28 37 12, tab 1
button "SiL", 5, 78 48 37 12, tab 1
tab "Amsg", 2
combo 6, 10 28 60 68, tab 2 size
button "Ekle", 7, 78 28 37 12, tab 2
button "SiL", 8, 78 48 37 12, tab 2
box "#Kanal Şeklinde Ekleyebilirsiniz", 9, 6 18 112 80
}
alias amele dialog -m amele amele
alias ame { haltdef | var %i 0 | var %t $chan(0) | while %i < %t { inc %i | if $istok(%muafame,$chan(%i),32) != $true { describe $chan(%i) $1- } } }
alias amsg { haltdef | var %i 0 | var %t $chan(0) | while %i < %t { inc %i | if $istok(%muafamsg,$chan(%i),32) != $true { msg $chan(%i) $1- } } }
on *:dialog:amele:init:*:{
if (%muafame) .didtok $dname 3 32 $ifmatch
if (%muafamsg) .didtok $dname 6 32 $ifmatch
}
on *:dialog:amele:sclick:*: {
;ame icin muafiyet
if ($did == 4) { if ($did(3) != $null) { set -u %sk $did(3) | if (%sk) && (!$istok(%muafame,%sk,32)) { .set %muafame $addtok(%muafame,%sk,32) | did -a $dname 3 %sk } } }
if ($did == 5) { if ($did(3).sel > 0) { .set %muafame $remtok(%muafame,$did(3).seltext,1,32) | did -d $dname 3 $did(3).sel | did -c $dname 3 1 } }
;amsg icin muafiyet
if ($did == 7) { if ($did(6) != $null) { set -u %sk $did(6) | if (%sk) && (!$istok(%muafamsg,%sk,32)) { .set %muafamsg $addtok(%muafamsg,%sk,32) | did -a $dname 6 %sk } } }
if ($did == 8) { if ($did(6).sel > 0) { .set %muafamsg $remtok(%muafamsg,$did(6).seltext,1,32) | did -d $dname 6 $did(6).sel | did -c $dname 6 1 } }
}
menu channel,menubar,status {
Ame-Amsg-Muaf:/amele
}
mırc'ınde herhangı bı ame amsg kodu varsa onları sıl bu dıyalog seklınde ıstedıgın kadar kanal ekle sıl cok daha kullanıslı ben kullanıyorum cokta ısıme yaradı |
