IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası

Sayfa 1 Toplam 2 Sayfadan

Konuya ait 40 Mesajı başka Sayfada göster

IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası (https://www.ircforumlari.net/)

- mIRC Scripting Sorunları (https://www.ircforumlari.net/mirc-scripting-sorunlari/)

- - !bomba nick (https://www.ircforumlari.net/mirc-scripting-sorunlari/184906-bomba-nick.html)

COMBOMAX

05 Mart 2009 17:05

!bomba nick

selam aleyküm öncelikle coderlerimizin yardımlarından ve ilgilerinden dolayı teşekkürü borç bilirim !bomba nick yazdıgımız zaman rastgele renkler verecek kendisi dogru bir renk sececek yanlış olursa atacak dogru olursa şimdilik kurtuldun bi dahaki sefere şanslı olmayabilirsin diyecek bu mümkünmü yardımcı olursanız seviinirim şimdiden tşkler iyiki varsın if varolmaya devam et inşallah :)

«16:44:06» <PRoFeSYoNeL> !bomba JetqiL
«16:44:08» <R2D2> Bombayı jetqiL isimli arkadaşın eline tutuşturur!. [32] Saniye içinde patlayacak!
«16:44:09» <R2D2> Bombayı etkisiz hale getirmek için 6 kablodan doğru olanı kesmelisin. Kablolar : altin lacivert mavi kahverengi yesil ve kirmizi. !kes renk
«16:44:12» <JetqiL> Bak ya
«16:44:13» <JetqiL> :D
«16:44:16» <PRoFeSYoNeL> geber
«16:44:17» <PRoFeSYoNeL> :D
«16:44:28» <JetqiL> !kes kirmizi
«16:44:29» • Kick : JetqiL R2D2 Tarafından Atıldı Sebep : ( Yanlış Kabloo *BOOOOOOOOOOM!*)

Hayat

05 Mart 2009 17:10

Cevap: !bomba nick

Eğlenceli birşeye benziyor komutları vermek kolayda renk seçimlerinin sürekli farklı olmasını nasıl sağlanır kestiremiyorum ceza alan kişiyede birşeyler yapmak lazım bomm demeyle olmaz örneğin titreşim addonu kullanarak timer 1 25 /titresim edilebilir

COMBOMAX

05 Mart 2009 17:13

Cevap: !bomba nick

hayat hocam kick atması yeter fazlası lazım değil :D

Difuzyon

05 Mart 2009 17:48

Cevap: !bomba nick

Kod:

on *:text:*:#:{

  if $1 == !bomba && $2 ison $chan && !%bombarenk {

    set $+(%,bomba,$2) $2

    set %bombarenkler altin lacivert mavi kahverengi yesil kirmizi

    set %bombarenk $token(%bombarenkler,$rand(1,6),32)

    $+(.,timer,$nick) 1 32 kick $chan $2 1Geç kaldın 4bOoOoOoomba1 patladı! $(|) unset %bomba*

    msg $chan Bombayı $2 isimli arkadaşın eline tutuşturur!. [32] Saniye içinde patlayacak!

    msg $chan Bombayı etkisiz hale getirmek için 6 kablodan doğru olanı kesmelisin. Kablolar : altin lacivert mavi kahverengi yesil ve kirmizi. !kes renk

  }

  if $var($+(%,bomba,$nick)) && $1 == !kes {

    if $2 == %bombarenk { $+(.,timer,$nick) off | msg $chan $nick şimdilik kurtuldun bi dahaki sefere şanslı olmayabilirsin :) | unset %bomba* }

    elseif $istok($remtok(%bombarenkler,%bombarenk,32),$2,32) { $+(.,timer,$nick) off | kick $chan $nick 1Yanlış Kabloo 4*BOOOOOOOOOOM!* | unset %bomba* }

  }

}

Böyle bir uygulama olabilir...

Heavenly

05 Mart 2009 17:55

Cevap: !bomba nick

:) supper bısey bu ya mırc'ı eglencelı hale getırıyo can sıkıntısına bırebır :) ellerınıze saglık

COMBOMAX

05 Mart 2009 17:59

Cevap: !bomba nick

