şehir takip - IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası

Gulsum · 06 Aralık 2011, 14:31

herkese merhaba
ip takip codu vardı . ircye farklı bir nickle girmiş birisinin daha önceden hangi nicki kullandığını gösteriyodu.fakat modeme reset atıp ip adresi değiştiğinde bu yöntem işe yaramıyordu.bunu ip değilde bulunduğu şehire göre takibini yapması mümkünmü? bu istediğim cod büyük bir kanalda sorun olabilir cüki yüzlerce kişi girip cıkıyo kanala aynı şehirden yüzlerce kişi olabilir fakat ayrı bi özel kanal var 20 kişi civarında ve bu kanala giren kişilerin coğu aynı kişiler ve farklı farklı şehirlerde coğu.ip deyilde şehire göre nick takibi yapılabilirmi? hafıza kaydı kalıcımı olsun belirli günmü olsun bilemedim cünki aynı şehirden sayı 3 4 cıktığında nasıl kayıt edicek felan o coderlerin düşüneciği bişiy ben düşündüm işin icinden cıkamaadım karmaşık gibi biraz
Bu forumdaki linkleri ve resimleri görebilmek için en az 25 mesajınız olması gerekir.
bilgilerde o an belirlediğim kanala echo olarak gösterilebilirmi.bide olabilirse nick özelime geldiğinde veya ben özele aldığımda bu bilgileri tekrar vermesi mümkünmü. isterseniz kullandığım şehir tesbit ve ip takibi codlerını yazayım ona göre ayarlama yapabilirsiniz belki.

şehir

Kod: Kodu kopyalamak için üzerine çift tıklayın!

on *:sockopen:city*: { 
  var %komut sockwrite -nt $sockname
  %komut GET $+(/ip/,$token($sock($sockname).mark,2,42)) HTTP1.1/
  %komut Host: whatismyipaddress.com
  %komut $crlf
}
on *:sockread:city*: {
  var %/ | sockread %/
  if ($regex(%/,State/Region)) set %ipsehir [ $+ [  $token($sock($sockname).mark,2,42) ] ]  $token($remove(%/,<tr>,<th>,</tr>,</th>,</td>,<td>),2,58)
  if ($regex(%/,City:)) set %ipyer [ $+ [  $token($sock($sockname).mark,2,42) ] ]  $token($remove(%/,<tr>,<th>,</tr>,</th>,</td>,<td>),2,58)  
}
on *:sockclose:city*: {
  var %nick $token($sock($sockname).mark,1,42), %ip $token($sock($sockname).mark,2,42)
  echo -as Bilgi:2 %nick 6IP:2 %ip 6Sehir:2 %ipsehir [ $+  [ $token($sock($sockname).mark,2,42) ] ] 6Yer:2 %ipyer [ $+ [  $token($sock($sockname).mark,2,42) ] ]
  unset %ipsehir [ $+ [ $token($sock($sockname).mark,2,42) ] ] %ipyer [ $+ [ $token($sock($sockname).mark,2,42) ] ]
}
alias cit {
  var %rand $rand(0,99999)
  sockopen $+(city,%rand) whatismyipaddress.com 80
  sockmark $+(city,%rand) $1
}
raw 378:*: { cit $+($2,*,$gettok($gettok($1-,2,64),2,32)) |  haltdef }
alias city { 
  if ($1 == on) { set %city on | echo -ea Giris-City Sistem Open! }
  if ($1 == off) { set %city off | echo -ea Giris-City Sistem Deopen! }
}

ip takip

Kod: Kodu kopyalamak için üzerine çift tıklayın!

