Kod: Kodu kopyalamak için üzerine çift tıklayın!
alias ppop {
if ($1 == -q) {
tokenize 32 [ [ $var(%ppop.queue.*.*:*,1) ] ]
var %ct = $gettok($var(%ppop.queue.*.*:*,1),4,46)
unset $var(%ppop.queue.*.*:*,1)
}
else { var %ct = $asctime(H:nn:ss) }
tokenize 1 $strip($1-)
var %h = $wrap($2,Tahoma,11,$calc(%ppop.width -14),0),%w = $calc(%h *14+55),%t = $width($1,Tahoma,11,1),%s = $1,%u = $2,%x,%y,%gh
if ($1 != -q) && ($window(@ppop)) {
set $+(%,ppop.queue.,$ticks,$rand(10000,99999),.,$asctime(H:nn:ss)) $+(%s,,%u)
drawtext -rbp @ppop %ppop.color.bg %ppop.color.border "Small Fonts" 8 1 0 SiLvEr v3 - Event Notify $iif($var(%ppop.queue.*.*,0),$nbr($v1 in queue))
}
else {
if (t? iswm %ppop.pos) { %y = 0 }
else { %y = $calc($window(-1).h - %w) }
if (?l iswm %ppop.pos) { %x = 0 }
else { %x = $calc($window(-1).w - %ppop.width) }
if (%ppop.offset) {
%x = $calc(%x + %ppop.xoffset)
%y = $calc(%y + %ppop.yoffset)
}
if (!$window(@ppop)) { %gh = 1 }
window -hnBdfiopk0 +dL @ppop %x %y %ppop.width %w
if (%ppop.fade) { if (%gh) || ($timer(ppop.fade)) { ppop.fade in } }
if (%ppop.transp.en) { if (!%ppop.fadecur.in) && (!%ppop.fadecur.out) { setlayer %ppop.transp @ppop } }
elseif (!%ppop.fade) || ((!%ppop.fadecur.in) && (!%ppop.fadecur.out)) { setlayer 255 @ppop }
drawrect -nrf @ppop %ppop.color.bg 1 0 0 %ppop.width %w
drawrect -nrf @ppop %ppop.color.border 1 0 0 %ppop.width 10
drawtext -nr @ppop %ppop.color.bg "Small Fonts" 8 $calc(%ppop.width - $width(%ct,Small Fonts,8) -2) 0 %ct
drawtext -nrbp @ppop %ppop.color.bg %ppop.color.border "Small Fonts" 8 1 0 SiLvEr v3 - Event Notify $iif($var(%ppop.queue.*.*,0),$nbr($v1 in queue))
drawrect -nr @ppop %ppop.color.border 1 0 0 %ppop.width %w
drawpic -cntros @ppop 16711935 6 16 18 18 4 $+(",$mircexe,")
drawtext -nro @ppop %ppop.color.text Tahoma 11 29 18 $iif(%t > $calc(%ppop.width -40),$mid($wrap( $+ %s,Tahoma,11,$calc(%ppop.width -40),0,1),2) $+ ...,%s)
drawline -nr @ppop %ppop.color.border 1 0 40 30 40
drawrect -nrf @ppop %ppop.color.border 1 30 38 5 5
while (%h) {
drawtext -nr @ppop %ppop.color.text Tahoma 11 9 $calc(%h *14+33) $wrap(%u,Tahoma,11,$calc(%ppop.width -14),%h)
dec %h
}
drawdot @ppop
window -o @ppop
if (%ppop.delay) {
if (%ppop.fade) { .timerppop.close -io 1 %ppop.delay ppop.fade out }
else { .timerppop.close -io 1 %ppop.delay ppop.doclose }
}
if (%ppop.beep) { beep }
}
}
alias -l ppop.chkhl { if ($highlight) && ($highlight($1-)) && ($1- !isnum) { return $true } }
alias -l ppop.trig { if (%ppop.enabled) && ((!%ppop.nactive) || (!$appactive)) && ((!%ppop.naw) || (!$away)) && ($1 isin %ppop.events) { return $true } }
alias ppop.fade {
var %b = $iif(%ppop.transp.en,%ppop.transp,255)
if ($1 == in) {
if (!%ppop.fadecur.in) && (!%ppop.fadecur.out) { setlayer 0 @ppop }
if (!%ppop.fadecur.in) {
set %ppop.fadecur.in $iif(%ppop.fadecur.out,$calc(%ppop.fadecur.out +((%b - %ppop.fadecur.out) % 20)),$iif(%ppop.transp.en,$calc(%ppop.transp % 20),15))
.timerppop.fade -imo 0 15 setlayer % $+ ppop.fadecur.in @ppop $chr(124) inc % $+ ppop.fadecur.in 20 $chr(124) if (%ppop.fadecur.in > %b $+ ) $chr(123) .timerppop.fade off $chr(124) unset % $+ ppop.fadecur.in $chr(125)
unset %ppop.fadecur.out
}
}
else {
set %ppop.fadecur.out $iif(%ppop.transp.en && $calc(%ppop.transp -(%ppop.transp % 20)) > 0,$v1,240)
.timerppop.fade -imo 0 15 setlayer % $+ ppop.fadecur.out @ppop $chr(124) dec % $+ ppop.fadecur.out 20 $chr(124) if (%ppop.fadecur.out < 0) $chr(123) ppop.doclose $chr(125)
}
}
alias ppop.doclose {
.timerppop.close off
.timerppop.fade off
unset %ppop.fadecur.*
close -@ @ppop
if ($var(%ppop.queue.*.*:*,0)) {
if ($1 != -s) { ppop -q }
else { unset %ppop.queue.* }
}
}
; events
on *:connect:{ if ($ppop.trig(n)) { ppop Bağlantı Kuruldu!Şu an $server sunucusu ile bağlantınız kuruldu. $iif($network,$nbr($v1)) $+ ! } }
on *:disconnect:{ if ($ppop.trig(i)) { ppop Bağlantı Kesildi!Şu an $server sunucusu ile bağlantınız kesildi. $iif($network,$nbr($v1)) $+ ! } }
on *:kill:{ if ($ppop.trig(i)) { ppop Bağlantı Kesildi!Şu an $2 TarafIndan sunucu ile bağlantınız kesildi. $iif($network,$nbr($v1)) $+ ! } }
on *:filercvd:*:{ if ($ppop.trig(d)) { ppop DCC Dosya Alımı Tamamlandı!Dosya: $+(",$get(-1).file,") Gönderen: $get(-1) Tamamlandı. Alınan: $bytes($get(-1).size,3).suf $iif($get(-1).resumed,after Devam edilen: $bytes($v1,3).suf) Süre: $duration($get(-1).secs) Ortalama Byte: $bytes($get(-1).cps,3).suf $+ /s. } }
on *:filesent:*:{ if ($ppop.trig(d)) { ppop DCC Dosya Gönderimi Tamamlandı!Dosya: $+(",$send(-1).file,") Alıcı: $send(-1) Tamamlandı. Gönderilen: $bytes($send(-1).size,3).suf $iif($send(-1).resumed,after Devam edilen: $bytes($v1,3).suf) Süre: $duration($send(-1).secs) Ortalama Byte: $bytes($send(-1).cps,3).suf $+ /s. } }
on *:getfail:*:{ if ($ppop.trig(d)) { ppop DCC Dosya Alımı Başarısız!Dosya: $+(",$get(-1).file,") Gönderen: $get(-1) başarısız! Alınan: $+($bytes($get(-1).rcvd,3),/,$bytes($get(-1).size,3).suf) ( $+ $get(-1).pc $+ %) $iif($get(-1).resumed,Devam edilen: $bytes($v1,3).suf) Süre: $duration($get(-1).secs) Ortalama byte: $bytes($get(-1).cps,3).suf $+ /s. } }
on *:sendfail:*:{ if ($ppop.trig(d)) { ppop DCC Dosya Gönderimi Başarısız!Dosya: $+(",$send(-1).file,") Alıcı: $send(-1) başarısız! Gönderilen: $+($bytes($send(-1).sent,3),/,$bytes($send(-1).size,3).suf) ( $+ $send(-1).pc $+ %) $iif($send(-1).resumed,Devam edilen: $bytes($v1,3).suf) Süre: $duration($send(-1).secs) Ortalama byte: $bytes($send(-1).cps,3).suf $+ /s. } }
ctcp !*:*:*:{
if ($1 == dcc) {
if ($ppop.trig(d)) {
if ($2 == send) { ppop Dosya Gönderme İsteği! $+ $nick size şu dosyayı göndermek istiyor: $+(",$3,") ( $+ $bytes($6,3).suf $+ )! }
elseif ($2 == chat) { ppop DCC Chat İsteği! $+ $nick sizinle DCC üzerinden chat yapmak istiyor! }
}
}
elseif ($ppop.trig(t)) { ppop Gelen İstek: $+(CTCP!?,$nick,$iif($chan,: $+ $v1),?) $1- }
}
on !*:ctcpreply:*:{ if ($balloon.trig(t)) { ppop Gelen CTCP İsteği: $+(reply!!,$nick,$iif($chan,: $+ $chan),!) $1- } }
on *:text:*:*:{
var %o = $strip($1-)
if ($ppop.trig(a)) && (((u isin %ppop.events) && (%ppop.ctrig) && ($regex(%o,%ppop.ctrig))) || (($ppop.chkhl(%o)) && (h isin %ppop.events))) {
if ($chan) { ppop $chan $+(message!<,$iif($nick !isreg $chan,$left($nick($chan,$nick).pnick,1)),$nick,>) $1- }
else { ppop Özel $+(mesaj!<,$nick,>) $1- }
}
}
on *:action:*:*:{
var %o = $strip($1-)
if ($ppop.trig(a)) && (((u isin %ppop.events) && (%ppop.ctrig) && ($regex(%o,%ppop.ctrig))) || (($ppop.chkhl(%o)) && (h isin %ppop.events))) {
if ($chan) { ppop $chan $+(message!<,$iif($nick !isreg $chan,$left($nick($chan,$nick).pnick,1)),$nick,>) $1- }
else { ppop Özel $+(mesaj!<,$nick,>) $1- }
}
}
on !*:invite:*:{ if ($ppop.trig(v)) { ppop Invite Daveti! $+ $nick sizi $chan kanalına davet ediyor. } }
on !*:ban:*:{ if ($banmask iswm $address($me,5)) && ($ppop.trig(k)) { ppop Kanaldan Banlandınız! $+ $nick sizi $chan kanalından banladı. $+ ! ( $+ $banmask $+ ) } }
on !*:kick:*:{ if ($knick == $me) && ($ppop.trig(k)) { ppop Kanaldan Atıldınız! $chan kanalından $nick tarafından atıldınız. $+ ! $iif($1- != $knick,Sebep: $1-) } }
on !*:notice:*:*:{
if ($ppop.trig(e)) {
if ($chan) { ppop Gelen Kanal $+(noticesi!-,$nick,:,$chan,-) $1- }
else { ppop Gelen $+(notice!-,$nick,-) $1- }
}
}
on *:unotify:{ if ($ppop.trig(f)) { ppop Ayrılış! $+ $nick IRC'den çıktı! } }
on *:notify:{ if ($ppop.trig(f)) { ppop Giriş! $+ $nick şu an IRC'de! } }
on *:open:?:{ if ($ppop.trig(q)) { ppop Gelen $+(Özel!<,$nick,>) $1- } }
on *:load:{
set %ppop.version 1.3
set %ppop.enabled 1
set %ppop.transp.en 1
set %ppop.transp 229
set %ppop.naw 0
set %ppop.delay 8
set %ppop.fade 1
set %ppop.width 250
set %ppop.color.bg 14679551
set %ppop.color.text 0
set %ppop.color.border 0
set %ppop.nactive 0
set %ppop.beep 0
set %ppop.pos br
set %ppop.events antdivkfq
}
on *:unload:{ unset %ppop.* }
on *:exit:{ unset %ppop.queue.* %ppop.fadecur.* }
menu @ppop {
uclick { ppop.doclose $iif($mouse.key & 4,-s) }
rclick { showmirc $iif($appstate == minimized,-r,-s) }
$ppop.doclose
}
; setup dialog
alias ppop.setup { dialog $iif($dialog(ppop.setup),-v,-m ppop.setup) ppop.setup }
dialog -l ppop.setup {
title SiLvEr v3 - Olay Görüntüleyici (v1.3)
size -1 -1 174 133
option dbu
tab "Genel", 1, 2 -1 170 116
box "Genel Ayarlar", 2, 6 14 162 97, tab 1
check "Aktif &Et", 3, 12 22 65 9, tab 1
text "Gecikme (0 sınırsız):", 4, 22 33 69 8, tab 1
edit %ppop.delay, 5, 93 31 38 11, tab 1 limit 3 center
text "saniye", 6, 134 33 24 8, tab 1
text "Genişlik:", 7, 22 44 23 8, tab 1
edit %ppop.width, 8, 93 42 38 11, tab 1 limit 4 center
check "Şeffaflık Ak&tif:", 9, 12 54 61 9, tab 1
edit "", 10, 93 53 38 11, tab 1 limit 3 center
text "%", 11, 134 55 9 8, tab 1
check "Geçiş E&fekti", 12, 12 63 43 9, tab 1
check "Yanlızca pencere aktif değilken göster", 13, 12 76 117 9, tab 1
check "Yanlızca away değilken göster", 14, 12 85 86 9, tab 1
check "Olaylarda 'bip' sesi çıkar", 15, 12 98 92 9, tab 1
text "piksel", 16, 134 44 18 8, tab 1
tab "Pozisyon", 17
text "Pencereyi Göster:", 18, 22 23 49 7, tab 17
radio "Sol Üst Köşe", 19, 40 32 47 9, tab 17 left
radio "Sağ Üst Köşe", 20, 91 32 54 9, tab 17
radio "Sağ Alt Köşe", 21, 91 41 63 9, tab 17
radio "Sol Alt Köşe", 22, 31 41 56 9, tab 17 left
check "Özel Pozisyon (Negatif sayılar kullanılabilir):", 23, 12 53 143 9, tab 17
text "X:", 24, 30 65 6 8, tab 17
edit %ppop.xoffset, 25, 39 63 26 11, tab 17 limit 5 center
text "Y:", 26, 30 76 6 8, tab 17
edit %ppop.yoffset, 27, 39 74 26 11, tab 17 limit 5 center
box "Pozisyon", 28, 6 14 162 76, tab 17
tab "Renkler", 29
box "Renkler", 30, 6 14 162 86, tab 29
text "Arkaplan:", 31, 12 23 35 8, tab 29
text "Kenarlık:", 33, 12 48 23 8, tab 29
text "Metin:", 35, 12 73 19 8, tab 29
icon 37, 80 31 48 12, $mircexe, 0, tab 29
icon 38, 80 56 48 12, $mircexe, 0, tab 29
icon 39, 80 81 48 12, $mircexe, 0, tab 29
edit $rgb(%ppop.color.bg), 32, 14 31 60 12, tab 29 center
edit $rgb(%ppop.color.border), 34, 14 56 60 12, tab 29 center
edit $rgb(%ppop.color.text), 36, 14 81 60 12, tab 29 center
tab "Olaylar", 40
box "Pencereyi Göster...", 41, 6 14 162 97, tab 40
check "Bağlantı Kurulduğunda", 42, 12 22 69 9, tab 40
check "CTCP İsteklerinde", 43, 12 31 67 9, tab 40
check "DCC Olaylarında", 44, 12 40 68 9, tab 40
check "Bağlantı Kesildiğinde", 45, 12 49 81 9, tab 40
check "Vurgularda", 46, 12 58 36 9, tab 40
check "Davetlerde", 47, 12 67 30 9, tab 40
check "Kick+Ban Olayında", 48, 12 76 38 9, tab 40
check "Noticelerde", 49, 100 22 30 9, tab 40
check "Giriş Çıkışlarda", 50, 100 31 31 9, tab 40
check "Özellerde", 51, 100 40 31 9, tab 40
check "Özel Durumlar (boşluk ile ayırın):", 52, 12 85 118 9, tab 40
edit $ppop.mkre(%ppop.ctrig).re, 53, 21 95 143 11, tab 40
tab "Hakkında", 54
box "Hakkında", 55, 6 14 162 88, tab 54
text "Script İsmi:", 56, 12 23 35 8, tab 54
text "SiLvEr ", 57, 52 23 110 8, tab 54 right
link "[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]", 58, 80 53 85 8, tab 54
text "Bu Add-on 'IrCbaStarD' tarafından EditLenmı$tir... ", 59, 52 63 110 34, tab 54 right
text "Açıklama:", 60, 12 63 35 8, tab 54
text "Anasayfa:", 61, 12 53 35 8, tab 54
text "Edit:", 62, 12 43 35 8, tab 54
text "Sürüm:", 63, 12 33 35 8, tab 54
text ..., 64, 52 33 110 8, tab 54 right
text "IrCbaStaRD", 65, 52 43 110 8, tab 54 right
button "&Tamam", 66, 48 119 40 12, ok
button "Ö&nizleme", 67, 2 119 40 12
button "İ&ptall", 68, 90 119 40 12
button "&Uygula", 69, 132 119 40 12
}
on *:dialog:ppop.setup:*:*:{
if ($devent == init) {
if (%ppop.enabled) { did -c $dname 3 }
else { did -b $dname 4,5,6,7,8,9,10,11,12,13,14,15,16,18,19,20,21,22,23,24,25,26,27,28,30,31,32,33,34,35,36,37,38,39,41,42,43,44,45,46,47,48,49,50,51,52,53 }
if (%ppop.transp.en) { did -c $dname 9 }
if (%ppop.transp !isnum 0-255) { set %ppop.transp 255 }
did -ra $dname 10 $int($calc(100- %ppop.transp /2.55))
if (%ppop.fade) { did -c $dname 12 }
if (%ppop.nactive) { did -c $dname 13 }
if (%ppop.naw) { did -c $dname 14 }
if (%ppop.beep) { did -c $dname 15 }
if (%ppop.offset) { did -c $dname 23 }
else { did -b $dname 24,25,26,27 }
if (%ppop.pos == tl) { did -c $dname 19 }
elseif (%ppop.pos == tr) { did -c $dname 20 }
elseif (%ppop.pos == br) { did -c $dname 21 }
elseif (%ppop.pos == bl) { did -c $dname 22 }
ppop.colprev.all
if (n isin %ppop.events) { did -c $dname 42 }
if (t isin %ppop.events) { did -c $dname 43 }
if (d isin %ppop.events) { did -c $dname 44 }
if (i isin %ppop.events) { did -c $dname 45 }
if (h isin %ppop.events) { did -c $dname 46 }
if (v isin %ppop.events) { did -c $dname 47 }
if (k isin %ppop.events) { did -c $dname 48 }
if (e isin %ppop.events) { did -c $dname 49 }
if (f isin %ppop.events) { did -c $dname 50 }
if (q isin %ppop.events) { did -c $dname 51 }
if (u isin %ppop.events) { did -c $dname 52 }
else { did -b $dname 53 }
}
elseif ($devent == sclick) {
if ($did == 3) {
if ($did($did).state) {
did -e $dname 4,5,6,7,8,9,12,13,14,15,16,18,19,20,21,22,23,28,30,31,32,33,34,35,36,37,38,39,41,42,43,44,45,46,47,48,49,50,51,52
if ($did(9).state) { did -e $dname 10,11 }
if ($did(23).state) { did -e $dname 24,25,26,27 }
if ($did(52).state) { did -e $dname 53 }
}
else { did -b $dname 4,5,6,7,8,9,10,11,12,13,14,15,16,18,19,20,21,22,23,24,25,26,27,28,30,31,32,33,34,35,36,37,38,39,41,42,43,44,45,46,47,48,49,50,51,52,53 }
}
elseif ($did == 9) { did $iif($did($did).state,-e,-b) $dname 10,11 }
elseif ($did == 23) { did $iif($did($did).state,-e,-b) $dname 24,25,26,27 }
elseif ($did == 52) { did $iif($did($did).state,-e,-b) $dname 53 }
elseif ($did == 58) { url -an [Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...] }
elseif ($did == 66) || ($did == 69) { ppop.setup.apply }
elseif ($did == 67) {
ppop.doclose -s
ppop Önizleme PenceresiBu alanda gelen uyarılar, olaylar vs. görüntülenir ...
}
elseif ($did == 68) { if ($input(Ayarları kaydetmeden çıkmak istediğinize emin misiniz?,wydu,Kaydetmeden Çık?)) { dialog -x $dname } }
}
elseif ($devent == edit) {
if ($did == 32) { ppop.colprev 37 $did($did) }
elseif ($did == 34) { ppop.colprev 38 $did($did) }
elseif ($did == 36) { ppop.colprev 39 $did($did) }
}
}
alias -l ppop.setup.apply {
if ($did(5) !isnum 0-) { did -ra $dname 5 8 }
did -ra $dname 5 $int($did(5))
set %ppop.delay $did(5)
set %ppop.enabled $did(3).state
if ($did(8) !isnum 50-9999) { did -ra $dname 8 $iif($did(8) isnum,$iif($did(8) < 50,50),250) }
did -ra $dname 8 $int($did(8))
set %ppop.width $did(8)
set %ppop.transp.en $did(9).state
if ($did(10) !isnum 0-100) { did -ra $dname 10 10 }
did -ra $dname 10 $int($did(10))
set %ppop.transp $calc((100- $did(10)) *2.55)
if ($did(19).state) { set %ppop.pos tl }
elseif ($did(20).state) { set %ppop.pos tr }
elseif ($did(21).state) { set %ppop.pos br }
elseif ($did(22).state) { set %ppop.pos bl }
set %ppop.offset $did(23).state
if ($did(25) !isnum) { did -ra $dname 25 0 }
did -ra $dname 25 $int($did(25))
set %ppop.xoffset $did(25)
if ($did(27) !isnum) { did -ra $dname 27 0 }
did -ra $dname 27 $int($did(27))
set %ppop.yoffset $did(27)
set %ppop.fade $did(12).state
set %ppop.nactive $did(13).state
set %ppop.naw $did(14).state
set %ppop.beep $did(15).state
var %e = a
if ($did(42).state) { %e = %e $+ n }
if ($did(43).state) { %e = %e $+ t }
if ($did(44).state) { %e = %e $+ d }
if ($did(45).state) { %e = %e $+ i }
if ($did(46).state) { %e = %e $+ h }
if ($did(47).state) { %e = %e $+ v }
if ($did(48).state) { %e = %e $+ k }
if ($did(49).state) { %e = %e $+ e }
if ($did(50).state) { %e = %e $+ f }
if ($did(51).state) { %e = %e $+ q }
if ($did(52).state) { %e = %e $+ u }
set %ppop.events %e
if (!$regex($did(32),/^\d+\x2C\d+\x2C\d+$/)) || ($rgb( [ $did(32) ] ) == $null) {
did -ra $dname 32 255,253,223
ppop.colprev 37 255,253,223
}
if (!$regex($did(34),/^\d+\x2C\d+\x2C\d+$/)) || ($rgb( [ $did(34) ] ) == $null) {
did -ra $dname 34 0,0,0
ppop.colprev 38 0,0,0
}
if (!$regex($did(36),/^\d+\x2C\d+\x2C\d+$/)) || ($rgb( [ $did(36) ] ) == $null) {
did -ra $dname 36 0,0,0
ppop.colprev 39 0,0,0
}
set %ppop.color.bg $rgb( [ $did(32) ] )
set %ppop.color.border $rgb( [ $did(34) ] )
set %ppop.color.text $rgb( [ $did(36) ] )
set %ppop.ctrig $ppop.mkre($did(53))
}
alias -l ppop.colprev.all {
ppop.colprev 37 $rgb(%ppop.color.bg)
ppop.colprev 38 $rgb(%ppop.color.border)
ppop.colprev 39 $rgb(%ppop.color.text)
}
alias -l ppop.colprev {
var %f = $+(",$scriptdir,ppop.colprev.bmp")
window -hpf @ppop.colprev 0 0 400 100
if (!$regex($2,/^\d+\x2C\d+\x2C\d+$/)) { did -h $dname $1 }
else {
if ($rgb( [ $2 ] ) != $null) {
did -v $dname $1
drawrect -nrf @ppop.colprev $v1 1 0 0 400 100
}
else { did -h $dname $1 }
}
drawsave @ppop.colprev %f
did -g $dname $1 %f
.remove %f
close -@ @ppop.colprev
}
alias -l ppop.mkre {
if ($1 != $null) {
if ($prop == re) { return $replacex($mid($1,5,-5),\^,^,\.,.,\|,|,|,$chr(44),\$,$,\\,\,\?,?,\+,+,\[,[,\],],.*,*,.,?,\ $+ $chr(123),$chr(123),\ $+ $chr(125),$chr(125),\ $+ $chr(40),$chr(40),\ $+ $chr(41),$chr(41)) }
else { return /\b( $+ $replacex($1,\,\\,$,\$,^,\^,|,\|,$chr(44),|,+,\+,.,\.,[,\[,],\],*,.*,?,.,$chr(123),\ $+ $chr(123),$chr(125),\ $+ $chr(125),$chr(40),\ $+ $chr(40),$chr(41),\ $+ $chr(41)) $+ )\b/i }
}
}
menu menubar,status {
Balon Ayar :/ppop.setup
}