[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...] eline sağlık süper olmuşta hocam !bomba nick bombayı başkasının eline verdiğimdede beni atıyor mümkünse yardımcı olurmusun
«17:43:19» <07PRoFeSYoNeL> !bomba K9
«17:43:19» <02K9> Bombayı K9 isimli arkadaşın eline tutuşturur!. [32] Saniye içinde patlayacak!
«17:43:19» <02K9> Bombayı etkisiz hale getirmek için 6 kablodan doğru olanı kesmelisin. Kablolar : altin lacivert mavi kahverengi yesil ve kirmizi. !kes renk
«17:43:41» <07PRoFeSYoNeL> .
«17:43:43» <07PRoFeSYoNeL> .
«17:43:52» • Kick : PRoFeSYoNeL , K9 Tarafından Atıldı Sebep: (1Geç kaldın 4bOoOoOoomba1 patladı!)

Difuzyon

05 Mart 2009 18:06

Cevap: !bomba nick

Kod:

;Kanala yazılan yazılarda

on *:text:*:#:{
 ;Eğer 1. kelime !bomba ise VE 2. kelime kanalda varolan bir nick ise VE %bombarenk isminde bir variables yoksa(Neden olmamasını istedim:Aynı anda 2. kez başlatılmasını engellemek için)

  if $1 == !bomba && $2 ison $chan && !%bombarenk {
 ;%bombaNick isminde bir değişken oluştur(Sebebi:Yazacak olan diğer nicklerle karışmasın)

    set $+(%,bomba,$2) $2

    ;%bombarenkler oluştur

    set %bombarenkler altin lacivert mavi kahverengi yesil kirmizi

    ;%bombarenkler 'den rastgele(1 2 3 4 5 6)  bir renk seç

    set %bombarenk $token(%bombarenkler,$rand(1,6),32)

    ;Zamanlayıcıyı başlat süre sonunda(32 sn) bilemezse\yanıtlamazsa kanaldan atılsın ve değişkenler silinsin

    $+(.,timer,$2) 1 32 kick $chan $2 Geç kaldın 4bOoOoOoomba1 patladı! $(|) unset %bomba*

    ;Kanala Belirtilen mesajı geç

    msg $chan Bombayı $2 isimli arkadaşın eline tutuşturur!. [32] Saniye içinde patlayacak!

    ;Kanala belirtilen mesajı geç

    msg $chan Bombayı etkisiz hale getirmek için 6 kablodan doğru olanı kesmelisin. Kablolar : altin lacivert mavi kahverengi yesil ve kirmizi. !kes renk

  }

  ;Eğer kanala yazan nick adına bir değişken varsa(yazan kişiyi doğrulamak adına) VE 1. kelimesi !kes ise

  if $var($+(%,bomba,$nick)) && $1 == !kes {
  ;Eğer 2. kelime rastgele seçilen renk ise(ki bu durumda doğru bulmuştur) , zamanlayıcıyı durdur ve kanal tebrik mesajı geç ve değişkenleri sil

    if $2 == %bombarenk { $+(.,timer,$nick) off | msg $chan $nick şimdilik kurtuldun bi dahaki sefere şanslı olmayabilirsin :) | unset %bomba* }
    ;Şayet 2. kelime doğru seçenek değilse ve aynı zamanda kanala yazdığı 2. kelime diğer renklerden biriyse zamanlayıcıyı durdur , kanaldan at ve değişkenleri sil

    elseif $istok($remtok(%bombarenkler,%bombarenk,32),$2,32) { $+(.,timer,$nick) off | kick $chan $nick Yanlış Kabloo 4*BOOOOOOOOOOM!* | unset %bomba* }

  }

}

Daha iyi kavramanız açısından kod içerisinde açıklamasınıda yazdım,o yanlışlığıda düzelttim.

konTes

05 Mart 2009 19:40

Cevap: !bomba nick

güzeL,doğRu Rengi biLinCe de PuAn veRiorduR heRaLde

COMBOMAX

05 Mart 2009 20:09

Cevap: !bomba nick

kontes maalesef puan vermesi luzumsuz gereksiz :D:D

Difuzyon

06 Mart 2009 00:09

Cevap: !bomba nick