alias hashran return $rand(0,999999)
on *:join:#kanal: {
  if ($nick == $me) { halt }
  if ($nickbul($address($nick,2))) { $iif($numtok($nickler($address($nick,2)),32) > 2,echo # $nick &2 5Gizli Ajan:2 $nickler($address($nick,2))) }
  hadd -m seens $hashran $+($date,+,$address($nick,2),+,$nick)
}
on *:open:?: {
  if ($nickbul($address($nick,2))) { echo $nick &2 5Gizli Ajan:2 $nickler($address($nick,2)) }
}
alias query {
  query $1
  if ($nickbul($address($1,2))) {
    echo $1 &2 $1 5Gizli Ajan:2 $nickler($address($1,2))
    echo $1 -
  }
}
alias nickbul {
  if (!$hget(seens)) { hmake seens | hload seens seens.63 }
  var %s 1
  while $hget(seens,%s).data {
    var %tarih $token($v1,1,43), %adres $token($v1,2,43), %nick $token($v1,3,43)
    $iif($1 == %adres,return 1)
    inc %s
  }
  return 0
}
alias nickler {
  if (!$hget(seens)) { hmake seens | hload seens seens.63 }
  unset %nickler
  var %s 1
  while $hget(seens,%s).data {
    var %tarih $token($v1,1,43), %adres $token($v1,2,43), %nick $token($v1,3,43)
    if ($1 == %adres) { %nickler = $addtok(%nickler,%nick,32) }
    inc %s
  }
  return  $replace(%nickler,$chr(32),$+($chr(32),4,-,,$chr(32)))
}
alias kontrols {
  if (!$hget(seens)) { hmake seens | hload seens seens.63 }
  unset %nickler
  var %s 1
  while $hget(seens,%s).data {
    var %tarih $token($v1,1,43), %adres $token($v1,2,43), %nick $token($v1,3,43), %v1 $v1
    if ($calc($ctime(%tarih) - $ctime($date)) >= 0) { hdel -m seens $hfind(seens,%v1,1,W).data }
    inc %s
  }
  hsave -o seens seens.63
  hfree -sw seens
  hmake seens
  hload seens seens.63
}
on *:start: {
  if ($findfile($mircdir,seens.63,0) >= 1) { kontrols }
}
on *:exit: {
  hsave -o seens seens.63
}

toXic · 06 Aralık 2011, 14:38

Kod: Kodu kopyalamak için üzerine çift tıklayın!

alias yerelip {
  return %yerelipno
}
on *:sockopen:yerelbilgi: {
  sockwrite -n $sockname GET $+(/ip/,$yerelip HTTP/1.1)
  sockwrite -n $sockname Host: $+(whatismyipaddress.com,$str($crlf, 2))
  sockwrite -n $sockname User-Agent: Mozilla/5.0 (Windows; U; Windows NT 5.1; en-US; rv:1.7) Gecko/20040614 Firefox/0.8
  sockwrite -n $sockname $crlf
}
on *:sockread:yerelbilgi:{
  var %happen
  sockread $htmlfree(%happen)
  .tokenize 32 $htmlfree(%happen)
  if (*State/Region:* iswm %happen) {
    .set %yerelbölge 0
    .set %yerelbölge $1 $2 $3 $4 $5
    .set %yerelbölge $remove(%yerelbölge,State/Region:)
  }
  if (*City:* iswm %happen) {
    .set %yerelsehir 0
    .set %yerelsehir $1 $2 $3 $4 $5
    .set %yerelsehir $remove(%yerelsehir,City:)
  }
  if (*Country:* iswm %happen) {
    .set %yerelulke 0
    .set %yerelulke $1 $2 $3 $4 $5
    .set %yerelulke $remove(%yerelulke,Country:)
  }
  if (*Latitude:* iswm %happen) {
    .set %yerelenlem 0
    .set %yerelenlem $1 $2 $3 $4 $5
    .set %yerelenlem $remove(%yerelenlem,Latitude:)
  }
  if (*Longitude:* iswm %happen) {
    .set %yerelboylam 0
    .set %yerelboylam $1 $2 $3 $4 $5
    .set %yerelboylam $remove(%yerelboylam,Longitude:)
    .echo @[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]is ( $+ $time $+ ) 5,1 ·::4::6[10,1 Nick:7 %yerelnick 6]4,1::5::5· 
    .echo @[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]is ( $+ $time $+ ) 5,1 ·::4::6[10,1 IP No:7 %yerelipno 6]4,1::5::5· 
    .echo @[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]is ( $+ $time $+ ) 5,1 ·::4::6[10,1 Bölge:7 %yerelsehir 6]4,1::5::5· 
    .echo @[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]is ( $+ $time $+ ) 5,1 ·::4::6[10,1 Şehir:7 %yerelbölge 6]4,1::5::5· 
    .echo @[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]is ( $+ $time $+ ) 5,1 ·::4::6[10,1 Ulke:7 $replace(%yerelulke,TURKEY,Türkiye,GERMANY,Almanya,NETHERLANDS,Hollanda,UNITED KINGDOM,Ingiltere,UNITED STATES,Amerika B. Devletleri,CHINA,Çin,EGYPT,Mısır) 6]4,1::5::5· 
    .echo @[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]is ( $+ $time $+ ) 5,1 ·::4::6[10,1 Enlem:7 %yerelenlem 6]4,1::5::5· 
    .echo @[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]is ( $+ $time $+ ) 5,1 ·::4::6[10,1 Boylam:7 %yerelboylam 6]4,1::5::5· 
    .echo @[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]is ( $+ $time $+ ) 5,1 ·::4::6[10,1 *** 7Bilgi Sonu10 *** 6]4,1::5::5· 
  }
}
alias bilgi {
  if $sock(yerelbilgi) {
    sockclose $ifmatch
  }
  sockopen yerelbilgi whatismyipaddress.com 80
}
on *:snotice:*whois*: {
  if !$window(@[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]is) { window -neg1 @[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]is }
  set %yerelipno $remove($gettok($3,2,64),-1,$chr(41))
  set %yerelnick $2
  .bilgi
  halt
}
raw 378:*:$iif(!$window(@[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]is),window -ne @[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]is) | set %yerelnick $2 | set %yerelipno $7 | bilgi $7 | aline -h @[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]is ( $+ $time $+ ) 5,1 ·::4::6[10,1 Nick:7 %yerelnick 6]4,1::5::5· 
alias htmlfree {
  var %x, %i = $regsub($1-,/(^[^<]*>|<[^>]*>|<[^>]*$)/gi,$null,%x), %x = $remove(%x,&nbsp;)
  return %x
}

Bu kod whois cektiğiniz kişinin sehrini gösteriyor anladiğim kadari ile böyle birşey istiyorsunuz.

Gulsum · 06 Aralık 2011, 15:22

hayır ip takibi ve şehir gösteren cod varbende ve paylaştım yukarda istediğim farklı bişiy. yazdığımı bikez daha okursan sanırım daha iyi anlıcaksın yardımın için tşkler

Set · 06 Aralık 2011, 16:15

Kod: Kodu kopyalamak için üzerine çift tıklayın!

on !*:join:#KANAL: {
  userip $nick
}

