Badnick HASH korumasına Muaf kodu - IRCForumları - IRC ve mIRC Kullanıcılarının Buluşma Noktası

yokay · 28 Eylül 2017, 17:19

on *:start:{ $iif(!$isfile(badnick.tprk),.write badnick.tprk) | .hmake badnick 100 | .hload badnick badnick.tprk }
on @*:join:#:{
if $read(muafnick.trpk,w,$3) || $nick isop $chan || $nick isvoice $chan || $nick ishop $chan || $nick ison #angelus || $nick ison #geveze35@ { return }
if $hfind(badnick,$nick,1,W).data {
kick # $nick 1Nick değiştirip (/nick yeninick) tekrar kanala giriş yapabilirsiniz..
mode # +b $nick
if !$hget(bdnck,$nick) {
.hinc -msu20 bdnck $nick
msg #angelus $chan kanalında [ JOIN ] $nick nicki badnick olarak tespit edildi. $+([,$chr(32),$hget(badnick,$hfind(badnick,$nick,1,W).data),$chr(32),])

}
}
}
on *:nick:{
if $hfind(badnick,$newnick,1,W).data {
if $read(muafnick.trpk,w,$nick) || $nick isop $chan || $nick isvoice $chan || $nick ishop $chan || $nick ison #angelus || $nick ison #geveze35@ { return }
msg #angelus [ NICK ] $newnick nicki badnick olarak tespit edildi. $+([,$chr(32),$hget(badnick,$hfind(badnick,$newnick,1,W).data),$chr(32),])
var %:c $regsubex($str(-,$comchan($newnick,0)),/./g, $iif($regex($nick($comchan($newnick,\n),$me).pnick,/(%|@|&|~\.)/i),$comchan($newnick,\n) $chr(32)))
var %c = 1 | while %c <= $token(%:c,0,32) {
mode $token(%:c,%c,32) +b $newnick | kick $token(%:c,%c,32) $newnick 1Nick değiştirip (/nick yeninick) tekrar kanala giriş yapabilirsiniz..
inc %c
}
}
}
on *:text:*:#:{
if ($regex($nick(#,$nick).pnick,[&.~.@])) {
if $regex($1,/^[!\.]badnick$/Si) {
if $regex($2,/^ekle$/Si) {
if (!$3) { msg # Lütfen nick belirtiniz | return }
if $hfind(badnick,$strip($3),0,W).data { msg # Eklemeye çalıştığınız badnick zaten $+([,$chr(32),$hget(badnick,$hfind(badnick,$strip($3),1,W).data),$chr(32),]) maskesi ile uyuşmakta. | return }
var %n = $left($calc($ctime * $rand(1000,9999)),7)
.hadd -m badnick %n $strip($3)
.hsave -o badnick badnick.tprk
msg # $strip($3) Badnick listesine eklendi.
}
if $regex($2,/^s[ıiİ]l$/Si) {
if (!$3) { msg # Lütfen nick belirtiniz | return }
if !$hfind(badnick,$strip($3),0,W).data { msg # Bad nick listesinde bulunmamaktadir. | return }
.hdel -m badnick $hfind(badnick,$strip($3),1,W).data
.hsave -o badnick badnick.tprk
msg # $strip($3) Badnick listesinden silindi.
}
if $regex($2,/^tara$/Si) {
if $read(muafnick.trpk,w,$nick) { return }
if (!$3) { msg # Lütfen nick belirtiniz | return }
if !$hfind(badnick,$strip($3),0,W).data { msg # Badnick listem'de $strip($3) ait bir mask yok. | return }
msg # Nick: $strip($3) - 4 Mask: $+([,$chr(32),$hget(badnick,$hfind(badnick,$strip($3),1,W).data),$chr(32),])
}
if $regex($2,/^l[ıiİ]st$/Si) {
if ($hget(badnick,0).data == 0) { msg # Badnick listesi boş. | return }
msg # Badnick listesi
msg # -
var %i = 1 | while (%i <= $hget(badnick,0).data) { msg # %i $+ .4) [ $hget(badnick,%i).data ] | inc %i }
msg # -
msg # Badnick listesi sonu
}
}
if $regex($1,/^[!\.]tara$/Si) {
if !$regex($2,/^#/Si) { msg # Lütfen #kanal belirtiniz | return }
if !$chan($2) { msg # $2 kanal'ında bulunmuyorum | return }
var %:tara = 1 | while %:tara <= $nick($2,0) {
if $hfind(badnick,$nick($2,%:tara),1,W).data {
msg #angelus [ TARAMA ] $nick($2,%:tara) nicki badnick olarak tespit edildi. $+([,$chr(32),$hget(badnick,$hfind(badnick,$nick($2,%:tara),1,W).data),$chr(32),])
mode $2 +b $nick($2,%:tara) | kick $2 $nick($2,%:tara) 4 Badnick! 1Nick değiştirip(/nick yeninick) tekrar kanala giriş yapabilirsiniz..
}
inc %:tara
}
}
}

Badnick korumasına if $read(muafnick.trpk,w,$3) || $nick isop $chan || $nick isvoice $chan || $nick ishop $chan || $nick ison #angelus || $nick ison #geveze35@ { return } olarak muaf ekledim lakin çalışmıyor, ayrıca badnick taramasına muaf eklememe rağmen badnick taraması yaparken muaf olanları da atıyor, var mı yardımcı olabilecek.

BlackForce · 29 Eylül 2017, 18:15

Kod: Kodu kopyalamak için üzerine çift tıklayın!

on *:start:{ $iif(!$isfile(badnick.tprk),.write badnick.tprk) | .hmake badnick 100 | .hload badnick badnick.tprk }


alias -l kanal return #geveze35
alias -l komutKanal return #geveze35|#geveze3555
alias -l bilgiKanal return #angelus


on *:join:*: { 
  if $chan == $kanal && $nick !isop $chan && $nick !ishop $chan && $nick !ison $bilgiKanal && $nick !ison #geveze35@ {
    if $hfind(badnick,$nick,1,W).data {
      if $read(muafnick.txt,w,$nick) { msg #geveze35 Muaf nick girişi; $nick | return }
      kick $kanal $nick 1Nick değiştirip (/nick yeninick) tekrar kanala giriş yapabilirsiniz..
      mode $kanal +b $nick
      if !$hget(bdnck,$nick) {
        .hinc -msu20 bdnck $nick
        msg $bilgiKanal $chan kanalında [ JOIN ] $nick nicki badnick olarak tespit edildi. $+([,$chr(32),$hget(badnick,$hfind(badnick,$nick,1,W). data),$chr(32),])
      }
    }
  }
}
on *:nick:{
  if $hfind(badnick,$newnick,1,W).data && $newnick !isop $chan && $newnick !isvoice $chan && $newnick !ishop $chan && $newnick !ison $bilgiKanal && $newnick !ison #geveze35@ {
    if $read(muafnick.txt,w,$newnick) { msg $bilgiKanal Muaf nick değişimi; $nick >> $newnick | return }
    if $read(muafnick.txt,w,$nick) { msg $bilgiKanal Muaf nick değişimi; $nick >> $newnick | return }
    msg $bilgiKanal [ NICK ] $newnick nicki badnick olarak tespit edildi. $+([,$chr(32),$hget(badnick,$hfind(badnick,$newnick,1, W).data),$chr(32),])
    var %:c $regsubex($str(-,$comchan($newnick,0)),/./g, $iif($regex($nick($comchan($newnick,\n),$me).pnick ,/(%|@|&|~\.)/i),$comchan($newnick,\n) $chr(32)))
    var %c = 1 | while %c <= $token(%:c,0,32) {
      mode $token(%:c,%c,32) +b $newnick | kick $token(%:c,%c,32) $newnick 1Nick değiştirip (/nick yeninick) tekrar kanala giriş yapabilirsiniz..
      inc %c
    }
  }
}
on *:text:*:#: {
  if !$regex($chan,/^( $+ $komutKanal $+ )$/i) { halt }
  if ($regex($nick(#,$nick).pnick,[&.~.@])) { 
    if $regex($1,/^[!\.]badnick$/Si) {
      if $regex($2,/^ekle$/Si) {
        if (!$3) { msg # Lütfen nick belirtiniz | return } 
        if $hfind(badnick,$strip($3),0,W).data { msg # Eklemeye çalıştığınız badnick zaten $+([,$chr(32),$hget(badnick,$hfind(badnick,$strip($3), 1,W).data),$chr(32),]) maskesi ile uyuşmakta. | return }
        if $read(muafnick.txt,w,$3) { msg # 2Bu kişi muaf nick listemde yer almakta. | return }
        var %n = $left($calc($ctime * $rand(1000,9999)),7)
        .hadd -m badnick %n $strip($3)
        .hsave -o badnick badnick.tprk
        msg # $strip($3) Badnick listesine eklendi.
      }
      if $regex($2,/^s[ıiİ]l$/Si) {
        if (!$3) { msg # Lütfen nick belirtiniz | return } 
        if !$hfind(badnick,$strip($3),0,W).data { msg # Bad nick listesinde bulunmamaktadir. | return }
        .hdel -m badnick $hfind(badnick,$strip($3),1,W).data
        .hsave -o badnick badnick.tprk
        msg # $strip($3) Badnick listesinden silindi.
      }
      if $regex($2,/^tara$/Si) {
        if (!$3) { msg # Lütfen nick belirtiniz | return } 
        if $read(muafnick.txt,w,$3) { msg # 2Bu kişi muaf nick listemde yer almakta. | return }
        if !$hfind(badnick,$strip($3),0,W).data { msg # Badnick listem'de $strip($3) ait bir mask yok. | return }
        msg # Nick: $strip($3) - 4 Mask: $+([,$chr(32),$hget(badnick,$hfind(badnick,$strip($3), 1,W).data),$chr(32),])
      }
      if ($2 == muaf) {
        if (!$3) { msg # Lütfen nick belirtiniz | return } 
        if $read(muafnick.txt,w,$3) { msg # $3 muaf listesinden silindi. | write $+(-dl,$read(muafnick.txt,w,$3)) muafnick.txt | return }
        msg # $3 muaf nick listesine eklendi.
        write muafnick.txt $3
      }
      if $regex($2,/^l[ıiİ]st$/Si) {
        if ($hget(badnick,0).data == 0) { msg # Badnick listesi boş. | return }
        msg # Badnick listesi
        msg # -
        var %i = 1 | while (%i <= $hget(badnick,0).data) { msg # %i $+ .4) [ $hget(badnick,%i).data ] | inc %i }
        msg # -
        msg # Badnick listesi sonu
      } 
    }
    if $regex($1,/^[!\.]tara$/Si) {
      if !$regex($2,/^#/Si) { msg # Lütfen #kanal belirtiniz | return } 
      if !$chan($2) { msg # $2 kanal'ında bulunmuyorum | return }
      var %:tara = 1 | while %:tara <= $nick($2,0) {
        if $hfind(badnick,$nick($2,%:tara),1,W).data && !$read(muafnick.txt,w,$nick($2,%:tara)) {
          msg # [ TARAMA ] $nick($2,%:tara) nicki badnick olarak tespit edildi. $+([,$chr(32),$hget(badnick,$hfind(badnick,$nick($2,%: tara),1,W).data),$chr(32),])
          mode $2 +b $nick($2,%:tara) | kick $2 $nick($2,%:tara) 4 Badnick! 1Nick değiştirip(/nick yeninick) tekrar kanala giriş yapabilirsiniz..
        }
        inc %:tara
      } 
      msg # Toplam $nick($2,0) kişi için, $hget(badnick,0).data adet mask taraması yapıldı. 
    }
  }
}

Böyle deneyebilir misin?

Muaf nick; .badnick muaf nick [Eklemek/Silmek için aynı komut]

Hesapsiz33 · 27 Şubat 2020, 16:51

On *:nick:{
if !$hfind(muafnick,$newnick,1,W).data && $hfind(badnick,$newnick,1,W).data {
var %:c vs işlem

on *:nick:{
if ($newnick isop $chan) { return } yaptım olmadı.
aynı sekilde kanal yerine $nick yaptım yine olmadı

on *:nick:{
if ($newnick !isreg $chan) { return } nick ve kanal yerini degistirdim yine olmadı.

Ne yaptıysam olmuyor kanalda prefix almış kullanıcıyı yine de atıyor bir sekilde. Buna nasıl bir cözüm bulunabilir acaba?

OperServ · 27 Şubat 2020, 21:03

Kod: Kodu kopyalamak için üzerine çift tıklayın!

on  @[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]:JOIN:*:{
  if ($ulist($fulladdress,koruma,0) >= 1) { return }
  elseif !$istok(#muafkanal #muafkanal2,$chan,32) {
    mode $chan +b $nick 
    kick $chan $nick Badnick
  }
}
on *:NICK:{ 
  if ($ulist($+($newnick,!*@*),koruma,0) >= 1) { return }
  else {
    if $ulist($+($newnick,!*@*),badnick,0) {
      var %Plt = 1 
      while $comchan($newnick,%Plt) { 
        var %e = $v1 
        if $me isop %e && !$istok(#muafkanal #muafkanal1,%e,32) { 
          mode %e +b $newnick 
          kick %e $newnick Badnick
        } 
        inc %Plt 
      } 
    } 
  }
}
alias badnickekle {
  auser badnick $1 $+ !*@*
}
alias badnicksil {
  ruser badnick $1 $+ !*@*
}
alias nickkoruma {
  auser koruma $1 $+ !*@*
}
alias badidentekle {
  auser badnick *! $+ $1 $+ @*
}
alias badidentsil {
  ruser badnick *! $+ $1 $+ @*
}
alias identkoruma {
  auser koruma *! $+ $1 $+ @*
}

Koda muaf kanal ve muaf nickler vardir ornek /badnickekle *gay* /nickkoruma *turgay* gibi Ekleme yapabilirsin
Kolay gelsin

Hesapsiz33 · 27 Şubat 2020, 21:35

OperServ Nickli Üyeden Alıntı
Bu forumdaki linkleri ve resimleri görebilmek için en az 25 mesajınız olması gerekir.

Kod: Kodu kopyalamak için üzerine çift tıklayın!

on  @[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]:JOIN:*:{
  if ($ulist($fulladdress,koruma,0) >= 1) { return }
  elseif !$istok(#muafkanal #muafkanal2,$chan,32) {
    mode $chan +b $nick 
    kick $chan $nick Badnick
  }
}
on *:NICK:{ 
  if ($ulist($+($newnick,!*@*),koruma,0) >= 1) { return }
  else {
    if $ulist($+($newnick,!*@*),badnick,0) {
      var %Plt = 1 
      while $comchan($newnick,%Plt) { 
        var %e = $v1 
        if $me isop %e && !$istok(#muafkanal #muafkanal1,%e,32) { 
          mode %e +b $newnick 
          kick %e $newnick Badnick
        } 
        inc %Plt 
      } 
    } 
  }
}
alias badnickekle {
  auser badnick $1 $+ !*@*
}
alias badnicksil {
  ruser badnick $1 $+ !*@*
}
alias nickkoruma {
  auser koruma $1 $+ !*@*
}
alias badidentekle {
  auser badnick *! $+ $1 $+ @*
}
alias badidentsil {
  ruser badnick *! $+ $1 $+ @*
}
alias identkoruma {
  auser koruma *! $+ $1 $+ @*
}

Koda muaf kanal ve muaf nickler vardir ornek /badnickekle *gay* /nickkoruma *turgay* gibi Ekleme yapabilirsin
Kolay gelsin

İlginiz için tşk. Ederim ama ben yukarıdaki badnick hash korumasını kullanıyorum
Nickler userlist'te degil yani "has" dosyasının icin de

Yukarıdaki kodda

$iif($regex($nick($comchan($newnick,\n),$me).pnick ,/(%|@|&|~\.)/i),$comchan($newnick,\n) $chr(32)))

Eklentisi var ama hiç bir işe yaramıyor maalesef.

Alper · 28 Şubat 2020, 00:17

Hesapsiz33 Nickli Üyeden Alıntı
Bu forumdaki linkleri ve resimleri görebilmek için en az 25 mesajınız olması gerekir.

İlginiz için tşk. Ederim ama ben yukarıdaki badnick hash korumasını kullanıyorum
Nickler userlist'te degil yani "has" dosyasının icin de

Yukarıdaki kodda

$iif($regex($nick($comchan($newnick,\n),$me).pnick ,/(%|@|&|~\.)/i),$comchan($newnick,\n) $chr(32)))

Eklentisi var ama hiç bir işe yaramıyor maalesef.

Kod: Kodu kopyalamak için üzerine çift tıklayın!

on *:start:{ $iif(!$isfile(badnick.tprk),.write badnick.tprk) | .hmake badnick 100 | .hload badnick badnick.tprk }

on *:join:*: { 
  if $read(muafnick.txt,w,$nick) { return }
  if $regex($nick($chan,$me).pnick,[.~%&@]) && $hfind(badnick,$nick,1,W).data {
    kick $chan $nick 1Nick değiştirip (/nick yeninick) tekrar kanala giriş yapabilirsiniz..
    mode $chan +b $nick
  }
}

on *:nick: {
  if $read(muafnick.txt,w,$newnick) { return }
  if $hfind(badnick,$newnick,1,W).data {
    var %cht = $comchan($newnick,0)
    while %cht {
      if $regex(me,$nick($comchan($newnick,%cht),$me).pnick,[.~%&@]) && !$regex(newnick,$nick($comchan($newnick,%cht),$newnick).pnick,[.~%&@+]) { 
        ban -k $comchan($newnick,%cht) $newnick 2 Bilmem Sen Badnick misin ama Badnick listemde olduğun için banlandın bla bla bla... 
      }
      dec %cht
    }
  }
}

on *:text:*:#: {
  if $regex($1,/^[!\.]badnick$/Si) {
    if $regex($2,/^ekle$/Si) {
      if (!$3) { msg # Lütfen nick belirtiniz | return } 
      if $hfind(badnick,$strip($3),0,W).data { msg # Eklemeye çalıştığınız badnick zaten $+([,$chr(32),$hget(badnick,$hfind(badnick,$strip($3), 1,W).data),$chr(32),]) maskesi ile uyuşmakta. | return }
      if $read(muafnick.txt,w,$3) { msg # 2Bu kişi muaf nick listemde yer almakta. | return }
      var %n = $left($calc($ctime * $rand(1000,9999)),7)
      .hadd -m badnick %n $strip($3)
      .hsave -o badnick badnick.tprk
      msg # $strip($3) Badnick listesine eklendi.
    }
    if $regex($2,/^s[ıiİ]l$/Si) {
      if (!$3) { msg # Lütfen nick belirtiniz | return } 
      if !$hfind(badnick,$strip($3),0,W).data { msg # Bad nick listesinde bulunmamaktadir. | return }
      .hdel -m badnick $hfind(badnick,$strip($3),1,W).data
      .hsave -o badnick badnick.tprk
      msg # $strip($3) Badnick listesinden silindi.
    }
    if $regex($2,/^tara$/Si) {
      if (!$3) { msg # Lütfen nick belirtiniz | return } 
      if $read(muafnick.txt,w,$3) { msg # 2Bu kişi muaf nick listemde yer almakta. | return }
      if !$hfind(badnick,$strip($3),0,W).data { msg # Badnick listem'de $strip($3) ait bir mask yok. | return }
      msg # Nick: $strip($3) - 4 Mask: $+([,$chr(32),$hget(badnick,$hfind(badnick,$strip($3), 1,W).data),$chr(32),])
    }
    if ($2 == muaf) {
      if (!$3) { msg # Lütfen nick belirtiniz | return } 
      if $read(muafnick.txt,w,$3) { msg # $3 muaf listesinden silindi. | write $+(-dl,$read(muafnick.txt,w,$3)) muafnick.txt | return }
      msg # $3 muaf nick listesine eklendi.
      write muafnick.txt $3
    }
    if $regex($2,/^l[ıiİ]st$/Si) {
      if ($hget(badnick,0).data == 0) { msg # Badnick listesi boş. | return }
      msg # Badnick listesi
      msg # -
      var %i = 1 | while (%i <= $hget(badnick,0).data) { msg # %i $+ .4) [ $hget(badnick,%i).data ] | inc %i }
      msg # -
      msg # Badnick listesi sonu
    } 
  }
  if $regex($1,/^[!\.]tara$/Si) {
    if !$regex($2,/^#/Si) { msg # Lütfen #kanal belirtiniz | return } 
    if !$chan($2) { msg # $2 kanal'ında bulunmuyorum | return }
    var %:tara = 1 | while %:tara <= $nick($2,0) {
      if $hfind(badnick,$nick($2,%:tara),1,W).data && !$read(muafnick.txt,w,$nick($2,%:tara)) {
        msg # [ TARAMA ] $nick($2,%:tara) nicki badnick olarak tespit edildi. $+([,$chr(32),$hget(badnick,$hfind(badnick,$nick($2,%: tara),1,W).data),$chr(32),])
        mode $2 +b $nick($2,%:tara) | kick $2 $nick($2,%:tara) 4 Badnick! 1Nick değiştirip(/nick yeninick) tekrar kanala giriş yapabilirsiniz..
      }
      inc %:tara
    } 
    msg # Toplam $nick($2,0) kişi için, $hget(badnick,0).data adet mask taraması yapıldı. 
  }
}

Nick eventinde $chan kullanılmıyor doğal olarak yeni nicke geçtiğinde hangi kanalda ne yetkisi var bilemez o yüzden $comchan kullanılmalı ortak kanallarda arama yapar. Kodun çalışması için kanalda en az @ olman gerek ek olarak nick değişip badnicke geçen kişinin voice dahil hiç bir yetkisi olmaması gerek.

Hesapsiz33 · 28 Şubat 2020, 00:40

Yardımlarınız ve bilginlendirme için çok teşekkür ederim.

Benzer Konular
Konu	Konuyu Başlatan	Forum	Cevaplar	Son Mesaj
Çözüldü Notice flood korumasına muaf	TİGeR	mIRC Scripting Sorunları	8	12 Temmuz 2015 15:01
küfür korumasına muaf eklentiler	angry1	mIRC Scripting Sorunları	11	12 Ekim 2013 12:40
Badnick korumasına yardım	sEntieL	mIRC Scripting Sorunları	3	31 Mayıs 2013 03:17
Giriş korumasına muaf ekleme	Emrax	mIRC Scripting Sorunları	13	27 Şubat 2010 19:21
Clone korumasına muaf eklemek?	TeRKeDiLdi	mIRC Scripting Sorunları	3	21 Ekim 2009 22:34

Konuyu Toplam 1 Üye okuyor. (0 Kayıtlı üye ve 1 Misafir)

5846 sayılı Fikir ve Sanat Eserleri Kanunu gereğince sitemizde telif hakkı bulunan mp3,video v.b. eserlerin paylaşımı yasaktır. Yasal işlem olması halinde paylaşan kişi yada kişilerin bilgileri gerekli kuruma verilecektir.