Oyunu tek kişilik olarak dizayn ettim.Kodu botunuzu yüklediğinizde , oyunu (siz veya başkası) başlatır.
Ve cevap hakkı sadece !bomba Nick (komutundaki Nick'e aittir).
Bunun dışındaki cevaplar sayılmayacaktır.Ve ayrıca oyun esnasında 2. kez açılış yapamazsınız, taki oyun bitene kadar.
Belirttiğim gibi tek kişilik bir oyun...(daha doğrusu soruda öyle gördüm ama siz isterseniz çoklu bir şekilde dizayn edebilirim)

İyi forumlar...

TurkArkadas

06 Mart 2009 17:09

Cevap: !bomba nick

Kusura bakma yenıledım yıne olmadı ;frown

Mustafa

06 Mart 2009 17:19

Cevap: !bomba nick

güzelmiş :)

Difuzyon

06 Mart 2009 17:45

Cevap: !bomba nick

TurkArkadas ,
Olmayan nedir ? açıklarsanız size yardımcı olalım\hata varsa düzeltelim...

TurkArkadas

06 Mart 2009 18:02

Cevap: !bomba nick

Alıntı:

Difuzyon Nickli Üyeden Alıntı (Mesaj 653893)

TurkArkadas ,
Olmayan nedir ? açıklarsanız size yardımcı olalım\hata varsa düzeltelim...

Hocam Ben Sizin Kodu Mırc Remotesine ekledım Ve sonrasında Kanalda
(!bomba Nick) yazıyorum hıc bir sey olmuyor.

Difuzyon

06 Mart 2009 18:08

Cevap: !bomba nick

Kodu kendi mircinizi eklerseniz, siz bu oyundan yararlanamazsınız.

Başkası sizin nickinizi yazar ama siz hiçbirşey yapamazsınız.
Sadece kanalda soruyu soran , bilemediği takdirde kanaldan atan , bildiği takdirde tebrik eden görevini yerine getirirsiniz.

Bende bu oyuna dahil olmak istiyorum diyorsanız , kodu kendi mircinize değil ; kanalda @ konumunda olan bir bota veya başka bir nickin mircine yüklemelisiniz.
Daha önceki post mesajımda da bunu belirtmiştim,uygulamanız halinde oyundan yararlanırsınız.

Anladığınızı umuyorum...

DenperaS

07 Mart 2009 22:12

Cevap: !bomba nick

bu kodu difuzyon dediğiniz gibi boş bi txt dosyasına atıp bota yükledim diğer mircle girip !bomba nick yazdım bota başka birinin nickini yazdım kendi nickimi yazdım botun nickini yazdım. hiç bir şekilde olmadı op olarak yazdım deop durumunda yazdım başkalarına yazdırdım ama çalışmadı. hiç bi tepki vermedi. geçen buraya mesaj yazmıştım mesajım silinmiş sanırım bide nedenini öğrenebilirmiyim neden silindi?

TurkArkadas

07 Mart 2009 22:33

Cevap: !bomba nick

ne yazıkkı bendede yıne olmadı

Difuzyon

07 Mart 2009 22:34

Cevap: !bomba nick

Mesaj silinme sebebi belirtmişim : Kodu yenileyiniz
Şuan yenilenen kod çalışıyor,şayet sizde çalışmıyorsa çakışan başka bir TEXT eventı olabilir...

Skills

07 Mart 2009 22:45

Cevap: !bomba nick

Kod'da herhangi bi sorun yok. Çok güzel bir şekilde çalişiyor.

[22:25] <Difüzyon> !bomba Cenk
[22:25] <Skills> Bombayı Cenk isimli arkadaşın eline tutuşturur!. [32] Saniye içinde patlayacak!
[22:25] <Skills> Bombayı etkisiz hale getirmek için 6 kablodan doğru olanı kesmelisin. Kablolar : altin lacivert mavi kahverengi yesil ve kirmizi. !kes renk
[22:26] <Cenk> !kes mavi
[22:26] *** Cenk Skills Tarafından Kanaldan Atıldı (Yanlış Kabloo *BOOOOOOOOOOM!*)

Eline Sağlık Cenk. Güzel bi çalişma olmus.

