asagidaki codeyi uzun zamandir kendim kullaniyorum gayet guzel calisiyor.bunu bot'a entegre etmeye calistim ama uzun oldugu icin bir yerlerde hep hata verdi.yardimci olabilirseniz sevinirim
Kod: Kodu kopyalamak için üzerine çift tıklayın!
alias takip {
if !$1 { echo -at Takip listesine alýnacak kanal'ý girmediniz. Kullaným þekli; $+($chr(2),/takip #kanalismi,$chr(2)) | halt }
if $hget($1) { echo -at $+($chr(2),$1,$chr(2)) kanal'ý zaten takip listesinde. | halt }
if $me !ison $1 { echo -at $+($chr(2),$1,$chr(2)) kanalýnda bulunmuyorsunuz. | halt }
else { hmake $1 100 | echo -at $+($chr(2),$1,$chr(2)) kanal'ý takip listesine eklendi. }
}
on *:quit: { var %1 = 1,%2 = $comchan($me,0) | while %1 <= %2 { if $hget($comchan($me,%1)) { hinc $v1 $+(ayr,½,$v1) 1 } | inc %1 } }
on *:nick: { var %= 1,%& = $comchan($me,0) | while %= <= %& { if $hget($comchan($me,%=)) { var %o = $v1 | hinc $v1 $+(nck,½,$v1) 1 | ekle $+(%o,nick,.txt) | write $+(%o,nick,.txt) Tarih: $+($chr(2),$date - $time,$chr(2)) Nick: $+($chr(2),$nick,$chr(2)) - Yeni nick: $+($chr(2),$newnick) } | inc %= } }
on !*:join:#: { if $hget(#) { hinc # $+(grs,½,#) 1 } }
on *:part:#: { if $hget(#) { hinc # $+(cks,½,#) 1 } }
on *:text:*:#: { if $hget(#) { hinc # $+(yz,½,#) 1 | hinc -m $+(yazý,#) $nick 1 } }
on *:ban:#: { if $hget(#) { hinc # $+(ban,½,#) 1 | ekle $+(#,ban,.txt) | write $+(#,ban,.txt) Tarih: $+($chr(2),$date - $time,$chr(2)) Banlýyan: $+($chr(2),$nick,$chr(2)) - Banlanan: $+($chr(2),$banmask,$chr(2)) } }
on *:unban:#: { if $hget(#) { hinc # $+(unbn,½,#) 1 | ekle $+(#,unban,.txt) | write $+(#,unban,.txt) Tarih: $+($chr(2),$date - $time,$chr(2)) Ban açan: $+($chr(2),$nick,$chr(2)) - Baný açýlan: $+($chr(2),$banmask) } }
on *:voice:#: { if $hget(#) { hinc # $+(yetki,½,#) 1 | hinc # $+(vc,½,#) 1 | ekle $+(#,yetkiler,.txt) | write $+(#,yetkiler,.txt) Tarih: $+($chr(2),$date - $time,$chr(2)) Voice veren: $+($chr(2),$nick,$chr(2)) - Voice olan: $+($chr(2),$vnick,$chr(2)) } }
on *:op:#: { if $hget(#) { hinc # $+(yetki,½,#) 1 | hinc # $+(op,½,#) 1 | ekle $+(#,yetkiler,.txt) | write $+(#,yetkiler,.txt) Tarih: $+($chr(2),$date - $time,$chr(2)) Op'u veren: $+($chr(2),$nick,$chr(2)) - Op olan: $+($chr(2),$opnick,$chr(2)) } }
on *:help:#: { if $hget(#) { hinc # $+(yetki,½,#) 1 | hinc # $+(hlp,½,#) 1 | ekle $+(#,yetkiler,.txt) | write $+(#,yetkiler,.txt) Tarih: $+($chr(2),$date - $time,$chr(2)) Halfop'u veren: $+($chr(2),$nick,$chr(2)) - Halfop olan: $+($chr(2),$hnick,$chr(2)) } }
on *:devoice:#: { if $hget(#) { hinc # $+(yetki,½,#) 1 | hinc # $+(devc,½,#) 1 | ekle $+(#,yetkiler,.txt) | write $+(#,yetkiler,.txt) Tarih: $+($chr(2),$date - $time,$chr(2)) Voice'u alan: $+($chr(2),$nick,$chr(2)) - Voice'u alýnan: $+($chr(2),$vnick,$chr(2)) } }
on *:deop:#: { if $hget(#) { hinc # $+(yetki,½,#) 1 | hinc # $+(deop,½,#) 1 | ekle $+(#,yetkiler,.txt) | write $+(#,yetkiler,.txt) Tarih: $+($chr(2),$date - $time,$chr(2)) Op'u alan: $+($chr(2),$nick,$chr(2)) - Op'u alýnan: $+($chr(2),$opnick,$chr(2)) } }
on *:dehelp:#: { if $hget(#) { hinc # $+(yetki,½,#) 1 | hinc # $+(dehlp,½,#) 1 | ekle $+(#,yetkiler,.txt) | write $+(#,yetkiler,.txt) Tarih: $+($chr(2),$date - $time,$chr(2)) Halfop'u alan: $+($chr(2),$nick,$chr(2)) - Halfop'u alýnan: $+($chr(2),$hnick,$chr(2)) } }
on *:mode:#: { if $hget(#) { hinc # $+(md,½,#) 1 | ekle $+(#,mode,.txt) | write $+(#,mode,.txt) Tarih: $+($chr(2),$date - $time,$chr(2)) Mod deðiþen: $+($chr(2),$nick,$chr(2)) - Deðiþen mod: $+($chr(2),$1-,$chr(2)) } }
alias rapor {
if !$1 { echo -at Rapor alýnacak kanal ismini girmediniz. Kullaným þekli; $+($chr(2),/rapor #kanalismi,$chr(2)) | halt }
if !$hget($1) { echo -at $+($chr(2),$1,$chr(2)) kanal'ý takip listesinde deðil. | halt }
else {
echo -a $+($chr(45),$chr(32),[,$chr(2),$1,$chr(2)) kanal'ý için istatist'likler] -
echo -a -
echo -a - Prefixler $+($chr(40),$iif($hget($1,$+(yetki½,$1)),$+($chr(2),$hget($1,$+(yetki½,$1)),$chr(2)),$+($chr(2),0,$chr(2))),$chr(41))
echo -a - [Voice: $+($iif($hget($1,$+(vc½,$1)),$+($chr(2),$hget($1,$+(vc½,$1)),$chr(2)),$+($chr(2),0,$chr(2))),]) - [OP: $+($iif($hget($1,$+(op½,$1)),$+($chr(2),$hget($1,$+(op½,$1)),$chr(2)),$+($chr(2),0,$chr(2))),]) - [Halfop: $+($iif($hget($1,$+(hlp½,$1)),$+($chr(2),$hget($1,$+(hlp½,$1)),$chr(2)),$+($chr(2),0,$chr(2))),])
echo -a - [Devoice: $+($iif($hget($1,$+(devc½,$1)),$+($chr(2),$hget($1,$+(devc½,$1)),$chr(2)),$+($chr(2),0,$chr(2))),]) - [DEOP: $+($iif($hget($1,$+(deop½,$1)),$+($chr(2),$hget($1,$+(deop½,$1)),$chr(2)),$+($chr(2),0,$chr(2))),]) - [Dehalfop: $+($iif($hget($1,$+(dehlp½,$1)),$+($chr(2),$hget($1,$+(dehlp½,$1)),$chr(2)),$+($chr(2),0,$chr(2))),])
echo -a - Kim kime ne zaman ne yetkisi vermiþ/almýþ? Görmek için: $+($chr(2),/yetki $1,$chr(2)) yazýnýz.
echo -a -
echo -a - Giren kullanýcý sayýsý: $iif($hget($1,$+(grs½,$1)),$+($chr(2),$hget($1,$+(grs½,$1))),$+($chr(2),Giren kullanýcý yok.))
echo -a - Ayrýlan kullanýcý sayýsý: $iif($hget($1,$+(cks½,$1)),$+($chr(2),$hget($1,$+(cks½,$1))),$+($chr(2),Ayrýlan kullanýcý yok.))
echo -a - Çýkan kullanýcý sayýsý: $iif($hget($1,$+(ayr½,$1)),$+($chr(2),$hget($1,$+(ayr½,$1))),$+($chr(2),Çýkan kullanýcý yok.))
echo -a - Nick deðiþim sayýsý: $iif($hget($1,$+(nck½,$1)),$+($chr(2),$hget($1,$+(nck½,$1)),$chr(32),$chr(2), - (Deðiþen nick'leri görmek için; $+($chr(2),/nik $1,$chr(2)) yazýnýz.)),$+($chr(2),Nick deðiþen yok.))
echo -a - Yazýlan satýr miktarý: $iif($hget($1,$+(yz½,$1)),$+($chr(2),$hget($1,$+(yz½,$1)),$chr(32),$chr(2), - (Kanal'da kimin kaç satýr cümle kurduðunu görmek için: $+($chr(2),/kns $1,$chr(2)) yazýnýz.)),$+($chr(2),Herhangi bir yazý yazýlmamýþ.))
echo -a - Atýlan ban sayýsý: $iif($hget($1,$+(ban½,$1)),$+($chr(2),$hget($1,$+(ban½,$1)),$chr(32),$chr(2), - (Kanal'da kim kime ne zaman ban atmýþ? Öðrenmek için: $+($chr(2),/bn $1,$chr(2)) yazýnýz.)),$+($chr(2),Atýlan ban yok.))
echo -a - Açýlan ban sayýsý: $iif($hget($1,$+(unbn½,$1)),$+($chr(2),$hget($1,$+(unbn½,$1)),$chr(32),$chr(2), - (Kanal'da kim ne zaman ban açmýþ? Öðrenmek için: $+($chr(2),/unbn $1,$chr(2)) yazýnýz.)),$+($chr(2),Açýlan ban yok.))
echo -a - Deðiþen mod sayýsý: $iif($hget($1,$+(md½,$1)),$+($chr(2),$hget($1,$+(md½,$1)),$chr(32),$chr(2), - (Kanal'da kim hangi mod'u deðiþtirmiþ? Öðrenmek için: $+($chr(2),/md $1,$chr(2)) yazýnýz.)),$+($chr(2),Deðiþen mod yok.))
}
}
alias kns {
if !$1 { echo -a - Lütfen kanal ismi giriniz; $+($chr(2),/kns #kanalismi) | halt }
if !$hget($+(yazý,$1)) { echo -a - Veri bulunamadý. | halt }
else { echo -a - $+($chr(2),$1,$chr(2)) kanalý için; $+($chr(2),$hget($+(yazý,$1),0).item,$chr(2)) adet veri bulundu. | var %& = 1,%&& = $hget($+(yazý,$1),0).item | while %& <= %&& { echo -a - Nick: $+($chr(2),$hget($+(yazý,$1),%&).item,$chr(2)) - Yazdýðý satýr miktarý: $+($chr(2),$hget($+(yazý,$1),%&).data,$chr(2)) | inc %& } }
}
alias bn {
if !$1 { echo -a - Lütfen kanal ismi giriniz; $+($chr(2),/bn #kanalismi) | halt }
if !$read($+($1,ban,.txt)) { echo -a - Veri bulunamadý. | halt }
else { echo -a - $+($chr(2),$1,$chr(2)) kanalý için; $+($chr(2),$hget($1,$+(ban½,$1)),$chr(2)) adet veri bulundu. | var %1 = 1,%2 = $lines($+($1,ban,.txt)) | while %1 <= %2 { echo -a - $read($+($1,ban,.txt),%1) | inc %1 } }
}
alias unbn {
if !$1 { echo -a - Lütfen kanal ismi giriniz; $+($chr(2),/unbn #kanalismi) | halt }
if !$read($+($1,unban,.txt)) { echo -a - Veri bulunamadý. | halt }
else { echo -a - $+($chr(2),$1,$chr(2)) kanalý için; $+($chr(2),$hget($1,$+(unbn½,$1)),$chr(2)) adet veri bulundu. | var %s = 1,%x = $lines($+($1,unban,.txt)) | while %s <= %x { echo -a - $read($+($1,unban,.txt),%s) | inc %s } }
}
alias yetki {
if !$1 { echo -a - Lütfen kanal ismi giriniz; $+($chr(2),/yetki #kanalismi) | halt }
if !$read($+($1,yetkiler,.txt)) { echo -a - Veri bulunamadý. | halt }
else { echo -a - $+($chr(2),$1,$chr(2)) kanalý için; $+($chr(2),$lines($+($1,yetkiler,.txt)),$chr(2)) adet veri bulundu. | var %q = 1,%r = $lines($+($1,yetkiler,.txt)) | while %q <= %r { echo -a - $read($+($1,yetkiler,.txt),%q) | inc %q } }
}
alias md {
if !$1 { echo -a - Lütfen kanal ismi giriniz; $+($chr(2),/md #kanalismi) | halt }
if !$read($+($1,mode,.txt)) { echo -a - Veri bulunamadý. | halt }
else { echo -a - $+($chr(2),$1,$chr(2)) kanalý için; $+($chr(2),$hget($1,$+(md½,$1)),$chr(2)) adet veri bulundu. | var %p = 1,%f = $lines($+($1,mode,.txt)) | while %p <= %f { echo -a - $read($+($1,mode,.txt),%p) | inc %p } }
}
alias nik {
if !$1 { echo -a - Lütfen kanal ismi giriniz; $+($chr(2),/nik #kanalismi) | halt }
if !$read($+($1,nick,.txt)) { echo -a - Veri bulunamadý. | halt }
else { echo -a - $+($chr(2),$1,$chr(2)) kanalý için; $+($chr(2),$hget($1,$+(nck½,$1)),$chr(2)) adet veri bulundu. | var %z = 1,%o = $lines($+($1,nick,.txt)) | while %z <= %o { echo -a - $read($+($1,nick,.txt),%z) | inc %z } }
}
alias ekle { if !$read(slnck.txt,w,$1) { write slnck.txt $1 } }
on *:connect: { sýfýrla | remove slnck.txt }
alias sýfýrla { echo -a - Tüm veriler sýfýr'landý. | .hfree -w yazý* | .hfree -w $+($chr(35),*) | var %oo = 1,%aa = $lines(slnck.txt) | while %oo <= %aa { .remove $read(slnck.txt,%oo) | inc %oo } }
-----------------------------------------
1- Kanal'da voice/halfop/op veren veya alanlarý.(Tarihleri dahil)
2- Kanal'da ban atan/atýlan veya baný açan/açýlan'larý.(Tarihleri dahil)
3- Kanal'da atýlan ban sayýsýný.
4- Kanal'a giren kullanýcý sayýsýný.
5- Kanal'dan çýkan kullanýcý sayýsýný.
6- Kanal'da bulunupta IRC'den çýkan sayýsýný.
7- Kanal'a kaç satýr text gönderdildiðini.
8- Kanal'da kimin ne zaman nick deðiþtiðini.(Tarihleri dahil)
9- Kanal'da ne zaman kim tarafýndan mod deðiþtirildiðini.(Tarihleri dahil)
Ek özellikler;
/kns #kanalismi yazarak kanal'da kimin kaç satýr yazý yazdýðýný,
/nik #kanalismi yazarak kanal'da kimin ne zaman nick deðiþtiðini ve yeni nick'ini,
/unbn #kanalismi yazarak kanal'da kim tarafýndan ne zaman ban açýldýðýný,
/bn #kanalismi yazarak kanal'da kim tarafýndan, ne zaman ban atýldýðýný,
/md #kanalismi yazarak kanal'da kimin, ne zaman, hangi modu, deðiþtirdiðini,
/yetki #kanalismi yazarak kimin kime ne yetki verdiði, tarihleri ile beraber
öðrenebilirsiniz.
/sýfýrla yazarak tüm kayýtlarý sýfýrlýyabilirsiniz.
Kullanýmý:
/takip #kanalismi (Kanal'ý takip'e alýr)
/rapor #kanalismi (Takip sonuçlarýný gösterir)
----------------------------------------------------
04 Mart 2009, 06:32
Benzer Konular 
Normal