alias hashran return $rand(0,999999)
on *:sockopen:city*: { 
  var %komut sockwrite -nt $sockname
  %komut GET $+(/ip/,$token($sock($sockname).mark,2,42)) HTTP1.1/
  %komut Host: whatismyipaddress.com
  %komut $crlf
}
on *:sockread:city*: {
  var %/ | sockread %/
  var %nick $token($sock($sockname).mark,1,42), %ip $token($sock($sockname).mark,2,42)
  if ($regex(%/,City:)) {
    var %nick $token($sock($sockname).mark,1,42), %ip $token($sock($sockname).mark,2,42), %sehir $token($free(%/),2-,58),%w @[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]liAjan
    $iif(!$window(%w),window -a %w)
    if ($nickbul(%ip)) { $iif($numtok($nickler(%ip),32) > 2,echo -t %w 4 %nick 5Gizli Ajan:4 Sehir %sehir - 2 $nickler(%ip)) }
    hadd -m seens $hashran $+($date,+,%ip,+,%nick)
  }
} 
alias cit {
  var %rand $rand(0,99999)
  sockopen $+(city,%rand) whatismyipaddress.com 80
  sockmark $+(city,%rand) $1
}
raw 340:*: { cit $+($token($token($2-,1,61),1,42),*,$token($2-,2-,64)) | haltdef }
alias nickler {
  if (!$hget(seens)) { hmake seens | hload seens seens.63 }
  unset %nickler
  var %s 1
  while $hget(seens,%s).data {
    var %tarih $token($v1,1,43), %adres $token($v1,2,43), %nick $token($v1,3,43)
    if ($1 == %adres) { %nickler = $addtok(%nickler,%nick,32) }
    inc %s
  }
  return  $replace(%nickler,$chr(32),$+($chr(32),4,-,,$chr(32)))
}
alias nickbul {
  if (!$hget(seens)) { hmake seens | hload seens seens.63 }
  var %s 1
  while $hget(seens,%s).data {
    var %tarih $token($v1,1,43), %adres $token($v1,2,43), %nick $token($v1,3,43)
    $iif($1 == %adres,return $true)
    inc %s
  }
  return $false
}
alias kontrols {
  if (!$hget(seens)) { hmake seens | hload seens seens.63 }
  unset %nickler
  var %s 1
  while $hget(seens,%s).data {
    var %tarih $token($v1,1,43), %adres $token($v1,2,43), %nick $token($v1,3,43), %v1 $v1
    if ($calc($ctime(%tarih) - $ctime($date)) >= 0) { hdel -m seens $hfind(seens,%v1,1,W).data }
    inc %s
  }
  hsave -o seens seens.63
  hfree -sw seens
  hmake seens
  hload seens seens.63
}
alias free {
  var %b, %i =  $regsub($1-,/(^[^<]*>|<[^>]*>|<[^>]*$)/gi,$null,%b),  %b = $remove(%b,&nbsp;,    )
  return %b
}
on *:start: {
  hmake seens
  if ($findfile($mircdir,seens.63,0) >= 1) { hload seens seens.63 | kontrols }
}
on *:exit: {
  hsave -o seens seens.63
}