DenperaS

08 Mart 2009 00:33

Cevap: !bomba nick

kodu çalıştırdım sanırım çakışma yapıyordu difuzyon eline emeğine sağlık çok sağolasın yalnız bota yaptıklarında bot kendi kendinide atıyor onu nasıl ömnleyebiliriz bota yaptıklarında bot bana kullanamazsınız diyebilirmi.

RapStar

08 Mart 2009 03:23

Cevap: !bomba nick

bende kullandım. gayet iyi çalışıyor.

Alıntı:

[03:08] <oZMoZ> !bomba OZMoZ
[03:08] <@RapStar> Bombayı OZMoZ isimli arkadaşın eline tutuşturur!. [32] Saniye içinde patlayacak!
[03:08:12] ******* RapStar #rapstar Kanalında Sana Sesleniyor... Yazdığı Yazı: "Bombayı OZMoZ isimli arkadaşın eline tutuşturur!. [32] Saniye içinde patlayacak!" *******
[03:08] <@RapStar> Bombayı etkisiz hale getirmek için 6 kablodan doğru olanı kesmelisin. Kablolar : altın lacivert mavi kahverengi yesil kırmızı. KuLLanImI: !kes renk
[03:08] <oZMoZ> !kes Kırmızı
[03:08] * RapStar Tarafından Atıldınız (Yanlış Kabloo *BOOOOOOOOOOM!*)

Kodu Biraz Kendime Göre Yazı Stili Verdim Biraz da Ayar Yaptım Deopken Çalışmaması Üzerine. Difüzyon Elinize Sağlık.

Kod:

on @*:text:*:#:{

  if $1 == !bomba && $2 ison $chan && !%bombarenk {

    set $+(%,bomba,$nick) $nick

    set %bombarenkler altın lacivert mavi kahverengi yesil kırmızı

    set %bombarenk $token(%bombarenkler,$rand(1,6),32)

    $+(.,timer,$nick) 1 32 kick $chan $2 1Geç KaLdIn 4bOoOoOoomba1 PatLadı! $(|) unset %bomba*

    msg $chan Bombayı $2 isimli arkadaşın eline tutuşturur!. [32] Saniye içinde patlayacak!

    msg $chan Bombayı etkisiz hale getirmek için 6 kablodan doğru olanı kesmelisin. Kablolar : altın lacivert mavi kahverengi yesil kırmızı. KuLLanImI: !kes renk

  }

  if $var($+(%,bomba,$nick)) && $1 == !kes {

    if $2 == %bombarenk { $+(.,timer,$nick) off | msg $chan Bravo  $nick  Doğru KabLoyu Kestin, Şimdilik KurtuLdun Bir Dahaki Sefere Şanslı OLmayabiLirsin :) | unset %bomba* }

    elseif $istok($remtok(%bombarenkler,%bombarenk,32),$2,32) { $+(.,timer,$nick) off | kick $chan $nick 1Yanlış Kabloo 4*BOOOOOOOOOOM!* | unset %bomba* }

  }

}

RapStar

08 Mart 2009 03:25

Cevap: !bomba nick

Gayet İyi Bir DÜşünce Olmuş Bence. ve Bu Düşünceye En İyi Kod da Böyle Yazılırdı Herhalde. Kullanamayan Arkadaşlar Bir Daha Gözden Geçirin Anlatılanları Tekrar Deneyin.

Dipnot : Her !Bomba nick Yazdığınızda Kablo Rengini Algoritmik Olarak Değişiyor.

Mustafa

08 Mart 2009 03:42

Cevap: !bomba nick

gayet güzel çalışıyor..

Difuzyon

08 Mart 2009 15:58

Cevap: !bomba nick

RapStar , kendine göre dizayn etmen güzel bir düşünce.
("Op olduğum kanalda çalışsın" mantığı için @ işareti eklemeni kast ediyorum)

2. satırıda şu şekilde değişirsen, kazara botun nickini yazmalarına engel olursun:

