on *:text:*:#Opers: {
  var %coderlab = $remove($1,.,!)
  var %nick  = $2
  if (%coderlab == cezalist) {
    if ($lines(cezalist.txt) == 0) {
      msg #Opers Herhangi bir Oper/Admin ceza almamış.
    }
    else {
      msg #Opers Oper/Admin ceza listesi sıralanıyor.
      .play #Opers cezalist.txt 2000
    }
  }

  elseif (%coderlab == cezasil) {
    if (!%nick) {
      msg #Opers Hatalı kullanım: .cezasil nick
    }
    elseif (!$read(cban.txt, ntw, %nick)) {
      msg #Opers %nick nickine ait herhangi bir ceza bulunamadı.
    }
    else {
      write -dl $+ $readn cban.txt
      write -dl $+ $readn cezalist.txt
      msg #Opers %nick nickine verilen ceza başarıyla kaldırıldı.
    }
  }
  elseif (%coderlab == cezabul) {
    if (!%nick) {
      msg #Opers Hatalı kullanım: .cezabul <nick>
    }
    elseif (!$read(cban.txt, ntw, %nick)) {
      msg #Opers %nick nickine ait herhangi bir ceza bulunmamaktadır. Büyük/Küçük Harfe Dikkat!!
    }
    else {
      var %satir = "", %i = 1
      while (%i <= $lines(cezalist.txt)) {
        var %line = $read(cezalist.txt, %i)
        if ($istokcs(%line, %nick, 32)) {
          var %satir = %line
          break
        }
        inc %i
      }

      if (%satir != $null) {
        msg #Opers %nick kullanıcısının ceza bilgisi: %satir
      }
      else {
        msg #Opers %nick nickine ait ceza bilgisi bulunamadı.
      }
    }
  }
  elseif (%coderlab == cezaekle) {
    if (!%nick || !$3 || !$4-) {
      msg #Opers Hatalı kullanım. .cezaekle nick gün sebep olarak deneyin.
    }
    elseif (!$istok(Mylife testt nick3 nick4 nick5, $nick, 32)) {
      msg #Opers Ceza eklemek için yetkili değilsiniz.
    }
    elseif ($read(cban.txt, ntw, %nick)) {
      msg #Opers %nick zaten cezalı. İkinci kez ceza eklenemez.
    }
    elseif (!$regex($3,/^\d+$/)) {
      msg #Opers Hatalı gün sayısı. Lütfen sayı girin.
    }
    else {
      var %bitis = $asctime($calc($ctime + ($3 * 86400)),dd.mm.yyyy)
      msg #Opers %nick nickine $3 gün $4- sebebi ile ceza eklendi. Ceza bitiş: %bitis
      .kill %nick reconnect
      write cban.txt %nick
      write cezalist.txt %nick - $4- sebebiyle $3 gün ceza verildi. Ekleyen: $nick - Bitiş: %bitis
    }
  }

}


on ^*:SNOTICE:*is now a*:{
  if ($regex($1-,/^(.*?) \((.*?)\) \[(.*?)\] is now a /i)) {
    var %grsnick = $regml(1)
    var %grsip   = $regml(2)
    var %oprnick = $regml(3)
    var %ipgrs = $gettok(%grsip,2,64)

    if ($read(cban.txt, ntw, %oprnick)) {
      kill %grsnick : Cezalısınız! 4 [ %oprnick ]
      os raw svskill %grsnick : Cezalısınız! - SVS-KILL 4 [ %oprnick ]
      msg #Opers 3 %grsnick 1 Nicki Cezalı Olan 4 %oprnick 1 ile giriş yapmaya çalıştı, Killendi. IP: %ipgrs
    }
  }
}

!cezaekle nick süre sebep
!cezasil nick
!cezalist
!cezabul nick

[01:22] -irc.test.net- testnick (test@182.244.145.***) [Testoper] is now a root administrator (X)