menu * {
  Otomatik Kelime Tamamlayici $iif($timer(editbox),KAPAT,AÇ):$iif(!$timer(editbox),_editboxkontrol,.timereditbox off ) | echo $color(info) -a * Otomatik kelime tamamlama $iif($v1,acildi.,kapandi.)
}

alias -l my_vocabulary return kelimedagarcigim.txt
alias -l _editboxkontrol { .timereditbox -m 0 100 mwfill }
alias -l mwfill {
  if ($len($editbox($active)) != %_editbox_chr_len) {
    if ($len($editbox($active)) > %_editbox_chr_len) {
      if $+(*,$chr(32)) iswm $editbox($active) { return }
      var %last_txt = $$gettok($editbox($active),-1,32)
      if ($len(%last_txt) >= 3) {
        if $read($my_vocabulary,nw,$+(%last_txt,*)) {
          var %read = $v1
          var %parames = -b $+ $calc($len($editbox($active)) +1) $+ e $+ $calc($len($editbox($active)) + $len(%read)) 
          editbox %parames $iif($active != Status Window,$active) $iif($gettok($editbox($active),0,32) > 1,$gettok($editbox($active),-2-0,32)) $+(%last_txt,$mid(%read,$calc($len(%last_txt) +1),12345))

        }
      }
    }
  }
  set %_editbox_chr_len $len($editbox($active))
}

on *:input:*:var %c = $strip($1-) | tokenize 32 %c | _kelimeayir $* | filter -ctff 1 1 $my_vocabulary $my_vocabulary
alias -l _kelimeayir {
  if ($1 !isnum && $len($1) >= 3) {
    if ($read($my_vocabulary,nw,$1) == $null) { write $my_vocabulary $1 }
  }
}
;Koder notlari.
;not1: idle suresi belirli bir sureyi gecince otomatik editbox kontrolu kapanacak timereditbox kapanacak on inputtan yapilabilir
;not2: kelimelerin kullanim sayisina gore duzenlenebilir ve eslesmeyi kullanim sikligina gore editboxda gosterilebilir.
;not3: kullanim sadece kendi kullandigim kelimelere gore degil ayni zamanda tum her yerde kullanilan kelimelere gore baz alinabilir ve bir secenek olusturulabilir.