if $1 == !bomba && $2 ison $chan && !%bombarenk && $2 != $me {

İyi forumlar...

SiberShell

08 Mart 2009 22:13

Cevap: !bomba nick

Difuzyon Sayin Üstadim bu Oyunu CokLu OLarak Dizayn EdebiLirmiyiz Birde Bu Bombayi Eline Verdiğimiz Kişi sadece !kes renk komutunu KullanabiLsin Mümkünmüdür bu Hocam ?

SiberShell

08 Mart 2009 22:22

Cevap: !bomba nick

+ Birde Hocam tek 1 sefer cvp verebilsin bombayı alinde tutan kişi bunu 2 de yapabiLiriz ?

RapStar

08 Mart 2009 23:00

Cevap: !bomba nick

:) ilk sorun için zaten bomba elinde olan kişi sadece !kes renk uygulayabiliyor bence önce bir kodu al test et

MT EkoL

09 Mart 2009 14:51

Cevap: !bomba nick

Peki şu şekilde biraz daha genişletsek ;

!bomba #kanal yazdığımız zaman

Kanalda bulunan kişiler doğru rengi 30 saniye içinde kesemesse kanalda olan herkes uçsun :)

eğer doğru kabloyu kesip kanalı kurtaran olursada bot kişinin nickinide belirterek tebrik etsin :)

Tabi birde !bomba #kanal yapan kişi atılmasın kanaldan sadece

bu şekilde ayarlayabilirmisiniz.

Difuzyon

09 Mart 2009 18:11

Cevap: !bomba nick

Doğrusu bu kadar heyecan dolu olduğunuzu tahmin etmemiştim :)
Ama eğlenceye dönük olmak gerekir arada :)

Kod:

on @*:text:*:#:{

  if $1 == !bomba && $2 == $chan && !%bombarenk {

    set %bombarenkler altin lacivert mavi kahverengi yesil kirmizi

    set %bombarenk $token(%bombarenkler,$rand(1,6),32)

    set %bombacı $nick

    msg $chan $nicks($chan)

    msg $chan -

    msg $chan $qt($nick) kanala bombayı bırakır!04 [30] 01Saniye içinde patlayacak!

    msg $chan Bombayı etkisiz hale getirmek için 6 kablodan doğru olanı kesmelisiniz. Kablolar : altin lacivert mavi kahverengi yesil ve kirmizi. !kes renk

    $+(.,timer,$chan) 1 30 msg $chan 01Doğru kablo $qt(%bombarenk) .Geç kaldınız 4bOoOoOoomba1 patladı! $(|) .enable #bombardıman $(|) who $chan  

  }

  if $1 == !kes && $timer($chan) && $nick != %bombacı {

    if $2 == %bombarenk { $+(.,timer,$chan) off | msg $chan - | msg $chan Kanalın kahramanı  $nick .Hepinizi o kurtardı,tebrikler $nick :) | msg $chan - | unset %bomba* }

    elseif $istok($remtok(%bombarenkler,%bombarenk,32),$2,32) { kick $chan $nick 1Yanlış kabloyu kestin!4 | msg $chan Bomba halen aktif ! }

  }

  if $1 == !bomba && $2 ison $chan && !%bombarenk && $2 != $me {

    set $+(%,bomba,$2) $2

    set %bombarenkler altin lacivert mavi kahverengi yesil kirmizi

    set %bombarenk $token(%bombarenkler,$rand(1,6),32)

    $+(.,timer,$nick) 1 30 kick $chan $2 1Geç kaldın 4bOoOoOoomba1 patladı! $(|) unset %bomba*

    msg $chan Bombayı $2 isimli arkadaşın eline tutuşturur!. [30] Saniye içinde patlayacak!

    msg $chan Bombayı etkisiz hale getirmek için 6 kablodan doğru olanı kesmelisin. Kablolar : altin lacivert mavi kahverengi yesil ve kirmizi. !kes renk

  }

  if $var($+(%,bomba,$nick)) && $1 == !kes {

    if $2 == %bombarenk { $+(.,timer,$nick) off | msg $chan $nick şimdilik kurtuldun bi dahaki sefere şanslı olmayabilirsin :) | unset %bomba* }

    elseif $istok($remtok(%bombarenkler,%bombarenk,32),$2,32) { $+(.,timer,$nick) off | kick $chan $nick 1Yanlış Kabloo 4*BOOOOOOOOOOM!* | unset %bomba* }

  }

}

