IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası

IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası (https://www.ircforumlari.net/)
-   mIRC Scripting Sorunları (https://www.ircforumlari.net/mirc-scripting-sorunlari/)
-   -   Özele gelen ''arkadaş/tanıdık'' kişilerin bilgilerini yansıtma. (https://www.ircforumlari.net/mirc-scripting-sorunlari/525858-ozele-gelen-arkadas-tanidik-kisilerin-bilgilerini-yansitma.html)

Prens 06 Mart 2013 13:22
Özele gelen ''arkadaş/tanıdık'' kişilerin bilgilerini yansıtma.
 
Merhaba,

Şöyle bir konuda yardımcı olabilir misiniz?

Örneğin, belirleyeceğim nickler özelime geldiğinde benim görebileceğim şekilde aşağıda belirtilen şekilde yansıta bilir mi?



<Arkadas> Merhaba,
*** Arkadas rumuzuna ait bilgiler ***
Adı : Ali
Nereli : Istanbul
Yaş : 20
Meslek : Öğretmen


Bu arada Arkadas rumuzunu örnek aldım, bunu bir kaç rumuz olarak düzenleyeceğim.

Coldman 06 Mart 2013 16:47
Cevap: Özele gelen ''arkadaş/tanıdık'' kişilerin bilgilerini yansıtma.
 
On *:open:?:*:{
msg $nick Merhaba; ~ $nick ~
msg $nick Ben Ali
msg $nick Mesleğim öğretmenlik
msg $nick yaş 20




}




bunu özeline gelen herkese gider, cok fazla kod bilgim olmadiği için. işini, görürse kullanabilirsin.

JohnGalt 06 Mart 2013 17:38
Cevap: Özele gelen ''arkadaş/tanıdık'' kişilerin bilgilerini yansıtma.
 
Bu aralar diyalog ile çok fazla haşır neşirim. Direk aklıma o şekilde bir panel yardımı ile istediğin nicklere ait bilgi ekleyip sonrasında özellerine geldiklerinde gösterime yönelik bir şey hazırladım. Paneli sağ klikten açabilirsin. Adı "Arkadaş Bilgileri Paneli".

Kodu remotelerden yeni bir sayfaya eklemeni öneririm.

Nick özeline gelince sadece şu şekilde görünecektir;

[BOX="örnek"]*** Arkadas Rumuzuna Ait Bilgiler ***
>> Ad: Ali
>> Memleket: İstanbul
>> Yaş: 20
>> Meslek: Öğretmen
*** Arkadas Rumuzuna Ait Bilgiler Sonu ***
06.03 [17:27:55] <Arkadas> Selam[/BOX]

Umarım istediğin bu tarz bir şeydir ve işine yarar.
Kolay gelsin.

Kod:
dialog ozel_bilgi {
  title "Arkadaş Bilgileri Paneli"
  size -1 -1 130 98
  option dbu
  text "Arkadaşlar:", 1, 5 8 30 8
  combo 2, 35 7 55 50, size drop
  button "Düzenle", 3, 95 6 30 12
  box "Arkadaş Bilgileri:", 4, 5 25 85 65
  text "Nick:", 5, 10 35 25 8
  text "Ad:", 6, 10 45 25 8
  text "Memleket:", 7, 10 55 25 8
  text "Yaş:", 8, 10 65 25 8
  text "Meslek:", 9, 10 75 25 8
  edit "", 10, 35 34 50 10, autohs
  edit "", 11, 35 44 50 10, autohs
  edit "", 12, 35 54 50 10, autohs
  edit "", 13, 35 64 50 10, autohs
  edit "", 14, 35 74 50 10, autohs
  button "Ekle", 15, 95 33 30 12
  button "Sil", 16, 95 46 30 12
  button "Kaydet", 17, 95 72 30 12
  button "Temizle", 18, 95 59 30 12
}
on *:dialog:ozel_bilgi:init:*:{
  did -f $dname 3
  did -b $dname 16,17
  if $isfile(ozel_bilgi.ini) { var %x = 1 | while $ini(ozel_bilgi.ini,%x) { did -az $dname 2 $ini(ozel_bilgi.ini,%x) | inc %x } }
}
on *:dialog:ozel_bilgi:sclick:15,17:{
  $iif($did(11),.writeini ozel_bilgi.ini $did(10) $did(6) $did(11),.remini ozel_bilgi.ini $did(10) $did(6))
  $iif($did(12),.writeini ozel_bilgi.ini $did(10) $did(7) $did(12),.remini ozel_bilgi.ini $did(10) $did(7))
  $iif($did(13),.writeini ozel_bilgi.ini $did(10) $did(8) $did(13),.remini ozel_bilgi.ini $did(10) $did(8))
  $iif($did(14),.writeini ozel_bilgi.ini $did(10) $did(9) $did(14),.remini ozel_bilgi.ini $did(10) $did(9))
  did -r $dname 2,10-14 | did -b $dname 16,17 | did -e $dname 15
  var %x = 1 | while $ini(ozel_bilgi.ini,%x) { did -az $dname 2 $ini(ozel_bilgi.ini,%x) | inc %x }
}
on *:dialog:ozel_bilgi:sclick:3:{
  did -n $dname 10-14 | did -b $dname 15 | did -e $dname 17
}
on *:dialog:ozel_bilgi:sclick:18:{
  did -r $dname 2,10-14 | did -b $dname 16,17 | did -e $dname 15 | did -n $dname 10-14
  var %x = 1 | while $ini(ozel_bilgi.ini,%x) { did -az $dname 2 $ini(ozel_bilgi.ini,%x) | inc %x }
}
on *:dialog:ozel_bilgi:sclick:16:{
  remini ozel_bilgi.ini $did(2,$did(2).sel)
  did -r $dname 2,10-14 | did -b $dname 16,17 | did -e $dname 15 | did -n $dname 10-14
  var %x = 1 | while $ini(ozel_bilgi.ini,%x) { did -az $dname 2 $ini(ozel_bilgi.ini,%x) | inc %x }
}
on *:dialog:ozel_bilgi:sclick:2:{
  did -r $dname 10-14 | did -b $dname 15 | did -e $dname 16 | did -m $dname 10-14
  did -az $dname 10 $did(2,$did(2).sel)
  var %x = 6 | while %x <= 9 {
  did -az $dname $calc(%x + 5) $readini(ozel_bilgi.ini,$did(2,$did(2).sel),$did(%x)) | inc %x }
}
menu status,query,channel {
  Arkadaş Bilgileri Paneli:ozel_bilgi
}
alias -l ozel_bilgi { dialog $iif($dialog(ozel_bilgi),-v,-m ozel_bilgi) ozel_bilgi }
on *:open:?:*:{
  if $ini(ozel_bilgi.ini,$nick) {
    echo $nick *** $nick Rumuzuna Ait Bilgiler ***
    var %x = 1 | while %x <= $ini(ozel_bilgi.ini,$nick,0) {
    echo $nick >> $+($chr(31),$ini(ozel_bilgi.ini,$nick,%x),$chr(31)) $readini(ozel_bilgi.ini,$nick,$ini(ozel_bilgi.ini,$nick,%x)) | inc %x }
    echo $nick *** $nick Rumuzuna Ait Bilgiler Sonu ***
  }
}

Krieq 07 Mart 2013 02:15
Cevap: Özele gelen ''arkadaş/tanıdık'' kişilerin bilgilerini yansıtma.
 
@[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...] kodlarını
on *:dialog:dialogadi:*: {
if ($devent == init) { komut }
if ($devent == sclik) {
if ($did == 1) { komut }
if ($did == 2) { komut }
} }
vs. gibi yazarsan daha sağlıklı olur.telefondan yazdığım için karışık gelmiş olabilir ama mantığını anladın sanırım.

JohnGalt 07 Mart 2013 03:51
Cevap: Özele gelen ''arkadaş/tanıdık'' kişilerin bilgilerini yansıtma.
 
@[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...] onu özellikle yapmıyorum aslında. Tam adını hatırlayamadığım bir dökümanda; diyalog eventinin içinde karşılaştırma yaptırıp komutu işletmektense, en başta o eventi başlattırmadan -yani koşullarını önceden belirtirip hiç o eventin içine girmeden- scripting yapılmasının daha sağlıklı olduğunu okumuştum o nedenle hep böyle yapıyordum. Ama yanlış öğrendiğim bir yöntem olabilir. Siz bu açıdan ne düşünüyorsunuz?

Prens 07 Mart 2013 14:44
Cevap: Özele gelen ''arkadaş/tanıdık'' kişilerin bilgilerini yansıtma.
 
Alıntı:
JohnGalt Nickli Üyeden Alıntı (Mesaj 1041287609)
Bu aralar diyalog ile çok fazla haşır neşirim. Direk aklıma o şekilde bir panel yardımı ile istediğin nicklere ait bilgi ekleyip sonrasında özellerine geldiklerinde gösterime yönelik bir şey hazırladım. Paneli sağ klikten açabilirsin. Adı "Arkadaş Bilgileri Paneli".

Kodu remotelerden yeni bir sayfaya eklemeni öneririm.

Nick özeline gelince sadece şu şekilde görünecektir;

[BOX="örnek"]*** Arkadas Rumuzuna Ait Bilgiler ***
>> Ad: Ali
>> Memleket: İstanbul
>> Yaş: 20
>> Meslek: Öğretmen
*** Arkadas Rumuzuna Ait Bilgiler Sonu ***
06.03 [17:27:55] <Arkadas> Selam[/BOX]

Umarım istediğin bu tarz bir şeydir ve işine yarar.
Kolay gelsin.

Kod:
dialog ozel_bilgi {
  title "Arkadaş Bilgileri Paneli"
  size -1 -1 130 98
  option dbu
  text "Arkadaşlar:", 1, 5 8 30 8
  combo 2, 35 7 55 50, size drop
  button "Düzenle", 3, 95 6 30 12
  box "Arkadaş Bilgileri:", 4, 5 25 85 65
  text "Nick:", 5, 10 35 25 8
  text "Ad:", 6, 10 45 25 8
  text "Memleket:", 7, 10 55 25 8
  text "Yaş:", 8, 10 65 25 8
  text "Meslek:", 9, 10 75 25 8
  edit "", 10, 35 34 50 10, autohs
  edit "", 11, 35 44 50 10, autohs
  edit "", 12, 35 54 50 10, autohs
  edit "", 13, 35 64 50 10, autohs
  edit "", 14, 35 74 50 10, autohs
  button "Ekle", 15, 95 33 30 12
  button "Sil", 16, 95 46 30 12
  button "Kaydet", 17, 95 72 30 12
  button "Temizle", 18, 95 59 30 12
}
on *:dialog:ozel_bilgi:init:*:{
  did -f $dname 3
  did -b $dname 16,17
  if $isfile(ozel_bilgi.ini) { var %x = 1 | while $ini(ozel_bilgi.ini,%x) { did -az $dname 2 $ini(ozel_bilgi.ini,%x) | inc %x } }
}
on *:dialog:ozel_bilgi:sclick:15,17:{
  $iif($did(11),.writeini ozel_bilgi.ini $did(10) $did(6) $did(11),.remini ozel_bilgi.ini $did(10) $did(6))
  $iif($did(12),.writeini ozel_bilgi.ini $did(10) $did(7) $did(12),.remini ozel_bilgi.ini $did(10) $did(7))
  $iif($did(13),.writeini ozel_bilgi.ini $did(10) $did(8) $did(13),.remini ozel_bilgi.ini $did(10) $did(8))
  $iif($did(14),.writeini ozel_bilgi.ini $did(10) $did(9) $did(14),.remini ozel_bilgi.ini $did(10) $did(9))
  did -r $dname 2,10-14 | did -b $dname 16,17 | did -e $dname 15
  var %x = 1 | while $ini(ozel_bilgi.ini,%x) { did -az $dname 2 $ini(ozel_bilgi.ini,%x) | inc %x }
}
on *:dialog:ozel_bilgi:sclick:3:{
  did -n $dname 10-14 | did -b $dname 15 | did -e $dname 17
}
on *:dialog:ozel_bilgi:sclick:18:{
  did -r $dname 2,10-14 | did -b $dname 16,17 | did -e $dname 15 | did -n $dname 10-14
  var %x = 1 | while $ini(ozel_bilgi.ini,%x) { did -az $dname 2 $ini(ozel_bilgi.ini,%x) | inc %x }
}
on *:dialog:ozel_bilgi:sclick:16:{
  remini ozel_bilgi.ini $did(2,$did(2).sel)
  did -r $dname 2,10-14 | did -b $dname 16,17 | did -e $dname 15 | did -n $dname 10-14
  var %x = 1 | while $ini(ozel_bilgi.ini,%x) { did -az $dname 2 $ini(ozel_bilgi.ini,%x) | inc %x }
}
on *:dialog:ozel_bilgi:sclick:2:{
  did -r $dname 10-14 | did -b $dname 15 | did -e $dname 16 | did -m $dname 10-14
  did -az $dname 10 $did(2,$did(2).sel)
  var %x = 6 | while %x <= 9 {
  did -az $dname $calc(%x + 5) $readini(ozel_bilgi.ini,$did(2,$did(2).sel),$did(%x)) | inc %x }
}
menu status,query,channel {
  Arkadaş Bilgileri Paneli:ozel_bilgi
}
alias -l ozel_bilgi { dialog $iif($dialog(ozel_bilgi),-v,-m ozel_bilgi) ozel_bilgi }
on *:open:?:*:{
  if $ini(ozel_bilgi.ini,$nick) {
    echo $nick *** $nick Rumuzuna Ait Bilgiler ***
    var %x = 1 | while %x <= $ini(ozel_bilgi.ini,$nick,0) {
    echo $nick >> $+($chr(31),$ini(ozel_bilgi.ini,$nick,%x),$chr(31)) $readini(ozel_bilgi.ini,$nick,$ini(ozel_bilgi.ini,$nick,%x)) | inc %x }
    echo $nick *** $nick Rumuzuna Ait Bilgiler Sonu ***
  }
}


Zahmetlerinizden dolayı teşekkür ediyorum çok güzel bir düşünce projesi, sorunsuz şekilde çalışmakta.


Tüm Zamanlar GMT +3 Olarak Ayarlanmış. Şuanki Zaman: 10:40.

Powered by vBulletin® Version 3.8.11
Copyright ©2000 - 2025, vBulletin Solutions, Inc.
Search Engine Friendly URLs by vBSEO
Copyright ©2004 - 2025 IRCForumlari.Net Sparhawk