!ekle komutu ile access ekleme. - Sayfa 2 - IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası

Che · 20 Mart 2014, 09:49

Toprak tsk ederim kardesim birde !git !gel !+m !-m gibi komutları nasıl koruma botuna ekleriz.yardımcı olurmusunuz

Feragat · 20 Mart 2014, 21:49

Dukka Nickli Üyeden Alıntı
Bu forumdaki linkleri ve resimleri görebilmek için en az 25 mesajınız olması gerekir.

Toprak tsk ederim kardesim birde !git !gel !+m !-m gibi komutları nasıl koruma botuna ekleriz.yardımcı olurmusunuz

Şu mantıkla ekleme/düzenleme veya geliştirme yapabilirsin.

Kod: Kodu kopyalamak için üzerine çift tıklayın!

on *:text:*:#:{
  if $1 == !ekle {
    if (!$2) || $left($2,1) != $chr(35) { msg # Lütfen !ekle #kanal nick seviye şeklinde belirtiniz. | return }
    if (!$3) || $left($3,1) == $chr(35) { msg # Lütfen !ekle #kanal nick seviye şeklinde belirtiniz. | return }
    if (!$4) || $4 < 1 || $4 > 999 { msg # Lütfen !ekle #kanal nick seviye şeklinde belirtiniz. | return }
    set %:ykanal # | set %:achan $2 | set %:seviye $4
    .enable #access | .nickserv info $3
  }
  if $regex($1-,/^[.!]g[iıİ]t\s(?:\S{1,25})$/Si) { $iif($2 ison #, !sapart $2 #, !msg # $2 Nick'i Kanalda Yok) }
  if $regex($1-,/^[.!]gel\s(?:\S{1,25})$/Si) { !sajoin $2 # } 
  if $regex(m,$1-,/^[.!]([-+])m(?:\s[#]\S+)?$/S) { $iif($2, !mode $2 $+($regml(m,1), m), !mode # $+($regml(m,1), m)) } 
}
#access off
on *:notice:*:?:{
  if $nick == NickServ {
    if (*kayitli bir nick degil* iswm $1-) { msg %:ykanal $1 nick'i kayıtlı degildir. | .disable #access }
    if (*isim:* iswm $1-) { cs access %:achan add $1 %:seviye }
  }
  if $nick == ChanServ {
    if (*kanali kayitli degil* iswm $1-) || (*nick* *seviyeden eklendi* iswm $1-) || (*nick* kanalindaki erisim * olarak degisti* iswm $1-) || (*nick* kanalindaki erisim seviyesi zaten* iswm $1-) {
      msg %:ykanal $1- | .disable #access
    }
  }
}
#access end

!git Nick (aktif kanaldan sapart eder)
!gel Nick (aktif kanala sajoin eder)
!+m [#Kanal] veya !-m [#Kanal] (Eğer kanal belirtirsen belirttiğin kanalda mode uygular. Belirtmezsen, komutu kullandığın kanalda mode uygular.)

ZenqerDenq · 13 Şubat 2016, 07:07

on *:input:#: { if $1 == !ekle { chanserv access $chan add $2 $3 | halt } }
Şu şekilde yaparsak daha iyi olur sanırım kanalda yazmış olduğumuz komutu göndermemiş olarak.

Feragat · 13 Şubat 2016, 13:40

İnput eventını yalnızca sen kullanabilirsin, text eventını senin dışındaki kullanıcılar kullanabilir

Mylife · 07 Ekim 2016, 15:41

Kod: Kodu kopyalamak için üzerine çift tıklayın!

on +11*:input:*: {
  if ($1 == .ban) && ($2 isop $chan && $2 ishop $chan && $2 !isreg $chan && $2 ison $chan) { 
  echo -ta 15,1 $2 nick i 4 $chan 15 kanalında görevli. | return  }
  if $regex($1,/^.unban) {
  mode $chan -b $2 | echo -at 15,1 4 $2 15 nick inin banı kaldırıldı. }
  if $regex($1,/^.ban) && ($2 !ison $chan) { echo -at 4,1 $2 15 nick i 4 $chan 15 kanalında bulunmuyor! | return }
  elseif ($2 ison $chan) { mode $chan +b $2 | kick $chan $2 $3- }
  if $regex($1,/^.kick) {
  kick $chan $2 $3- }
  if ($1 == .akick) && ($2 isreg $chan) {
  chanserv akick $chan add $2!*@* $3- }
  if $regex($1,/^.akicksil) && ($2 isreg $chan) {
  chanserv akick $chan del $2!*@* }
  if ($1 == .accesslist) { chanserv access $chan list }
}

on +11*:notice:*:?: {
  if ($notice == $Chanserv) && $regex($1-,/.u..omu.a/i) {
  echo -at 15,1 $1- }
  if ($notice == $Chanserv) && $regex($1-,/...tes.ne.eklen.../i) {
  echo -at 15,1 $1- | privmsg $2 2 $chan kanalında akick alındınız. }
  if ($notice == $Chanserv) && $regex($1-,/.kick....tes.nd.n.s.l.nd../i) {
  echo -at 15,1 $1- }
  if ($notice == $Chanserv) && $regex($1-,/..b.l..dild./i) {
  echo -at 15,1 $1- }
}

kullanım;
ban atmak için; .ban nick
ban acmak için; .unban nick
kick atmak için; .kick nick
akick almak için; .akick nick sebep
akick silmek için; .akicksil nick
Access list e bakmak için; .accesslist
-
*Hangi kanal penceresinde kullanırsanız o kanal için işlem yapar.

diEfoRyoU · 23 Kasım 2018, 22:26

Kod: Kodu kopyalamak için üzerine çift tıklayın!

on *:text:*:#:{
  if $regex($1,/((!|\.)ekle)$) { 
    if (!$2) || $left($2,1) != $chr(35) { msg # Lütfen !ekle #kanal nick seviye şeklinde belirtiniz. | return }
    if (!$3) || $left($3,1) == $chr(35) { msg # Lütfen !ekle #kanal nick seviye şeklinde belirtiniz. | return }
    if (!$4) || $4 < 1 || $4 > 999 { msg # Lütfen !ekle #kanal nick seviye şeklinde belirtiniz. | return }
    set %:ykanal # | set %:achan $2 | set %:seviye $4
    .enable #access | .nickserv info $3
  }
  if $regex($1,/((!|\.)sil)$) { 
  if (!$2) || $left($2,1) != $chr(35) { msg # Lütfen !sil #kanal nick şeklinde belirtiniz. | return }
    if (!$3) || $left($2,1) =! $chr(35) { msg # Lütfen !sil #kanal şeklinde belirtiniz. | return }
  .enable #access | cs access $2 list $+(*,$3,*) | cs access $2 del $3 |  set %:ykanal # | set -eu5 %:achan $2 }
  if $regex($1,/((!|\.)list)$) {
    if !$2 || !$regex($left($2,1),/#) { msg # Access listesini istediğin kanalı belirtmelisin. | return }
  set %:ykanal # | set %:achan $2 | cs access $2 list } 
}
#access off
on *:notice:*:?:{
  if $nick == NickServ {
    if (*kayitli bir nick degil* iswm $1-) { msg %:ykanal $1 nick'i kayıtlı degildir. | .disable #access }
    if (*isim:* iswm $1-) { cs access %:achan add $1 %:seviye | .disable #access }
  }
  if $nick == ChanServ {
    if (*kanali kayitli degil* iswm $1-) || (*nick* *seviyeden eklendi* iswm $1-) || (*kanalinin erisim listesinden silindi* iswm $1-) || (*nick* kanalindaki erisim * olarak degisti* iswm $1-) || (*nick* kanalindaki erisim seviyesi zaten* iswm $1-) || (*kanalinin erisim listesinde bulunamad* iswm $1-) || (*erisim listesinde belirtilen tanima uyan kayit bulunamadi* iswm $1-) {
    msg %:ykanal $1- | .disable #access | halt }
    if  * $+ %:achan Kanali Erisim Listesi* iswm $strip($1-) { Set -eu5 %acc-list on }
    if $regex($1,/([0-9]{1,})) && %acc-list == on { msg  %:ykanal Nick: $3 Seviye: $2 $iif($4,Ekleyen: $4) } 
  }
}
#access end

Benzer Konular
Konu	Konuyu Başlatan	Forum	Cevaplar	Son Mesaj
Nickserv Access Komutu Eğitimi	blackhole	NickServ	12	07 Temmuz 2022 15:03
Access ekleme hk.	Fredyyy	mIRC Parça Kodlar	2	20 Ekim 2020 12:59
Access ekleme	Melek	mIRC Scripting Sorunları	1	17 Temmuz 2017 23:14
access ekle/sil	lacremel	mIRC Scripting Sorunları	5	12 Haziran 2008 22:55
Anopede cs access komutu	ZORBEY	Servisler	8	10 Mart 2006 18:21

Konuyu Toplam 1 Üye okuyor. (0 Kayıtlı üye ve 1 Misafir)

Etiketlenen Kullanıcılar
Etiketlemek istediğiniz kullanıcılar arasına virgül koyunuz. Örnek: nokta,sukunet,NucLear

5846 sayılı Fikir ve Sanat Eserleri Kanunu gereğince sitemizde telif hakkı bulunan mp3,video v.b. eserlerin paylaşımı yasaktır. Yasal işlem olması halinde paylaşan kişi yada kişilerin bilgileri gerekli kuruma verilecektir.