alias nicks {

  var %i = 1

  while ($nick($1,%i)) {

    var %cenk = %cenk $nick($1,%i)

    inc %i

  }

  return %cenk

}

#bombardıman off

raw 352:*:haltdef | if !$istok(%bombacı $me,$6,32) { raw -q kick $2 $6 1Bomba patladı 4*BOOOOOOOOOOM!* }

raw 315:*:haltdef | unset %bomba* | .disable #bombardıman

#bombardıman end

Oyun iki şekilde de çalışıyor;

1) Birinci sayfadaki verdiğimiz kod ve açıklaması: !bomba nick
2) İkincisi ise e-koL arkadaşımız belirttiği şekilde : !bomba #kanal

Bol eğlenceler...

moonlarge3162

19 Mart 2009 15:08

Cevap: !bomba nick

Puanlı yapsak çok iyi olur.

Ve Puanları HAfızasında Kaydetsin

TragediE

21 Mart 2009 01:16

Cevap: !bomba nick

Burda bu kodu herkez yapiyor ama ben yapamiyorum !bomba nick bende calismior : (

Difuzyon

22 Mart 2009 00:37

Cevap: !bomba nick

TragediE

1) Burdaki kodu #kanalda @ olan botunuzu yükleyin.
2) Kodu yüklediğiniz remote'da başka bir on *:TEXT event'ı varsa,kod çakışma yapar.Eğer bu kodun çalışmasını istiyorsanız diğer on *:TEXT event'ını kaldırırsınız.

Sizde oynayın,kanaldaki arkadaşlarınızda oynasın.Tüm yapmanız gereken bu.

aRiF	14 Nisan 2009 21:12

Cevap: !bomba nick

özelde bu oyunu oynama şansımız varmı
özelime gelen biri !oyun yazdığında oyun hakkında bilgi versin
!oyunoyna yazdığında oyun başlasın ve seçeneklerde 3 renk olsun yanlış cvp veya 30 sn de cvp vermeyene
/timer 40 00 /msg $nick Boooommmmm

aRiF	29 Nisan 2009 14:53

Cevap: !bomba nick

Mümkün Değil Demekki :)

toXic

29 Nisan 2009 15:06

Cevap: !bomba nick

Alıntı:

aRiF Nickli Üyeden Alıntı (Mesaj 687814)

Kod:

 

 

