IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası

- mIRC Scripting Sorunları (https://www.ircforumlari.net/mirc-scripting-sorunlari/)

- - Nick Takip sorun (https://www.ircforumlari.net/mirc-scripting-sorunlari/355111-nick-takip-sorun.html)

Nick Takip sorun

on 1:connect:{
.IAL ON
takip + 300
}
alias takip {
if $1 == + {
$iif($hget(Takip),hfree Takip)
.enable #Takip | $iif(!$hget(Takip),hmake Takip 10000000)
set %cSj $iif($2,$2,300)
echo -ta 4Takip Modu Devrede!.. $+([,%cSj,sn.,])
}
else {
.disable #Takip
unset %cSj
echo -ta 14Takip Modu DevreDışı !
}
}
#Takip on
on ^*:QUIT:{
hadd $iif($address($nick,2),$+(-u,%cSj),$+(-u1)) Takip $address($nick,2) $iif($istok($hget(Takip,$address($nick,2)),$nick,3 2),$hget(Takip,$address($nick,2)),$iif($hget(Takip ,$address($nick,2)),$hget(Takip,$address($nick,2)) + $nick,$nick))
}
on !^*:JOIN:#:{
if ($hget(Takip,$address($nick,2)) && $hget(Takip,$address($nick,2)) != $nick) {
//echo $chan 2**** 1 5 Rapor : 2 $chan Kanalına giren 6 $nick 2 nickinin daha önce kullandığı nickler: 6 $hget(Takip,$address($nick,2)) 5 IP adresi : 2 $address($nick,2)) )
}
if $gettok($hget(Takip,$address($nick,2)).data,0,43) > 3 {
ban -k $chan $nick 2 Nick Change
}
}
#Takip end
;ac: /takip + 1000
;kapa: /takip

Şu kod eklediğimde çalışıyordu bir sonraki gün hata vermeye başladı

* /hadd: no such table 'Takip' (line 21, script7.txt)
-
* /hadd: no such table 'Takip' (line 21, script7.txt)
-
* /hadd: no such table 'Takip' (line 21, script7.txt)
-

sorun nasıl düzeltebiliriz

Cevap: Nick Takip sorun

Alıntı:

aldanis Nickli Üyeden Alıntı (Mesaj 1040519070)

kırmızı olan yer 300 olması gerekli koda göre

Cevap: Nick Takip sorun

Kod:

on 1:connect:{ .IAL On | takip + 1000 }

alias takip { 

  if $1 == + { $iif($hget(Takip),hfree Takip) | .enable #Takip | $iif(!$hget(Takip),hmake Takip 1000) | set %cSj $iif($2,$2,300) | echo -ta 4Takip Modu Devrede!.. $+([,%cSj,sn.,]) }

  else { .disable #Takip | unset %cSj | echo -ta 14Takip Modu DevreDışı ! } 

}

#Takip on

on ^*:QUIT:{ hadd $iif($address($nick,2),$+(-u,%cSj),$+(-u1)) Takip $address($nick,2) $iif($istok($hget(Takip,$address($nick,2)),$nick,3 2),$hget(Takip,$address($nick,2)),$iif($hget(Takip ,$address($nick,2)),$hget(Takip,$address($nick,2)) + $nick,$nick)) }

on !^*:JOIN:#:{ 

  if ($hget(Takip,$address($nick,2)) && $hget(Takip,$address($nick,2)) != $nick) { echo -t $chan 4Takip Raporu:12 $nick 5nickinin %cSj saniye içinde kullandığı nickler:14 $hget(Takip,$address($nick,2)) }

  if $gettok($hget(Takip,$address($nick,2)).data,0,43) > 3 { ban -k $chan $nick 2 Nick Change } 

}

#Takip end

bunu dene birde

Cevap: Nick Takip sorun

Güncel;

Bu ve benzeri kodlar genelde: * /hadd: Böyle bir Tablo yok 'Takip' (Satır 116, core.mrc) gibi hatalar veriyor. Çoğu kodu denedim yine hata verdi. Son kodu denedim. * /hadd: Böyle bir Tablo yok 'Takip' hatası geldi.

Cevap: Nick Takip sorun

Kodu remote kısmına ekledikten sonra sunucuya yeniden connect olunması halinde Takip tablosu aktif hale gelecektir.

Cevap: Nick Takip sorun

Teşekkürler sorun halloldu ama şöyle bir sorun var.

Raporlar;

[23:29:06] *** IRC`den Çıktı: Kelebek35863 (KELEBEK@84.22.5797CEEF.CC4B3252) (Excess Flood)
Takip Raporu: Kelebekv6Script64 nickinin 1000 saniye içinde kullandığı nickler: Kelebekv6Script822
[23:29:07] *** Giriş: Kelebekv6Script64 (KLBKScript@78.175.A013A723.993614D1)

Şeklinde nickin üstünde geliyor. Girişlerde inanılmaz bir karmaşa oluyor. Neyin ne olduğunu çözemiyorsun bazen kim kime ait kim kimin clonu çözüm zor.

Bunun için raporların ekranda gösterimini;

[23:29:07] *** Giriş: Kelebekv6Script64 (KLBKScript@78.175.A013A723.993614D1) Daha önceki nickleri: Kelebekv6Script822

Gibi yapma imkanımız var mı?

Cevap: Nick Takip sorun

mirc'inizde başka JOIN eventi(kanala giriş uyarısı) olmadıgından emin olunuz.
eger varsa o kıs'mı kaldırınız kod istediginiz şekilde çalışacakdır..

Kod:

on ^*:join:#:echo # [ $+ $time $+ ] *** Giriş: $nick ( $+ $address $+ ) | halt

Gibi kod olması lazım kaldırınız.

Cevap: Nick Takip sorun

/hadd komutunu kullanırken tablo oluşturulmamış ise, oluşturma parametresi ile beraber kullanın her zaman. Çünkü bu şekilde kullandığınızda, tablo oluşturulmuş olsa bile hiçbir sıkıntı olmaz. Ama tablo oluşturulmamış ise, direk oluşturur.

Yani kısacası: /hadd -m tablo parça değer(..)

Koda gelecek olursak kodun çalışma mantığı biraz farklı geldi bana. Birden çok aynı sorgular kullanılmış.
Bir istek üzerine çok önceden yazdığım kodu paylaşacağım. İşinizi fazlasıyla görür.

Kod:

on ^!*:join:#: {

  haltdef
   var %_itime = 600

  var %_ilimit = 3

  hadd -mu $+ $iif($hget(_i,$site).unset,$v1,%_itime) _i $site $addtok($hget(_i,$site),$nick,32)

  tokenize 32 $remtok($hget(_i,$site),$nick,0,32)

  var %. = ( $+ $token($fulladdress,2,33) $+ ) $&

    $iif($0 >= 1,- Önceki nickler: $regsubex($1-,/(\s)/g,$+($chr(32),/,$chr(32)))) $&

    - Expire: $duration($hget(_i,$site).unset)

  echo -cti join # * $nick %.

  if ($0 = %_ilimit) {
     ;ban -k # $nick 2 nick değişimi fazla.( %_itime sürede $0 adet)

    hdel _i $site

  }

}

;on *:quit:if ($hget(_i,$site)) hdel _i $site

Kod içerisindeki:

%_itime değişkeni süre belirlemenize yarar.
%_ilimit değişkeni limit belirlemenize yarar.

;ban -k satırı belirlediğiniz limitde nick değişimi olursa kullanıcıyı kanaldan banlamak için kullanılır. Çalışması için başındaki comment prefix-ini(;) kaldırın.

;on quit kısmı kullanıcı sunucudan çıktığı zaman, tablodan tamamen silmek için aktif edilebilir. Başındaki ; comment prefix-ini karakterini kaldırın.

Ek olarak girişlerde expire kısmı tablodan silinme süresinin ne kadar kaldığını gösterir vs.

Not: Bu kodu kullanırken bazı hostlar için devre dışı bırakmanızı öneririm. Çünkü sunucularda genellikle, helper/admin hostları sabit oluyor. Dolayısıyla bu hostlar/özel hostlar gözardı edilmezse kod istenilen şekilde çalışmayacak ve host sahibi kişilerden limit dolduranı kanaldan atmaya çalışacaktır.

Bunun için koda şöyle bir satır ekleyebilirsiniz.

Kod:

if (!$istok(host1.net host2.net host3.net,$site,32)) {

Veya çok fazla özel host belirtmek istiyorsanız, bu hostları bir txt dosyasına alt alta ekleyin(/write dosya.txt host.adresi) ve yukarıdaki satır yerine,

Kod:

if (!$read(dosya.txt,w,$site)) {

Ekleyin.

Bu kodlardan kullanmak istediğinizi yukarıdaki ana kodda hadd -mu komutu ile başlayan satırın üstüne ekleyin ve kod sonunda bracket-ı(}) kapatın.