Bende kullanıyorum öyle bir hatayla karşılaşmadım.
/sunucuban şekline açabilirsin.
Kod: Kodu kopyalamak için üzerine çift tıklayın!
alias sunucuban { dialog -m glist glist }
dialog glist {
title "Sunucu Genel Ban Listesi"
size -1 -1 423 149
option dbu
list 1, 2 10 82 126, size
text "Gline Listesi", 4, 4 2 45 8
button "KAPAT", 5, 170 116 82 20, flat ok
list 2, 86 10 82 126, size
list 3, 254 10 82 126, size
text "Shun Listesi", 6, 86 2 71 8
text "Zline Listesi", 7, 254 2 54 8
text "Kaldırmak istediğiniz banın ip numarasının üzerine çift tıklayınca ban kalkacaktır.", 8, 118 140 189 8
list 9, 170 10 82 103, size
text "G-Zline Listesi", 10, 170 2 65 8
list 11, 338 10 82 126, size
text "Kline Listesi", 12, 338 2 60 8
}
on *:dialog:glist:*:*:{
if $devent == init {
set %gkontrol on | .enable #bangizle | .stats g | .stats s | .stats k | .stats Z
.timer 1 1 .disable #bangizle
}
if $devent == dclick {
if $did == 1 {
gline $+(-*@, $did(1).seltext)
did -d $dname 1 $did(1).sel
}
if $did == 2 {
shun $+(-*@, $did(2).seltext)
did -d $dname 2 $did(2).sel
}
if $did == 3 {
zline $+(-*@, $did(3).seltext)
did -d $dname 3 $did(3).sel
}
if $did == 9 {
gzline $+(-*@, $did(9).seltext)
did -d $dname 9 $did(9).sel
}
if $did == 11 {
kline $+(-*@, $did(11).seltext)
did -d $dname 11 $did(11).sel
}
}
if $devent == close {
write -c gline.txt
write -c zline.txt
write -c shun.txt
write -c gzline.txt
write -c kline.txt
}
}
raw 223:*: {
if ($2 isincs G) && (%gkontrol == on) && ($dialog(glist)) {
did -a glist 1 $gettok($3,2,64) | write gline.txt $gettok($3,2,64)
.timer 1 3 unset %gkontrol
}
if ($2 isincs z) && (%gkontrol == on) && ($dialog(glist)) {
did -a glist 3 $gettok($3,2,64) | write zline.txt $gettok($3,2,64)
}
if ($2 isincs s) && (%gkontrol == on) && ($dialog(glist)) {
did -a glist 2 $gettok($3,2,64) | write shun.txt $gettok($3,2,64)
}
if ($2 isincs Z) && (%gkontrol == on) && ($dialog(glist)) {
did -a glist 9 $gettok($3,2,64) | write gzline.txt $gettok($3,2,64)
}
if ($2 isincs K) && (%gkontrol == on) && ($dialog(glist)) {
did -a glist 11 $gettok($3,2,64) | write kline.txt $gettok($3,2,64)
}
/halt
}
#bangizle off
raw 223:*: { /halt }
raw 249:*: { /halt }
raw 219:*: { /halt }
raw 216:*: { /halt }
#bangizle end