Gulsum · 06 Aralık 2011, 17:53

hata veriyo
Bilgi: Romantikbalik IP: 62.29.98.129 Sehir: Yer:
Bilgi: DaMLa_ IP: 88.224.247.24 Sehir: Yer:
başkabişiy göstermiyo şehride belirtmiyo

bide yanlış anlaşıldığımı düşünüyorum. kısaca belirtim .belirlediğim kanala giren kişinin hangi şehirde oldunu göstercek ve karşısınada o şehirden hangi nickler bu kanala girmiş
örnek : bilgi:Ahmet ip 88.224.247.24 Sehir
Bu forumdaki linkleri ve resimleri görebilmek için en az 25 mesajınız olması gerekir.
ursa Bölge:osmangazi >> Bursadan #x kanalına Mehmet elif sedat Girmiş. Ahmet nicki daha önce bu nickleri kullanmış olabilir.

gibi.

POSOFxPOWER · 07 Aralık 2011, 02:16

IP adresten sehir bulmasi hic bizaman 100% gostermez
bazen dogru gosterir bazen gostermez..

Gulsum · 07 Aralık 2011, 13:16

Bu forumdaki linkleri ve resimleri görebilmek için en az 25 mesajınız olması gerekir.
fikrin için saol fakat bunu biliyorum 100% 97 doğru gestiryor .herneyse benim istediğim şey farklı zaten.belirlediğim kanala giren 20 30 kişi genellikle aynı kişiler . bu kişiler modeme reset atıp ip adresini değişmiş olsa dahi şehri değişmiyo . belirlediğim kanala giren kişilerin hangi şehirden ve nicklerini kayıt edicek bi cod. bu kişiler tekrar kanala başka nickle girdiğinde kaydetmiş verilerden bana şöle bi bilgi vericek.

