on 10*:text:*:?: {
if ($ulevel == 101) {
;Burda master başlıyor..
    if ($1 == !ekle) && $2 {
     .auser 100 $2
     .notify $2
     msg $nick $2 Eklendi!
    }
    if ($1 == !sil) && $2 {
     .ruser 100 $2
     .notify -r $2
     unset $+(%,*,$2)
     msg $nick $2 Silindi!
    }
 
    if ($1 == !puan) {
     if ($2) {
        if (!$($+(%,login.,$2),2)) {
         if ($($+(%,online.,$2),2)) {
            msg $nick $2 online gözüküyor ama login olmadı!
            msg $nick $2 Toplam onLine Süresi $duration($($+(%,toplam.,$2),2),2)
         }
         else { msg $nick $2 Şu an offline $($+(%,online.,$nick),2) }
        }
        else {
         msg $nick $2 Şu anki onLine Süresi $duration($calc($ctime - $($+(%,login.,$2),2)),2)
         msg $nick $2 Toplam onLine Süresi $duration($calc($($+(%,toplam.,$2),2) + ($ctime - $($+(%,login.,$2),2))),2)
        }
     }
     else {
        msg $nick --- Listeleniyor ----
        var %i = $ulist(*,100,0)
        while %i {
         %n = $gettok($ulist(*,100,%i),1,42)
         msg $nick Nick: %n Puan: $duration($($+(%,toplam.,%n),2),2) Durum: $iif($($+(%,online.,%n),2),Online Login: $iif($($+(%,login.,%n),2),$duration($calc($ctime - $($+(%,login.,%n),2)),2),Login oLmamış! ),Offline)
         dec %i
        }
        msg $nick ----- Son ------
        msg $nick Ayrıntı için "!puan nick"
     }
    }
 
}
;master sonu
else {
;user başlangıcı
    if ($1 == !Login) {
     if ($($+(%,login.,$nick),2)) { msg $nick Zaten Loginsiniz! }
     else { msg $nick Login oLdunuz! }
     set $($+(%,login.,$nick),1) $ctime
    }
    if ($1 == !Puan) {
     msg $nick Puan: $duration($($+(%,toplam.,$nick),2),2)
    }
}
;user sonu
}
on 100:NOTIFY: { set $($+(%,online.,$nick),1) on }
on 100:UNOTIFY: {
if ($($+(%,login.,$nick),2)) {
    set $($+(%,toplam.,$nick),1) $calc($($+(%,toplam.,$nick),2) + ($ctime - $($+(%,login.,$nick),2)))
}
unset $($+(%,login.,$nick),1)
unset $($+(%,online.,$nick),1)
}