IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası

- mIRC Scripting Sorunları (https://www.ircforumlari.net/mirc-scripting-sorunlari/)

- - -v +v yapma bakabilir misiniz ? (https://www.ircforumlari.net/mirc-scripting-sorunlari/448199-v-v-yapma-bakabilir-misiniz.html)

-v +v yapma bakabilir misiniz ?

Selam hayirli forumlar Söyle birşey belirtmek istiyorum ihtiyacım vardı yardim edilebilir mi .

belirlediğim bir nick #a kanalina giriş yaptiği zaman benim tarafımdan +v verilmesini istiyorum aynı şekilde belirlediğim bir nicke #a kanalinda +v verilmesini engellemek istiyorum +v verildiği taktirde -v yapmak istiyorum oto olarak ve bu nickleri eklemek istiyorum ekleme işini #b kanalinda .otovoice ekle .otovoicesil gibi işlem olabilir yardımcı olabilir misiniz?

Cevap: -v +v yapma bakabilir misiniz ?

Alıntı:

ads01ads Nickli Üyeden Alıntı (Mesaj 1041016257)

Kod:

on *:text:*:#B:{

  if (.otovoice == $1) && $2 && $3 {

    if ($2 == ekle) { if $istok(%otovoice,$3,32) { msg $chan $3 Nick'i otovoice Listemde Zaten var.  | halt  } | else { msg $chan $3 Nick'i Otovoice Listesine Eklendi.. | set %otovoice $addtok(%otovoice,$3,32) } }  

    if ($2 == sil) { if !$istok(%otovoice,$3,32) { msg $chan $3  Nicki Listede Zaten yok. } | else {  msg $chan Otovoice Listesinin $findtok(%otovoice,$3,1,32) $+ . Sırasında Olan  $3  Listeden Silindi. | set %otovoice $deltok(%otovoice,$findtok(%otovoice,$3,1,32),32) } }  

  }

  if (.alvoice == $1) && $2 && $3 {

    if ($2 == ekle) { if $istok(%alvoice,$3,32) { msg $chan $3 Nick'i  Listemde Zaten var.  | halt  } | else { msg $chan $3 Nick'i  Listeye Eklendi.. | set %alvoice $addtok(%alvoice,$3,32) } }  

    if ($2 == sil) { if !$istok(%alvoice,$3,32) { msg $chan $3  Nicki Listede Zaten yok. } | else {  msg $chan  Listesinin $findtok(%alvoice,$3,1,32) $+ . Sırasında Olan  $3  Listeden Silindi. | set %alvoice $deltok(%alvoice,$findtok(%alvoice,$3,1,32),32) } }

  }

}

on *:Join:#a:{ if $istok(%otovoice,$nick,32) { mode # +v $nick } }

on *:voice:#a:{ if $istok(%alvoice,$vnick,32) { mode # -v $vnick } }

Kullanılacak Komutlar

.otovoice Ekle/sil Komutuyla Kanala Girdiğinde otovoice vereceğin Nickleri Ekleyip Silebilirsin.
.Alvoice Ekle/sil Komutuylada Voice Aldıgında VOicesini Geri Alacağın/engelleyeceğin Nickleri Ekleyip Silebilirsin.
Güle güle Kullan. Hayırlı Akşamlar.

Cevap: -v +v yapma bakabilir misiniz ?

Tşkler çok iyi olmuş sizede iyi akşamlar tekrardan tşk ederim

Kod:

on @*:join:#a:if $read(voice.txt,w,$nick) { mode # +v $v1 }

on *:voice:#a:if $read(devoice.txt,w,$vnick) { mode # -v $v1 }

on @*:text:*:#b: {

  if ($1 == .otovoiceekle) && $2 && ($3- == $null) && $read(voice.txt,w,$2) { msg #b $nick $qt($2) nicki otovoice listesinde mevcut }

  if ($1 == .otovoiceekle) && $2 && ($3- == $null) && !$read(voice.txt,w,$2) { write voice.txt $2 | msg #b $nick $qt($2) nicki otovoice listesine basari ile eklendi }

  if ($1 == .otovoicesil) && $2 && ($3- == $null) && $read(voice.txt,w,$2) { write -dw $2 voice.txt | msg #b $nick $qt($2) nicki otovoice listesinden basari ile silindi }

  if ($1 == .otodevoiceekle) && $2 && ($3- == $null) && $read(devoice.txt,w,$2) { msg #b $nick $qt($2) nicki otodevoice listesinde mevcut }

  if ($1 == .otodevoiceekle) && $2 && ($3- == $null) && !$read(devoice.txt,w,$2) { write devoice.txt $2 | msg #b $nick $qt($2) nicki otodevoice listesine basari ile eklendi }

  if ($1 == .otodevoicesil) && $2 && ($3- == $null) && $read(devoice.txt,w,$2) { write -dw $2 devoice.txt | msg #b $nick $qt($2) nicki otodevoice listesinden basari ile silindi }

  if ($1 == .otovoicelist) && ($2- == $null) { .play #b voice.txt }

  if ($1 == .otodevoicelist) && ($2- == $null) { .play #b devoice.txt }

}

komutlar;

#b kanalında

.otovoiceekle nick
.otovoicesil nick
.otovoicelist

.otodevoiceekle nick
.otodevoicesil nick
.otodevoicelist

ekletme silme olaylarının çalışması için botun #b kanalında op olması lazım.Eğer istemiyorsan op olmasını
on @*:text:*:#b: {

kısmını

on *:text:*:#b: {

olarak değiştirirsin.

Cevap: -v +v yapma bakabilir misiniz ?

cok makbuleye gecti :)