Örnek
Bu forumdaki linkleri ve resimleri görebilmek için en az 25 mesajınız olması gerekir.
ilgi Nick:Ahmet Sehir
Bu forumdaki linkleri ve resimleri görebilmek için en az 25 mesajınız olması gerekir.
ursa Bölge:osmangazi : Bursadan #x
kanalına daha önce Mehmet elif sedat Girmiş. Ahmet nicki bu nickleri kullanmış olabilir.

gibi bilgi vericek. ip adresi ile nickleri takib eden cod var yukarda verdim benim istediğimde sehrine göre nick takibi.

Set · 07 Aralık 2011, 14:18

Code calisiyor sorun yok bende, KANAL kısmını ayarlarsin gözükür.

Kod: Kodu kopyalamak için üzerine çift tıklayın!

[14:17]  Nito Gizli Ajan: Sehir Urfa -   Deneme - MetaL

Gulsum · 01 Mayıs 2012, 00:17

bu cod whois cektiğim kişinin şehrini gösteriyodu 1 aya yakın çalışmaz oldu acaba wep sitesimi kapalı niye çalışmıyo yardım edermisiniz.

Kod: Kodu kopyalamak için üzerine çift tıklayın!

on *:sockopen:city*: { 
  var %komut sockwrite -nt $sockname
  %komut GET $+(/ip/,$token($sock($sockname).mark,2,42)) HTTP1.1/
  %komut Host: whatismyipaddress.com
  %komut $crlf
}
on *:sockread:city*: {
  var %/ | sockread %/
  if ($regex(%/,State/Region)) set %ipsehir [ $+ [  $token($sock($sockname).mark,2,42) ] ]  $token($remove(%/,<tr>,<th>,</tr>,</th>,</td>,<td>),2,58)
  if ($regex(%/,City:)) set %ipyer [ $+ [  $token($sock($sockname).mark,2,42) ] ]  $token($remove(%/,<tr>,<th>,</tr>,</th>,</td>,<td>),2,58)  
}
on *:sockclose:city*: {
  var %nick $token($sock($sockname).mark,1,42), %ip $token($sock($sockname).mark,2,42)
  echo -as Bilgi:2 %nick 6IP:2 %ip 6Sehir:2 %ipsehir [ $+  [ $token($sock($sockname).mark,2,42) ] ] 6Yer:2 %ipyer [ $+ [  $token($sock($sockname).mark,2,42) ] ]
  unset %ipsehir [ $+ [ $token($sock($sockname).mark,2,42) ] ] %ipyer [ $+ [ $token($sock($sockname).mark,2,42) ] ]
}
alias cit {
  var %rand $rand(0,99999)
  sockopen $+(city,%rand) whatismyipaddress.com 80
  sockmark $+(city,%rand) $1
}
raw 378:*: { cit $+($2,*,$gettok($gettok($1-,2,64),2,32)) |  haltdef }
alias city { 
  if ($1 == on) { set %city on | echo -ea Giris-City Sistem Open! }
  if ($1 == off) { set %city off | echo -ea Giris-City Sistem Deopen! }
}

muratt_aziz · 02 Mayıs 2012, 00:05

raw 378:*: { cit $+($2,*,$gettok($gettok($1-,2,64),2,32)) | haltdef }
Whois cektiğinde kırmızı belirttiğim yer ipadresini whois rawlarından ayırtediyor eğer rawlarla ilgili bir sorunun yoksa kodu yeni baştan yazdım
ben vodofone vın kullanmaktayım kendime göre verileri socket sistemiyle aldım kod aşağıda
umarım işine yarar

IP Address: 176.55.61.68
Vodafone Telekomunikasyon A.S.Organization
Ülke: Turkey
Şehir: Samsun
Enlem: 41.2867
Boylam: 36.33
Bu aldığım sonuç herhangi bir sunucuyla bağlantım yok oper girip whois çekmeden kodu yazdım sorun olmayacağını umuyorum

