menu channel {
  Kanalda Sadece Kayitli Kullanicilarin Yazdiklarini Goreyim
  . $+ $iif($group(#kayitli-gosterim) == on,[X]) EVET :/.enable #kayitli-gosterim
  . $+ $iif($group(#kayitli-gosterim) == off,[X]) HAYIR:/.disable #kayitli-gosterim
  .Kayitli Nickler Listesi:run kayitlimi.txt
  .Kayitsiz Nickler Listesi:run kayitsizmi.txt
}

#kayitli-gosterim off
on ^*:Text:*:#mirchelp:{
  set %_msg__user $nick
  set %_msg__ < $+ $nick $+ > $1-
  set %_chan_not_reg $chan
  ;burada nick zaten once kayitli ise who cekmesine gerek kalmadan ve halt kullanilmadan text eventi oldugu gibi kaliyor.
  if $read(kayitlimi.txt,w,$nick) { return } 
  who $nick
  halt
}
#kayitli-gosterim END

raw 352:*:{
  if (*r* iswmcs $7 && %_msg__) { 
    echo -t %_chan_not_reg %_msg__
    if !$read(kayitlimi.txt,w,%_msg__user) { write  kayitlimi.txt %_msg__user }
  }
  elseif %_msg__ {
    if !$read(kayitsizmi.txt,w,%_msg__user) { write kayitsizmi.txt %_msg__user }
    unset %_msg__user %_chan_not_reg 
    halt
  }
}
raw 315:*:{
  if %_msg__ { unset %_msg__ }
  halt
}