IRCForumlarý - IRC ve mIRC Kullanýcýlarýnýn Buluþma Noktasý

IRCForumlarý - IRC ve mIRC Kullanýcýlarýnýn Buluþma Noktasý (https://www.ircforumlari.net/)
-   Projeler (https://www.ircforumlari.net/projeler/)
-   -   Profil Sistem. (https://www.ircforumlari.net/projeler/1014172-profil-sistem.html)

Toprak 07 Temmuz 2023 20:06
Profil Sistem.
 
Merhaba, çok önceden yapmýþtým, iþine yarayan kullansýn.

[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]


[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]


Socket Bot;

Kod:
alias _prbot return PROFIL
alias _pass return 56tyhgfnd
alias _ident return Paradox
alias _username return Coder by Toprak
alias _oper return Koruma qwf8sc9c
alias _supass return 121212121212121
alias _sunucu return irc.Toprak.NET
alias _sunucuip return 185.241.121.51
alias _port return 6667
alias _profil return #Profil
alias _services return #Services

;- Profil sayfasý ayarlarý
alias _prolink return https://profil.toprak.net/
alias _botlink return bot.toprak.net
alias _prosifre return 2o22b45gb1lt0P
;----------------------------------------
;- Bot'un gireceði kanallar.
alias _pr-kanallar return $_profil $_services #Sohbet #Chat #Radyo
;----------------------------------------

alias _saatkontrol $iif(!$sock(prbot),sockopen prbot $_sunucuip $_port)
alias _nick return $remove($gettok($1,1,33),:)
alias swprbot $iif($sock(prbot).status == active,sockwrite -nt prbot $1-)
on *:sockclose:prbot:$+(.timer,_saatkontrol) 1 2 _saatkontrol
on *:sockopen:prbot:{
  if ($sockerr) { sockclose $sockname | $+(.timer,_saatkontrol) 1 2 _saatkontrol }
  else { swprbot NICK $+($_prbot,$left($calc($ticks * $r(10,99999)),$r(5,7))) | swprbot USER $_ident "" $+(",$ip) $+(:,$_username) | sockmark $sockname $_prbot }
}
on *:sockread:prbot:{
  var %;prbot | sockread -f %;prbot | tokenize 32 %;prbot
  if $regex($1,/^PING$/) { swprbot pong $remove($2,:) }
  elseif $regex($1,/^ERROR$/i) { sockclose $sockname | $+(.timer,_saatkontrol) 1 2 _saatkontrol }
  elseif $regex($2,/^(471|473|474|475)$/) { swprbot sajoin $_prbot $4 }
  elseif $regex($2,/^(411|481)$/) { swprbot oper $_oper | swprbot nick $_prbot | swprbot nickserv identify $_pass }
  elseif $regex($2,/^(001|433)$/) {
    swprbot oper $_oper
    swprbot ns ghost $_prbot $_pass
    swprbot ns release $_prbot $_pass
    swprbot join #0,0
    .timer 1 3 swprbot nick $_prbot
  }
  elseif $regex($2,/^NICK$/i) {
    if ($_nick($1) == $_prbot) { swprbot ns ghost $_prbot $_pass | swprbot ns release $_prbot $_pass | .timer 1 3 swprbot nick $_prbot }
    elseif ($right($3,-1) == $_prbot) {
      swprbot ns identify $_pass
      swprbot oper $_oper
      swprbot os su $_supass
      swprbot join #0,0
      swprbot mode $right($3,-1) +qHp-hY
      $+(.timer,_saatkontrol) 0 20 _saatkontrol
      $+(.timer,prbot-gir) 1 3 swprbot sajoin $right($3,-1) $replace($_pr-kanallar,$chr(32),$chr(44))
    }
  }
  elseif $regex($2,/^KICK$/i) && ($4 == $_prbot) && $istok($_pr-kanallar,$3,32) { swprbot sajoin $4 $3 }
  elseif $regex($2,/^JOIN$/i) {
    if ($_nick($1) == $_prbot) {
      if $istok($_pr-kanallar,$right($3,-1),32) { swprbot mode $right($3,-1) -qao+h $str($+($_nick($1),$chr(32)),5) }
      else { swprbot sapart $_nick($1) $right($3,-1) }
    }
  }
  elseif $regex($2,/^352$/i) && $hget(Pro-Mesajat,$8) {
    if !$regex($9,/r/) { swprbot privmsg $token($hget(Pro-Mesajat,$8),1,191) :Nickiniz kayýtlý olmadýðýndan bu komutu kullanamazsýnýz.! | .hdel -ms Pro-Mesajat $8 }
    else { _profil-mesaj $8 $token($hget(Pro-Mesajat,$8),1,191) $token($hget(Pro-Mesajat,$8),2-,191) | .hdel -ms Pro-Mesajat $8 }
  }
  elseif $regex($2,/^NOTICE$/i) && $regex($_nick($1),/^NickServ$/Si) {
    if $regex($token($token($1-,2-,58),-1,46),/(.+) nick'inin sifresi : (.+)/Si) {
      if $hget(Profil-Kayit,$regml(1)) { _profil-kayit $regml(1) $+($regml(1),@,$gettok($_sunucu,2-,46)) $iif($regml(2),$v1,sifreyoqs) $_profil-rank($regml(1)) | .hdel -ms Profil-Kayit $regml(1) }
      elseif $hget(Profil-Güncelle,$regml(1)) { _profil-guncel $regml(1) $iif($regml(2),$v1,sifreyoqs) | .hdel -ms Profil-Güncelle $regml(1) }
    }
  }
  elseif $regex($2,/^PRIVMSG$/i) {
    if ($3 == $_services) && $regex($_nick($1),/^NickServ$/Si) {
      if $regex($4-,/\] (.+)!.+@.+ Nick'i sunucuya login oldu/Si) {
        if ($_eggdrop-nickler($regml(1)) == 1) { return }
        .hadd -msu50 Profil-Kayit $regml(1) ok.
        swprbot ns getpass $regml(1)
      }
      elseif $regex($4-,/\] (.+) Nick'i.+email üzerine kayýt edilmiþdir/Si) {
        if ($_eggdrop-nickler($regml(1)) == 1) { return }
        .hadd -msu50 Profil-Kayit $regml(1) ok.
        swprbot ns getpass $regml(1)
      }
      elseif $regex($4-,/\] (.+) Nick'inin þifresi.+tarafýndan deðiþtirildi/Si) {
        if ($_eggdrop-nickler($regml(1)) == 1) { return }
        .hadd -msu50 Profil-Güncelle $regml(1) ok.
        swprbot ns getpass $regml(1)
      }
      elseif $regex($4-,/\] (.+) Nick'i.+tarafýndan drop'landi/Si) {
        if ($_eggdrop-nickler($regml(1)) == 1) { return }
        _profil-sil $regml(1)
      }
    }
    else {
      if $regex($remove($4,:),/^([!.&-]prof[ýiÝ]l)$/Si) {
        if $hget(Pro-Durum,$_nick($1)) { swprbot notice $_nick($1) :5 dakika da bir !profil komutunu kullanabilirsiniz. }
        elseif !$regex($5,/^([a-zA-ZÐðýÝöÖüÜþÞçÇ_^\133\135}{`][a-zA-ZÐðýÝöÖüÜþÞçÇ0-9_|^}\{\133\135`-]{0,30})$/Si) { swprbot privmsg $3 :Lütfen nick belirtiniz. 4ÖRN: !profil Toprak }
        else { _profil-bak $strip($5) $3 | .hinc -msu300 Pro-Durum $_nick($1) }
      }
      elseif $regex($remove($4,:),/^([!.&-]durum)$/Si) {
        if $hget(Pro-Mesaj,$_nick($1)) { swprbot notice $_nick($1) :5 dakika da bir !durum komutunu kullanabilirsiniz. }
        elseif !$5 { swprbot privmsg $3 :Lütfen 4!durum MESAJ olarak belirtiniz. MESAJ en fazla 140 karekter olmalý! }
        elseif ($len($strip($5-)) > 140) || ($len($strip($5-)) < 10) { swprbot notice $_nick($1) :Lütfen 4!durum MESAJ olarak belirtiniz. Durumunuz en az 10 en fazla 140 karekter olmalý! }     
        else { .hadd -ms Pro-Mesajat $_nick($1) $+($3,¿,$strip($5-)) | swprbot who $_nick($1) | .hinc -msu300 Pro-Mesaj $_nick($1) }
      }
      elseif $regex($remove($4,:),/^([!.&-]rank)$/Si) && ($3 == $_profil) {
        if !$regex($5,/^([a-zA-ZÐðýÝöÖüÜþÞçÇ_^\133\135}{`][a-zA-ZÐðýÝöÖüÜþÞçÇ0-9_|^}\{\133\135`-]{0,30})$/Si) { swprbot privmsg $3 :Lütfen nick belirtiniz. 4ÖRN: !rank Toprak }
        elseif !$istok(0 1 2 3 4 5 6,$strip($6),32) {
          swprbot privmsg $3 :Lütfen rank belirtiniz.
          swprbot privmsg $3 :
          swprbot privmsg $3 :0 : User
          swprbot privmsg $3 :1 : Özel Üye
          swprbot privmsg $3 :2 : Sunucu Yetkilisi (Oper/Admin)
          swprbot privmsg $3 :3 : Teknik Sorumlu
          swprbot privmsg $3 :4 : Genel Sorumlu
          swprbot privmsg $3 :5 : AR-GE Sorumlusu
          swprbot privmsg $3 :6 : Sunucu Sahibi
          swprbot privmsg $3 :
          swprbot privmsg $3 :4ÖRN: !rank Toprak 5
        }
        else { _profil-rankekle $strip($5-) $3 }
      }
    }
  }
}
alias _profil-rank {
  if ($1 == Toprak) { return 5 }
  elseif $istok($_masternick,$1,32) { return 6 }
  elseif ($rootbul($1) == 1) { return 4 }
  elseif ($operbul($1) == 1) { return 2 }
  elseif $hget(VIP,$1) { return 1 }
  else { return 0 }
}
alias _profil-tr {
  if !$regex($1-,/^([a-zA-Z-_][a-zA-Z0-9_-]{0,30})$/Si) { return 1 }
  else { return 0 }
}
alias _profil-kayit {
  if ($_profil-tr($1) == 1) { swprbot privmsg $1 $+(:,$1) nickinizde Türkçe ya/yada Özel Karekterler olduðundan dolayý Profil Sayfasý oluþturulamýyor. }
  else {
    sockopen $+(_profil-socks¬,$1) $_prbotlink 80
    sockmark $+(_profil-socks¬,$1) $+(durum=ekle&kod=,$_prosifre,&username=,$1,&sifre=,$3,&mail=,$2,&flag=,$4)
  }
}
alias _profil-bak {
  sockopen $+(_profil-socks¬,$1,¬,$2) $_prbotlink 80
  sockmark $+(_profil-socks¬,$1,¬,$2) $+(durum=profil&kod=,$_prosifre,&username=,$1)
}
alias _profil-sil {
  if ($_profil-tr($1) == 1) { return }
  else {
    sockopen $+(_profil-socks¬,$1) $_prbotlink 80
    sockmark $+(_profil-socks¬,$1) $+(durum=sil&kod=,$_prosifre,&username=,$1)
  }
}
alias _profil-guncel {
  if ($_profil-tr($1) == 1) { return }
  else {
    sockopen $+(_profil-socks¬,$1) $_prbotlink 80
    sockmark $+(_profil-socks¬,$1) $+(durum=guncel&kod=,$_prosifre,&username=,$1,&sifre=,$2)
  }
}
alias _profil-mesaj {
  if ($_profil-tr($1) == 1) { return }
  else {
    sockopen $+(_profil-socks¬,$1,¬,$2) $_prbotlink 80
    sockmark $+(_profil-socks¬,$1,¬,$2) $+(durum=mesaj&kod=,$_prosifre,&username=,$1,&mesaj=,$replace($3-,$chr(32),$+($chr(37),20)))
  }
}
alias _profil-rankekle {
  if ($_profil-tr($1) == 1) { return }
  else {
    sockopen $+(_profil-socks¬,$1,¬,$3) $_prbotlink 80
    sockmark $+(_profil-socks¬,$1,¬,$3) $+(durum=rank&kod=,$_prosifre,&username=,$1,&rank=,$2)
  }
}
on *:sockopen:_profil-socks¬*:{
  if ($sockerr) { swprbot privmsg $_prbots :Profil sayfasýna baðlanýlamýyor, lütfen kontrol ediniz. | .sockclose $sockname }
  else {
    sockwrite -nt $sockname GET $+(/index.php?,$sock($sockname).mark) HTTP/1.1
    sockwrite -nt $sockname Host: $sock($sockname).addr
    sockwrite -nt $sockname Accept: image/jpeg, application/x-ms-application, image/gif, application/xaml+xml, image/pjpeg, application/x-ms-xbap, */*
    sockwrite -nt $sockname Accept-Language: tr-TR
    sockwrite -nt $sockname User-Agent: Mozilla/4.0 (compatible; MSIE 8.0; Windows NT 6.1; Trident/4.0; SLCC2; .NET CLR 2.0.50727; .NET CLR 3.5.30729; .NET CLR 3.0.30729)
    sockwrite -nt $sockname Connection: Keep-Alive
    sockwrite -nt $sockname $crlf
  }
}
on *:sockread:_profil-socks¬*:{
  var %:_pro-socks | sockread %:_pro-socks | tokenize 32 %:_pro-socks
  if $regex($1-,/Kayıt tamam! profil yapılandırılıyor bekleyiniz../Si) {
    swprbot privmsg $_profil $+(:,$token($sockname,2,172)) nickine profil sayfasý oluþturuldu!
    swprbot privmsg $token($sockname,2,172) :Merhaba $token($sockname,2,172)
    swprbot privmsg $token($sockname,2,172) :Profil sayfanýz oluþturuldu, paylaþým yapmanýz için sizi bekliyor :)
    swprbot privmsg $token($sockname,2,172) :
    swprbot privmsg $token($sockname,2,172) :Profil sayfamýz: $_prolink
    swprbot privmsg $token($sockname,2,172) :Kullanýcý adýnýz: $token($sockname,2,172) - Þifreniz sunucu þifreniz ile aynýdýr.
    sockclose $sockname
  }
  elseif $regex($1-,/Bu nick kayıtlı./Si) && $regex($sock($sockname).mark,/^durum=ekle/Si) {
    swprbot privmsg $token($sockname,2,172) :Merhaba $token($sockname,2,172)
    swprbot privmsg $token($sockname,2,172) :
    swprbot privmsg $token($sockname,2,172) :Profil sayfamýz: $_prolink
    swprbot privmsg $token($sockname,2,172) :Kullanýcý adýnýz: $token($sockname,2,172) - Þifreniz sunucu þifreniz ile aynýdýr.
    sockclose $sockname
  }
  elseif $regex($1-,/"totalFollowers":"(.+)"."totalFollowing":"(.+)"."totalFavs":"(.+)"."totalPost":"(.+)"/Si) {
    swprbot privmsg $token($sockname,3,172) $+(:,$token($sockname,2,172)) nickinin profil sayfasý: $+($_prolink,$token($sockname,2,172))
    sockclose $sockname
  }
  elseif $regex($1-,/Böyle bir profil bulunamadı!/Si) && $regex($sock($sockname).mark,/^durum=profil/Si) {
    swprbot privmsg $token($sockname,3,172) $+(:,$token($sockname,2,172)) nickine ait profil sayfasý bulunmamaktadýr!
    sockclose $sockname
  }
  elseif $regex($1-,/Profil kaydı silindi./Si) { swprbot privmsg $_profil $+(:,$token($sockname,2,172)) nicki silindiði(/ns drop NICK) için profil sayfasý silindi. | sockclose $sockname }
  elseif $regex($1-,/Åžifreniz güncellendi/Si) {
    swprbot privmsg $_profil $+(:,$token($sockname,2,172)) nickinin profil þifresi güncellendi.
    swprbot privmsg $token($sockname,2,172) :Merhaba $token($sockname,2,172)
    swprbot privmsg $token($sockname,2,172) :Profil sayfanýzýn þifreside güncellendi.
    swprbot privmsg $token($sockname,2,172) :
    swprbot privmsg $token($sockname,2,172) :Profil sayfamýz: $_prolink
    swprbot privmsg $token($sockname,2,172) :Kullanýcý adýnýz: $token($sockname,2,172) - Þifreniz sunucu þifreniz ile aynýdýr.
    sockclose $sockname
  }
  elseif $regex($1-,/Böyle bir nick kayıtlı deÄŸil./Si) {
    if $regex($sock($sockname).mark,/^durum=sil/Si) { sockclose $sockname }
    elseif $regex($sock($sockname).mark,/^durum=guncel/Si) {
      swprbot privmsg $_profil $+(:,$token($sockname,2,172)) nicki þifresini güncelledi, profil sayfasý olmadýðýndan dolayý iþlem yapýlamadý. Profil sayfasýnýn olmadýðý bildirildi.
      swprbot privmsg $token($sockname,2,172) :Merhaba $token($sockname,2,172)
      swprbot privmsg $token($sockname,2,172) :
      swprbot privmsg $token($sockname,2,172) :Profil sayfanýz bulunmamaktadýr!: $_prolink
      swprbot privmsg $token($sockname,2,172) :Nickinizi identify(/ns identify SIFRE) ederek profil sayfanýzý oluþturabilirsiniz.
      sockclose $sockname
    }
    elseif $regex($sock($sockname).mark,/^durum=mesaj/Si) {
      swprbot privmsg $token($sockname,3,172) $+(:,$token($sockname,2,172)) profil sayfanýz bulunmadýðýndan !durum mesajý atamazsýnýz!
      swprbot privmsg $token($sockname,3,172) :Nickinizi identify(/ns identify SIFRE) ederek profil sayfanýzý oluþturabilirsiniz.
      sockclose $sockname
    }
    elseif $regex($sock($sockname).mark,/^durum=rank/Si) { swprbot privmsg $token($sockname,3,172) $+(:,$token($sockname,2,172)) nickinin profil sayfasý olmadýðýndan ranký güncellenemedi. | sockclose $sockname }
  }
  elseif $regex($1-,/Durumunuz paylaşıldı.!!/Si) { swprbot privmsg $token($sockname,3,172) $+(:,$token($sockname,2,172)) durumunuz profil sayfanýzda paylaþýldý! | sockclose $sockname }
  elseif $regex($1-,/HATA!! Ä°ÅŸlem yapılamadı../Si) { swprbot privmsg $token($sockname,2,172) :4HATA iþlem yapýlamadý, lütfen daha sonra tekrar deneyiniz! | sockclose $sockname }
  elseif $regex($1-,/Rank güncellendi.!!/Si) { swprbot privmsg $token($sockname,3,172) $+(:,$token($sockname,2,172)) nickinin ranký güncellenmiþtir. | sockclose $sockname }
}
Bottan ayýrdým belki hata olmuþ olur, kontrol edin yapamazsanýz yardýmcý olurum.

xlxlxl 07 Temmuz 2023 20:07
Cevap: Profil Sistem.
 
yapýyorsun bu sporu :) eline saðlýk

Seyra 07 Temmuz 2023 22:51
Cevap: Profil Sistem.
 
Soyle sitesinde bi ara çok popülerdi bu profil uygulamasý.

xwerswoodx 08 Temmuz 2023 18:45
Cevap: Profil Sistem.
 
O zaman da boþ bir sistemdi, hala da boþ bir sistem bence. Eðer insanlar profil oluþturmak istese IRCe mi girer, IRC'i insanlarýn sevme nedeni burada istedikleri insan olabilmeleri zaten. Soylede de sadece sahte fotoðraflar koyup ben buyum diyenlerden baþka kimsenin kullanmadýðý bir sistemdi. Yine de eline saðlýk emek verilmiþ ancak, IRC'yi olmadýðý bir þeye çevirmekle uðraþmak gerçekten anlamsýz. Ýlle resim falan atacaðým diyorsanýz bir sürü güzel resimli, sesli, applet yapanlar var, gidin appleti satýn alýn kullanýn botla motla uðraþmaya ne gerek var.

Vision 09 Temmuz 2023 13:51
Cevap: Profil Sistem.
 
Ýsteyen kullanýr, istemeyen kullanmaz.

Güzel paylaþým @[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...], eline saðlýk.

Xander 09 Temmuz 2023 14:03
Cevap: Profil Sistem.
 
Çok eski bir sistemdi, bir kaç sunucuda görmüþtüm ellerine saðlýk ibram. Emek vermiþsin birþeyler yapmissin, ÝRC için yapýlan herþey iyidir taktir edilmelidir.


Tüm Zamanlar GMT +3 Olarak Ayarlanmýþ. Þuanki Zaman: 22:39.

Powered by vBulletin® Version 3.8.11
Copyright ©2000 - 2025, vBulletin Solutions, Inc.
Search Engine Friendly URLs by vBSEO
Copyright ©2004 - 2025 IRCForumlari.Net Sparhawk