on *:text:*:?:{

if !oyun isin $1 {

.msg $nick Oyun Hakkında bilgi

.msg $nick Güzeldir

.msg $nick vs.

}

Özelde Nasıl oynancak Bu Oyun Kullanıcı özele !oyunoyna yazdıgı zamanbilemezse ignoremi edilcek? msg atması biraz abes ;P

ŞaH	30 Nisan 2009 12:37

Cevap: !bomba nick

Yaaa çok güzel çalışıyor gerçekten emeğe sağlık ama şu seçenekleri 2 yada 3 yapma şansımız varmı ?

YiGiTCAN

09 Mayıs 2009 20:13

Cevap: !bomba nick

Difuzyon Kardeş Emegine Saglık Bende Uzun Zamandır Bunu Arıyordum Konu Açmadım Ama Tesedüfen Buldum

Erdem

12 Mayıs 2009 16:18

Cevap: !bomba nick

Alıntı:

ŞaH Nickli Üyeden Alıntı (Mesaj 699829)

Yaaa çok güzel çalışıyor gerçekten emeğe sağlık ama şu seçenekleri 2 yada 3 yapma şansımız varmı ?

Kod:

        on @*:text:*:#:{
  if $1 == !bomba && $2 == $chan && !%bombarenk {
    set %bombarenkler altin mavi yesil kirmizi
    set %bombarenk $token(%bombarenkler,$rand(1,6),32)
    set %bombacı $nick
    msg $chan $nicks($chan)
    msg $chan -
    msg $chan 4 $qt($nick) 12kanala bombayı bırakır!04 [30] 01Saniye içinde patlayacak!
    msg $chan 12Bombayı etkisiz hale getirmek için 4 kablodan doğru olanı kesmelisiniz. 4Kablolar : 3altin mavi yesil ve kirmizi. 12!kes renk
    $+(.,timer,$chan) 1 30 msg $chan 01Doğru kablo $qt(%bombarenk) .Geç kaldınız 4bOoOoOoomba1 patladı! $(|) .enable #bombardıman $(|) who $chan  
  }
  if $1 == !kes && $timer($chan) && $nick != %bombacı {
    if $2 == %bombarenk { $+(.,timer,$chan) off | msg $chan - | msg $chan Kanalın kahramanı  $nick .Hepinizi o kurtardı,tebrikler $nick :) | msg $chan - | unset %bomba* }
    elseif $istok($remtok(%bombarenkler,%bombarenk,32),$2,32) { kick $chan $nick 1Yanlış kabloyu kestin!4 | msg $chan Bomba halen aktif ! }
  }
  if $1 == !bomba && $2 ison $chan && !%bombarenk && $2 != $me {
    set $+(%,bomba,$2) $2
    set %bombarenkler altin mavi yesil kirmizi
    set %bombarenk $token(%bombarenkler,$rand(1,6),32)
    $+(.,timer,$nick) 1 30 kick $chan $2 1Geç kaldın 4bOoOoOoomba1 patladı! $(|) unset %bomba*
    msg $chan 12Bombayı4 $2 12 isimli arkadaşın eline tutuşturur!. [30] Saniye içinde patlayacak!
    msg $chan 12Bombayı etkisiz hale getirmek için 4 kablodan doğru olanı kesmelisin. 4Kablolar :3 altin mavi yesil ve kirmizi.12 !kes renk
  }
  if $var($+(%,bomba,$nick)) && $1 == !kes {
    if $2 == %bombarenk { $+(.,timer,$nick) off | msg $chan 4 $nick 12şimdilik kurtuldun bi dahaki sefere şanslı olmayabilirsin :) | unset %bomba* }
    elseif $istok($remtok(%bombarenkler,%bombarenk,32),$2,32) { $+(.,timer,$nick) off | kick $chan $nick 1Yanlış Kabloo 4*BOOOOOOOOOOM!* | unset %bomba* }
  }
 }
 alias nicks {
  var %i = 1
  while ($nick($1,%i)) {
    var %cenk = %cenk $nick($1,%i)
    inc %i
  }
  return %cenk
 }
 #bombardıman off
 raw 352:*:haltdef | if !$istok(%bombacı $me,$6,32) { raw -q kick $2 $6 1Bomba patladı 4*BOOOOOOOOOOM!* }
 raw 315:*:haltdef | unset %bomba* | .disable #bombardıman
 #bombardıman end

Seçenekler 4 tanedir , umarım işinize yarar .

Spectral

21 Haziran 2009 21:46

Cevap: !bomba nick

Kod:

  if $var($+(%,bomba,$nick)) && $1 == !kes {

    if $2 == %bombarenk { $+(.,timer,$nick) off | msg $chan $nick şimdilik kurtuldun bi dahaki sefere şanslı olmayabilirsin :) | unset %bomba* }

    elseif $istok($remtok(%bombarenkler,%bombarenk,32),$2,32) { $+(.,timer,$nick) off | kick $chan $nick 1Yanlış Kabloo 4*BOOOOOOOOOOM!* | unset %bomba* }

  }

}

kodun bu kısmında sanırım hata var dogru bildin diyor 30 sn sonra tektar yanlış kablo diye kickliyor
ayrıca şöyle bir ekleme gerekli eger yanlış bilen biri oldugunda kicklenip oyunun bitmesi gereki ki bomba patlamis olur dimi :)
düzeltebilirseniz ne mutlu çok teşekkürler tekrar kod icin

ahmet_corum

21 Haziran 2009 22:52

Cevap: !bomba nick

[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...] arkadasım eline sağlık çok güzel olmuş atılan userleri 5 -10 saniye sora sajoin yapsa daha iyi olmaz mı ? Atılanlar geri girmeyi bilmeyebilir.

Tüm Zamanlar GMT +3 Olarak Ayarlanmış. Şuanki Zaman: 16:40.

Sayfa 1 Toplam 2 Sayfadan

Konuya ait 40 Mesajı başka Sayfada göster