#ByteCam on
menu status,menubar {
  -
  Web Kamera
  .-
  .Kamerayı Başlat:bc.open
  .-
  .$iif($bc.bcast != $true, $style(2)) Davet Gönder:bc.invite $$?="Davet Gönderilecek Nick:"
  .$iif(# == $null || !$bc.bcast, $style(2)) Kanala Davet #:bc.invite #
  .-
  .$iif($exists($bcdll) == $false, $style(2)) Kamerayı Kapat:bc.close
  -
}
 
alias bc.open { dll $bcdll OpenCam }
alias bc.close { dll -u $bcdll }
alias bc.website { .run [Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...] }
alias bc.forum { dll $bcdll Forum }
alias bc.upgrade { dll $bcdll Upgrade }
alias bc.about { dll $bcdll ShowAbout }
alias bc.opensnaps { .run $+(",$scriptdirWebCamera\Snapshots,") }
alias bc.openvids { .run $+(",$scriptdirWebCamera\Videos,") }
alias bc.bcast { return $dll($bcdll, ServerUp, $null) }
alias bc.port { return $dll($bcdll, ServerPort, $null) }
alias bc.modname { return $dll($bcdll, ModuleName, $null) }
alias bc.camname { return $dll($bcdll, CamName, $null) }
alias bc.cam { if ($bc.camname != $null) return $+($chr(91),$bc.camname,$chr(93)) | return $null }
alias bc.vstr { return $dll($bcdll, VersionString, $null) }
alias bc.vnum { return $dll($bcdll, VersionNumber, $null) }
alias bc.ad { say 0,2 WebCamera Script 4(Kameralı Script ile Sohbet)...0Download İcin [Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...] }
alias bc.invite { 
  if (!$bc.bcast) return
  .raw PRIVMSG $$1 $+(:, $chr(1), BYTECAM) INVITE $longip($$ip) $+($bc.port, $chr(1)) 
  .echo $color(Info2) -a $timestamp WebCamera Script Kamera Daveti Gonderildi: $$1
}
alias bc.irc {
  var %tmp = 1
  while (%tmp <= $scon(0)) {
    if ($scon(%tmp).network == SohbetHattiCom) {
      scon -t1 %tmp join #Kamera
      if (scon -s %tmp $window(#Kamera) != $null) { scon %tmp window -a #Kamera }
      return
    }
    inc %tmp
  }
  server -m irc.SohbetHatti.Com -j #Kamera
}
ctcp *:BYTECAM: {
  if ($2 == INVITE && $3 isnum && $4 isnum 1025-65535) {
    dll $bcdll OpenRemote $nick $address $$longip($3) $4
  }
  else if ($2 == REQUEST) {
  }
  haltdef
}
#ByteCam end
on *:load:{
  if ($bc.compatible) { .enable #ByteCam | set %bc.dir $bc.dir }
  else { .disable #ByteCam }
}
on *:unload:{
  if ($sock(gdiplus.head) != $null) { sockclose gdiplus.head }
  if ($sock(gdiplus.data) != $null) { sockclose gdiplus.data }
}
alias bc.dir { return $scriptdir }
alias bcdll { return $shortfn($+($bc.dir,ByteCam.dll)) }
alias bc.compatible { 
  if (!$exists($bcdll)) return $false
  if ($version < 6.14) {
    echo $color(Info2) -s -
    echo $color(Info2) -s mIRC $version WebCamera Kullanılması Icin Cok Eski.
    echo $color(Info2) -s Daha Rahat Kullanım Icin WebCamera Scripti Download Ediniz.
    echo $color(Info2) -s [Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]
     echo $color(Info2) -s -
    .timer 1 1 .unload -rs $shortfn($script)
    return $false
  }
  if (($os != XP) && ($os != 2003)) {
    if (!$exists($shortfn($+($bc.dir,gdiplus.dll)))) {
      .timer 1 1 bc.gdiplus
      return $false
    }
    if ($md5($shortfn($+($bc.dir,gdiplus.dll)), 2) != 3317698f2090dd811f0aa93190e13c82) {
      .timer 1 1 bc.gdiplus
      return $false
    }
  }
  return $true
}
alias bc.copy {
  var %err = 0
  if (!$exists($shortfn($+($bc.dir,ByteCam\.tmp\ByteCam.dll)))) return
  if ($dll(ByteCam.dll) != $null) { dll -u $dll(ByteCam.dll) | .timer 1 2 bc.copy | return }
  reseterror
  %err = 12
  .copy -o $+(",$scriptdirByteCam\.tmp\ByteCam.dll,") $+(",$scriptdirByteCam.dll,")
  %err = 10
  .remove $+(",$scriptdirByteCam\.tmp\ByteCam.dll,")
  %err = 0
  bc.open
  return
  :error
  if (%err == 12) { 
    .disable #ByteCam
    echo $color(Info) -s -
    echo $color(Info) -s Error copying ByteCam.dll
    echo $color(Info) -s WebCamera Kapatıldı.
    echo $color(Info) -s -
  }
  if (%err == 10) { bc.open }
  reseterror
}
dialog -l bc.gdiplus.table {
  title "gdiplus.dll update"
  size -1 -1 320 240
  option type pixels
  edit "", 101, 0 0 320 210, multi, read, return, vsbar, autovs
  text "", 102, 5 220 220 18, 
  button "Ok", 201, 265 212 50 25, default, ok, hide
}
on *:dialog:bc.gdiplus.dlg:init:0: {
}
alias -l bc.gdiplus.report {
  if ($dialog(bc.gdiplus.dlg)) {
    did -a bc.gdiplus.dlg 101 $+($$1-, $crlf)
    return
  }
  echo $color(Info2) -s $$1-
}
alias -l bc.gdiplus {
  if (($os == XP) || ($os == 2003)) return
  if (!$dialog(bc.gdiplus.dlg)) dialog -m bc.gdiplus.dlg bc.gdiplus.table
  if ($sock(gdiplus.head) != $null) {
    sockclose gdiplus.head
    .timer 1 1 bc.gdiplus
    return
  }
  if ($sock(gdiplus.data) != $null) {
    sockclose gdiplus.data
    .timer 1 1 bc.gdiplus
    return
  }
  unset %gdiplus.*
  if ($dialog(bc.gdiplus.dlg)) {
    did -r bc.gdiplus.dlg 101
    did -h bc.gdiplus.dlg 201
  }
  bc.gdiplus.report WebCamera modulunun WindowsXP'de calismasi icin GDI+ library Yuklu Olmasi gerekiyor.
  bc.gdiplus.report -
  bc.gdiplus.report WebCamera modulunu Windows $os $+ 'te kullanmak icin , gdiplus.dll dosyasini Yukleyin.. Yuklenecek yer: $+($bc.dir,gdiplus.dll)
  bc.gdiplus.report -
  bc.gdiplus.report WebCamera sizin icin gerekli olan gdiplus.dll dosyasini Yukleyecek.
  bc.gdiplus.report -
  sockopen gdiplus.head [Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...] 80
}
alias -l bc.gdiplus.fail {
  if (($os == XP) || ($os == 2003)) return
  if ($exists($shortfn($+($bc.dir,gdiplus.dll)))) .remove $+(",$bc.dir,gdiplus.dll,")
  bc.gdiplus.report GDI+ Yukleme Hatasi.. WebCamera Yuklemesi iptal edildi.
  unset %gdiplus.*
  .timer 1 1 .unload -rs $shortfn($script)
}
on *:sockopen:*: {
  if ($sockname == gdiplus.head) {
    sockwrite -n $sockname GET /WebCamera/gdiplus.dll HTTP/1.1
    sockwrite -n $sockname Host: [Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]
    sockwrite -n $sockname User-Agent: $os + mIRC $version
    sockwrite -n $sockname Accept: */*
    sockwrite -n $sockname Connection: close
    sockwrite -n $sockname
  }
}
on *:sockread:*:{
  if ($sockname == gdiplus.head) {
    sockread %gdiplus.head
    if ($sockerr > 0 || $sockbr == 0) { sockclose $sockname | bc.gdiplus.fail | return }
    if (%gdiplus.head == $null) {
      sockrename $sockname gdiplus.data
      return
    }
    tokenize 32 %gdiplus.head
    if ($1 == HTTP/1.1) {
      if ($2 != 200) { bc.gdiplus.report $3- | sockclose $sockname | bc.gdiplus.fail | return }
      write -c $+(",$bc.dir,gdiplus.dll,")
      bc.gdiplus.report gdiplus.dll yuklemesi tamamlandiginda, WebCamera Kullanıma hazır olcak.
      bc.gdiplus.report -
      bc.gdiplus.report gdiplus.dll Yukleniyor, Lutfen Bekleyiniz...
    }
    if (($1 == Content-Length:) && ($2 isnum)) {
      set %gdiplus.length $2
      set %gdiplus.recv 0
    }
  }
  if ($sockname == gdiplus.data) {
    sockread &data
    if ($sockerr > 0 || $sockbr == 0) { sockclose $sockname | bc.gdiplus.fail | return }
    inc %gdiplus.recv $sockbr
    bwrite $+(",$bc.dir,gdiplus.dll,") -1 -1 &data
    if (%gdiplus.length > 0) {
      var %rem = $calc(%gdiplus.length - %gdiplus.recv)
      if ($dialog(bc.gdiplus.dlg)) {
        did -o bc.gdiplus.dlg 102 1 $+($round($calc(100 - ((%rem / %gdiplus.length) * 100)), 0), %) Complete - $&
          $round($calc(%gdiplus.recv / 1024^2), 2) MB of $round($calc(%gdiplus.length / 1024^2), 2) MB
      }
    }
  }
}
on *:sockclose:*:{
  if ($sockname == gdiplus.data) {
    unset %gdiplus.*
    if ($dialog(bc.gdiplus.dlg)) { did -vf bc.gdiplus.dlg 201 }
    if ($bc.compatible) {
      .enable #ByteCam
      bc.gdiplus.report -
      bc.gdiplus.report GDI+ Yuklemesi Tamamlandı!
      bc.gdiplus.report $$bc.modname $bc.vstr Kullanıma Hazır.
    }
    else { .disable #ByteCam }
  }
}