IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası

IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası (https://www.ircforumlari.net/)
-   mIRC Scripting Sorunları (https://www.ircforumlari.net/mirc-scripting-sorunlari/)
-   -   istek addonu (https://www.ircforumlari.net/mirc-scripting-sorunlari/669774-istek-addonu.html)

Darnasus 13 Ocak 2015 12:18
istek addonu
 
Merhaba,

Radyo panelinde istek yapmak icin kullandigimiz bir remote var. istek alimi kapatildiginda istekte bulunan user'a istek aliminin kapali olduguna dair mesaj gondermek istiyorum. Bir kac deneme yaptim fakat istedigim neticeyi elde edemedim. Nasil bir degisiklik yapmam gerekiyor

Kod:
#istek on
on *:text:*:#radyo: {
  if !istek * iswm $1- {
    if $read(istekler.txt,w,$nick) { msg # 4 $nick Sizin baska bir "istek" de bulunabilmeniz icin beklemeniz gereken sure: $replace($duration($timer($+(istekler,$nick)).secs),hr, $chr(32) saat,mins, $chr(32) dakika,secs, $chr(32) saniye,min, $chr(32) dakika,sec, $chr(32) saniyedir.) | return }
    else {
      write istekler.txt $nick
      $+(timer,istekler,$nick) -o 1 300 /write -ds $+ $nick istekler.txt
      if !$readini(isteksayaci.ini,RAPOR,$nick) { msg # 0,14 $nick 0isteginiz alindi  | msg #istek 4 $nick 6( $+ $2- $+ ) 1sarki isteginde bulundu | writeini -n isteksayaci.ini RAPOR $nick 1 }
      else { msg # 0,14 $nick 0isteginiz alindi  | msg #istek  4 $nick 6( $+ $2- $+ ) 1sarki isteginde bulundu | writeini -n isteksayaci.ini RAPOR $nick $calc($readini(isteksayaci.ini,RAPOR,$nick) +1) }

    }
  }
}
#istek end


on $*:text:/^[.!]isteka[çÇc]$/Si:#radyohelp:{
  if $group(#istek).status = on { msg # istek alimi zaten acik }
  else { .enable #istek | msg # istek alimi acildi }

}
on $*:text:/^[.!]kapatistek$/Si:#radyohelp:{
  if $group(#istek).status = off { msg # istek alimi zaten kapali }
  else { .disable #istek | msg # istek alimi kapatildi }
}

KuL 13 Ocak 2015 12:45
Cevap: istek addonu
 
Alıntı:
Darnasus Nickli Üyeden Alıntı (Mesaj 1041589849)
Merhaba,

Radyo panelinde istek yapmak icin kullandigimiz bir remote var. istek alimi kapatildiginda istekte bulunan user'a istek aliminin kapali olduguna dair mesaj gondermek istiyorum. Bir kac deneme yaptim fakat istedigim neticeyi elde edemedim. Nasil bir degisiklik yapmam gerekiyor

Öncelikle böyle Kod eklerken lütfen Kod tagi kullanin, php kod tagini degil. yoksa ilk satirda genelde kayma oluyor :)

Aslinda en basiti su olur. Örnek #istek var birtane, Istek panelini acinca enable #istek yapiyorsun. Kapatincada disable #istek.

Ve bundan yola cikara, ikinci #istekkapali yaparsin. Istek Panelini acinca, enable #istek | disable #istekkapali yaparin. ve kapatincada tersini.

Yani söyle:

Kod:
#istek on
on *:text:*:#radyo: {
  if !istek * iswm $1- {
    if $read(istekler.txt,w,$nick) { msg # 4 $nick Sizin baska bir "istek" de bulunabilmeniz icin beklemeniz gereken sure: $replace($duration($timer($+(istekler,$nick)).secs),hr, $chr(32) saat,mins, $chr(32) dakika,secs, $chr(32) saniye,min, $chr(32) dakika,sec, $chr(32) saniyedir.) | return }
    else {
      write istekler.txt $nick
      $+(timer,istekler,$nick) -o 1 300 /write -ds $+ $nick istekler.txt
      if !$readini(isteksayaci.ini,RAPOR,$nick) { msg # 0,14 $nick 0isteginiz alindi  | msg #istek 4 $nick 6( $+ $2- $+ ) 1sarki isteginde bulundu | writeini -n isteksayaci.ini RAPOR $nick 1 }
      else { msg # 0,14 $nick 0isteginiz alindi  | msg #istek  4 $nick 6( $+ $2- $+ ) 1sarki isteginde bulundu | writeini -n isteksayaci.ini RAPOR $nick $calc($readini(isteksayaci.ini,RAPOR,$nick) +1) }

    }
  }
}
#istek end

#istekkapali off
on *:text:*:#radyo: {
  if !istek * iswm $1- {
    msg # Istek Paneli kapali oldugundan Dolayi, Isteginiz DJ imize iletilmemistir $nick
  }
}
#istekkapali end


on $*:text:/^[.!]isteka[çÇc]$/Si:#radyohelp:{ 
  if $group(#istek).status = on { msg # istek alimi zaten acik }
  else { .enable #istek | .disable #istekkapali | .msg # istek alimi acildi }

}
on $*:text:/^[.!]kapatistek$/Si:#radyohelp:{
  if $group(#istek).status = off { msg # istek alimi zaten kapali }
  else { .disable #istek | .enable #istekkapali | .msg # istek alimi kapatildi }
}

Darnasus 13 Ocak 2015 12:59
Cevap: istek addonu
 
Eyvallah kardesim, guzel mantik :)

Toprak 13 Ocak 2015 13:12
Cevap: istek addonu
 
Buda benden olsun :)


Kod:
on *:text:*:#Radyo: {
  if $regex($1,/^([!\.][ıiİ]stek)$/i) {
    if !$2 { msg # Lütfen !istek şarkı olarak belirtiniz.. | return }
    if %:istek != on { msg # Şuan'da istek alımı kapalı.. | return }
    if $hget(İstek,$nick) { msg # 4 $nick Sizin baska bir "istek" de bulunabilmeniz icin beklemeniz gereken sure: $replace($duration($hget(İstek,$nick).unset),hr, $chr(32) saat,mins, $chr(32) dakika,secs, $chr(32) saniye,min, $chr(32) dakika,sec, $chr(32) saniyedir.) | return }
    else {
      .hinc -msu300 İstek $nick
      if !$readini(isteksayaci.ini,RAPOR,$nick) { msg # 0,14 $nick 0isteginiz alindi  | msg #istek 4 $nick 6( $+ $2- $+ ) 1sarki isteginde bulundu | writeini -n isteksayaci.ini RAPOR $nick 1 }
      else { msg # 0,14 $nick 0isteginiz alindi  | msg #istek  4 $nick 6( $+ $2- $+ ) 1sarki isteginde bulundu | writeini -n isteksayaci.ini RAPOR $nick $calc($readini(isteksayaci.ini,RAPOR,$nick) +1) }
    }
  }
}
on *:text:*:#RadyoHelp:{ 
  if $regex($1,/^([!\.][ıiİ]steka[cçÇ])$/i) {
    if %:istek == on { msg # İstek alimi zaten açık durumda. }
    else { set %:istek on | msg # istek alimi acildi }
  }
  if $regex($1,/^([!\.]kapat[ıiİ]stek)$/i) {
    if %:istek == off { msg # İstek alimi zaten kapalı durumda. }
    else { set %:istek off | msg # istek alimi kapatildi. }
  }
}


Tüm Zamanlar GMT +3 Olarak Ayarlanmış. Şuanki Zaman: 03:16.

Powered by vBulletin® Version 3.8.8 Beta 3
Copyright ©2000 - 2024, vBulletin Solutions, Inc.
Search Engine Friendly URLs by vBSEO
Copyright ©2004 - 2024 IRCForumlari.Net