Kod: Kodu kopyalamak için üzerine çift tıklayın!

#shrtkp on
alias klk { sockopen city whatismyipaddress.com 80 }
on *:sockopen:city*: { 
  sockwrite -n $sockname GET /ip/ $+ %halat HTTP/1.1
  sockwrite -n $sockname Accept: text/html, application/xhtml+xml, */*
  sockwrite -n $sockname Accept-Language: tr-TR
  sockwrite -n $sockname User-Agent: Mozilla/5.0 (compatible; MSIE 9.0; Windows NT 6.1; WOW64; Trident/5.0)
  sockwrite -n $sockname Host: whatismyipaddress.com
  sockwrite -n $sockname DNT: 1
  sockwrite -n $sockname Connection: Keep-Alive
  sockwrite -n $sockname $crlf
}
on *:sockread:city*: {
  var %az
  sockread %az
  if (Country: isin %az) { echo -a 4Ülke:3 $remove($htmlfree(%az),Country:) }
  if (IP Address: isin %az) { echo -a 4 $htmlfree(%az) }
  if ISP: isin %az { echo -a 4 $gettok($htmlfree(%az),5,58) }
  if State/Region isin %az { echo -a 4Şehir:3 $remove($htmlfree(%az),State/Region:) }
  if Latitude: isin %az {  echo -a 4Enlem:3 $remove($htmlfree(%az),Latitude:) }
  if Longitude: isin %az {  echo -a 4Boylam:3 $remove($htmlfree(%az),Longitude:) }
}
alias htmlfree { 
  var %x, %i = $regsub($1-,/(^[^<]*>|<[^>]*>|<[^>]*$)/g,$null,%x), %x = $remove(%x,&nbsp;) 
  return %x 
}
raw 378:*: { var %halat $+($2,*,$gettok($gettok($1-,2,64),2,32)) | klk %halat  | haltdef }
#shrtkp end
alias klk { }
alias city { 
  if ($1 == on) { .enable #shrtkp | echo -ea Giris-City Sistem Açık! }
  if ($1 == off) { .disable #shrtkp | echo -ea Giris-City Sistem Kapalı! }
}
menu * {
  Şehir Takip
  .Aç:city on
  .Kapat:city off
}

Benzer Konular
Konu	Konuyu Başlatan	Forum	Cevaplar	Son Mesaj
Eğer bir şehir olabilseydin, hangi şehir olurdun ve neden?	Ayışığı	IF Soruyor	2	24 Haziran 2024 13:51
Çözüldü Nick takip-ıp takip-kelime takip	Yasakkk	mIRC Scripting Sorunları	7	15 Kasım 2022 18:59
Trump, Biden'ı dalga konusu yaptı! Şehir şehir gezip herkese izletiyor	CORDON BLEU	Dünyadan Haberler	0	10 Kasım 2022 19:57
Sağlıklı bir şehir nasıl olmalı? Yaşadığınız şehir size kilo aldırıyor olabilir mi?	Sanem	Sağlık Köşesi	0	24 Ekim 2018 16:12
Şehir şehir gezip erkeklerle s*ks yapacak	Seth	Haber Arşivi	0	02 Kasım 2014 17:27

Konuyu Toplam 1 Üye okuyor. (0 Kayıtlı üye ve 1 Misafir)

Etiketlenen Kullanıcılar
Etiketlemek istediğiniz kullanıcılar arasına virgül koyunuz. Örnek: nokta,sukunet,NucLear

5846 sayılı Fikir ve Sanat Eserleri Kanunu gereğince sitemizde telif hakkı bulunan mp3,video v.b. eserlerin paylaşımı yasaktır. Yasal işlem olması halinde paylaşan kişi yada kişilerin bilgileri gerekli kuruma verilecektir.